Formel für Zellbezug mit 2 Variablen, beliebig angeordnet

[alexbu171]

Hallo Ihr Lieben,

ich habe ein Problem, an dem ich schon einige Zeit dran sitze und ich finde da einfach keine Lösung zu.
Ich bin eher ei Excel-Anfänger und denke, dass mir hier geholfen werden kann.
Ein Bild, um das Problem zu beschreiben, findet Ihr unten als Thumbnail angehängt.

Es soll so funktionieren: 
Ich gebe In die Zelle E2 und F2 Buchstaben aus der linken Matrix ein. Dabei soll es egal sein in

welcher Reihenfolge ich die Buchstaben eingebe. Das Ergebnis in der Zelle G2 soll gleich bleiben und aus der Zeile entnommen werden. 

Also wenn ich zum Beispiel "C" in die Zelle E2 und "A" in die Zelle F2 eingebe, soll in der Zelle G2 das Wort "rot" stehen. 

Und wenn ich "A" in die Zelle E2 und "C" in die Zelle F2 eingebe, soll in der Zelle G2 dasselbe Wort stehen. 

Ich hoffe echt, dass mit jemand helfen kann, da ich mit meinem begrenzten Wissen komplett am Ende bin..

MfG

[WillWissen]

Hi,

ich würde es mit einer Hilfsspalte (farbig hinterlegt) lösen, die du einfach ausblendest.

Tabelle1

	A	B	C	D	E	F	G	H
1	1	2	3			1	2	3
2	A	B	AB	grün		C	A	rot
3	B	A	BA	grün
4	C	D	CD	blau
5	D	A	DA	gelb
6	C	A	CA	rot

Formeln der Tabelle

Zelle Formel C2 =A2&B2 H2 =SVERWEIS($F$2&$G$2;C2:D6;2;0)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[alexbu171]

Hi, Danke dir für deine Antwort, werde es später nach der Arbeit ausprobieren und dann ein Feedback geben ?

[Jockel]

Hallo, oder ohne Hilfsspalte..:

Code:

=INDEX(C2:C6;VERGLEICH(E2&"*"&F2;INDEX(A2:A6&"*"&B2:B6;);0))

oder..:

Code:

=VERWEIS(42;1/(A2:A6=E2)*(B2:B6=F2);C2:C6)

[alexbu171]

Soo, Hallo nochmal :)

Danke auf jeden Fall für eure schnellen Antworten. Hab die Lösungswege gerade mal ausprobiert, aber die funktionieren leider nur Teilweise. Wenn ich in Zelle E2 "C" und in Zelle F2 "A" eingebe kommt die richtige Lösung raus. ABER wenn ich jetzt Beispielsweise in Zelle E2 "A" und in Zelle F2 "C" eingebe, soll die selbe Lösung rauskommen wie in Zeile 6. Dann wird mir aber eine Fehlermeldungen ausgegeben..

[BoskoBiati]

Hi,

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	A	B	rot	D	A	blau
2	A	C	grün
3	A	D	blau
4	B	C	gelb
5	B	D	schwarz
6	C	D	weiß

Zelle	Formel
F1	=WENNFEHLER(INDEX(C:C;WENNFEHLER(AGGREGAT(15;6;ZEILE($A$1:$A$6)/(A1:A6=E1)/(B1:B6=D1);1);AGGREGAT(15;6;ZEILE($A$1:$A$6)/(A1:A6=D1)/(B1:B6=E1);1)));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Soo, Hallo nochmal :)

... Teilweise... Wenn ich in Zelle E2 "C" und in Zelle F2 "A" eingebe kommt die richtige Lösung raus. ABER wenn ich jetzt Beispielsweise in Zelle E2 "A" und in Zelle F2 "C" eingebe, soll die selbe Lösung rauskommen wie in Zeile 6. Dann wird mir aber eine Fehlermeldungen ausgegeben..

Hallo, meinst du dann so..:

Code:

=WENNFEHLER(VERWEIS(42;1/((A2:A6=E2)*(B2:B6=F2)+(B2:B6=E2)*(A2:A6=F2));C2:C6);"")

[alexbu171]

Hey :)
Vielen Dank für eure Hilfe, beide Formeln funktionieren ganz genau so wie ich das geplant habe :)

[Jockel]

Hallo, danke für's feedback. Bitte poste doch nächstes Mal KEIN Bild(chen) sondern entweder einen aussagekräftigen Tabellenausschnitt mit einem Tool, da kann man sich das Nachbauen ersparen... ... oder gleich (d)eine (Beispiel)Datei...  :17: