Formel mit 2 Dropdown Menüs erstellen

[tanja_chat]

Hallo,
ich hab eine für euch sicherlich kleine Herausforderung. Da ich aber Excel in der Regel nur zu hohen Feiertagen brauche (also 2 mal in Jahr), bin ich selber noch nicht auf die Lösung gekommen. Es geht um Folgendes.

Ich habe ein Excel Sheet mit 2 Dropdown Menüs


1. Dropdown hat Auswahlmöglichkeiten
-Leer-
Zustand 1
Zustand 2
Zustand 3
Zustand 4


2. Dropdown hat die Auswahlmöglichkeiten
-Leer-
Zustand A
Zustand B
Zustand C
Zustand D


Je nach Auswahl in den jeweiligen Menüs soll in einem Dritten Feld eine Zahl zwischen 1 und 7 erscheinen. 1 und 2 Grün hinterlegt, 3 und 4 Gelb hinterlegt. 5, 6 und 7 rot Hinterlegt.

Folgende Zustände sollen möglich sein

Zustand 1 + Zustand A = 1
Zustand 1 + Zustand B = 2
Zustand 1 + Zustand C = 3
Zustand 1 + Zustand D = 4
Zustand 2 + Zustand A = 2
Zustand 2 + Zustand B = 3
Zustand 2 + Zustand C = 4
Zustand 2 + Zustand D = 5
Zustand 3 + Zustand A = 3
Zustand 3 + Zustand B = 4
Zustand 3 + Zustand C = 5
Zustand 3 + Zustand D = 6
Zustand 4 + Zustand A = 4
Zustand 4 + Zustand B = 5
Zustand 4 + Zustand C = 6
Zustand 4 + Zustand D = 7

Bei allen anderen Kombinationen mit dem Leerfeldern soll im 3ten Feld das Wort "kein Ergebnis" erscheinen.

Ich freue mich auf eure Hilfe und Tipps.

Danke die Tanja

[BoskoBiati]

Hallo,

z.B. so:

Arbeitsblatt mit dem Namen 'Gorgy'
	E	F	G
1

Zelle	Formel
G1	=WENN((E1<>"")*(F1<>"");E1+CODE(F1)-65;"")

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
E1	Liste		--;1;2;3;4
F1	Liste		--;A;B;C;D

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[shift-del]

Hallo

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E	F	G	H	I	J	K
1						Zustand 1	Zustand A	1
2						Zustand 1	Zustand B	2
3						Zustand 1	Zustand C	3
4						Zustand 1	Zustand D	4
5						Zustand 2	Zustand A	2
6						Zustand 2	Zustand B	3
7						Zustand 2	Zustand C	4
8						Zustand 2	Zustand D	5
9	Zustand 1	Zustand A				Zustand 3	Zustand A	3
10						Zustand 3	Zustand B	4
11						Zustand 3	Zustand C	5
12						Zustand 3	Zustand D	6
13						Zustand 4	Zustand A	4
14						Zustand 4	Zustand B	5
15	1					Zustand 4	Zustand C	6
16						Zustand 4	Zustand D	7

Zelle	Formel
D15	{=WENNFEHLER(INDEX(K1:K16;1/(1/MIN(WENN((I1:I16=D9)*(J1:J16=E9);ZEILE($K$1:$K$16)))));"kein Ergebnis")}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Zelle	bedingte Formatierung...	Format
D15	1: =D15<=2	abc
D15	2: =D15<=4	abc
D15	3: =D15<=7	abc

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hi,

  :20:

Hatte nicht alles verinnerlicht:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A
1	3
2	A
3	3

Zelle	Formel
A3	=WENNFEHLER(A1+CODE(A2)-65;"kein Ergebnis")

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
A1	Liste		--;1;2;3;4
A2	Liste		--;A;B;C;D

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[shift-del]

Hallo Edgar

Habe ich das Problem falsch verstanden?

[BoskoBiati]

Hallo Detlef,


es ging um zwei DropDowns. Da ist mir Deine Formel entschieden zu komplex.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A
1	Zustand 3
2	Zustand D
3	6

Zelle	Formel
A3	=WENNFEHLER(RECHTS(A1;1)+CODE(RECHTS(A2;1))-65;"kein Ergebnis")

Zelle	bedingte Formatierung...	Format
A3	1: =$A$3<3	abc
A3	2: =$A$3<5	abc
A3	3: =$A$3>4	abc

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
A1	Liste		--;Zustand 1;Zustand 2;Zustand 3;Zustand 4
A2	Liste		--;Zustand A;Zustand B;Zustand C;Zustand D

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Statt Deiner Hilfskonstruktion wurde ich die nehmen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Zustand 1
2	Zustand A
3	1		Zustand 1	Zustand A
4			Zustand 2	Zustand B
5			Zustand 3	Zustand C
6			Zustand 4	Zustand D

Zelle	Formel
A3	=WENNFEHLER(VERGLEICH(A1;$C$3:$C$6;0)+VERGLEICH(A2;$D$3:$D$6;0)-1;"kein Ergebnis")

Zelle	bedingte Formatierung...	Format
A3	1: =$A$3<3	abc
A3	2: =$A$3<5	abc
A3	3: =$A$3>4	abc

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
A1	Liste		--;Zustand 1;Zustand 2;Zustand 3;Zustand 4
A2	Liste		--;Zustand A;Zustand B;Zustand C;Zustand D

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Falls Zustand 1 usw. nur Platzhalter darstellen.

[shift-del]

Hallo Edgar

Du hast unter der Prämisse gearbeitet dass die Werte reale Werte sind. Ich habe unter der Prämisse gearbeitet dass die Werte Dummy-Werte sind.
Mal abwarten was die Tanja sagt.

[BoskoBiati]

Hallo Detlef,


deswegen in meinem letzten Beitrag noch eine Ergänzung, die auch das berücksichtigt.

[tanja_chat]

Hallo,

sorry, hätte ich noch sagen sollen, die Werte waren Platzhalter Werte, damit es verständlicher ist.

@ BoskoBiati. Deine Formel funktioniert super, musste nur

...6;0)-1;"kein Ergebnis")...

in

...6;0)-3;"kein Ergebnis")...


dann stimmten die Ergebnisse. Kann aber auch an meiner Excel Vorlage liegen


Vielen Dank für die Hilfe,

Gruß Tanja

[BoskoBiati]

Hallo,

das liegt eher am Rest Deiner Formel, die wohl nicht $D$3:SD$6 als Bereich hat!