Formel verschmelzen! :)

[EA1950]

Hallo,

ich habe 2 grundlegende Versionen anzubieten, weil ich nicht weiß, was davon gewünscht ist:

Version1:
Im Bereich B1:D1000 wird in der 2.Spalte (=C:C) die unterste Zelle mit Daten ermittelt  (=Zelle C6) und Werte aus Spalte A bzw. Zeile 1 zurückgegeben:
=LET(sp; 1; b; $C$1:.$C$1000; zlct; ZEILEN(b); 
VSTAPELN("Spalte: " & sp+1; "ID: " & INDEX($A:$A; zlct); "Überschrift: " & INDEX(b; 1; sp)))
bzw.
=LET(sp; 1; b; $C$1:.$C$1000; zlct; ZEILEN(b); 
VSTAPELN("Spalte: " & ZEICHEN(sp + 66); "Zeile: " & zlct; "Überschrift: " & INDEX(b; 1; sp)))


Version2:
Im Bereich B1:D1000 wird die unterste Zeile mit Daten gesucht (=Zeile B6:D6) und in dieser Zeile die äußerst rechte Zelle mit Daten (=Zelle C6) zurückgegeben mit den passenden Werten aus Spalte A bzw. Zeile 1:
=LET(b; $B$1:.$D$1000; zlct; ZEILEN(b); 
maxZl; INDEX(b; zlct; 0); sp; XVERGLEICH("x"; maxZl; 0; -1); 
VSTAPELN("Spalte: " & sp; "ID: " & INDEX($A:$A; zlct); "Überschrift: " & INDEX(b; 1; sp)))
bzw.
=LET(b; $B$1:.$D$1000; zlct; ZEILEN(b); 
maxZl; INDEX(b; zlct; 0); sp; XVERGLEICH("x"; maxZl; 0; -1); 
VSTAPELN("Spalte: " & ZEICHEN(sp + 65); "Zeile: " & zlct; "Überschrift: " & INDEX(b; 1; sp)))

Ich hoffe, dass jetzt etwas dabei ist, was passend ist.

[cysu11]

Hallo Edgar und Anton,

sorry für die späte Anwort und dafür, ich benötige die Formel für meine Office 2024 zuhause, aus dem Grund funktionieren die Formeln von Dir Anton, leider nicht, wahrscheinlich nur für 365.
Deine Formeln Edgar funktionieren zwar, aber ich habe das nicht detailliert genug erklärt.
Ich fange immer in B2 ein "x" einzugeben, dann geht das erstmal die Spalte runter, dann gehe ich in die nächste Spalte auch wieder von oben nach unten usw..Das was ich suche ist also das letzte eingetragene "x".
Wenn also z.B. B2 bis B6 und C2 bis C6 voll mit "x" sind und in D2 ein "x" steht, dann benötige ich diese Adresse und die ID und Überschrift dazu, da dies das letzte eingetragene "x" ist. 
kurz gesagt aus der Spalte die am weitesten nach rechts steht und ein oder mehrere "x" enthält und aus dieser spalte das "x" das am weitesten unten steht! :)

Vielen Dank schon mal im Voraus & LG, Alexandra

[BoskoBiati]

Hi,

dann sollte das gehen, zumindest in 365:

Code:

=LET(xa;XVERGLEICH("x";B2:K2;0;-1);xb;INDEX(B2:K11;;xa);xc;XVERGLEICH("x";xb;0;-1);VSTAPELN("Spalte: "&ZEICHEN(64+xa+1);"Zeile: "&xc;"Überschrift:"&INDEX(1:1;xa+1)))

2024 habe ich nicht, kann also nicht sagen, was da geht.

[cysu11]

Hallo Edgar,

die Formel funktioniert in 2024, allerdings auch nicht ganz richtig. Ich habe die Beispieldatei hochgeladen. D4 ist hier das letzt "x". Deine Formel spuckt aber B2 aus. 
Und wäre es möglich die Werte einzeln auszugeben in verschieden Zellen.

1. Adresse, in diesen Fall also D4
2. ID
3. Überschrift

Vielen Dank & LG, Alexandra

[BoskoBiati]

Hi,

Code:

=LET(za;A1:K10;xa;MAX(WENN(za="x";SPALTE(A:K)));xb;VERWEIS(9;1/(INDEX(za;;xa)="x");ZEILE(za));xc;INDEX(A1:K1;xa);VSTAPELN("Spalte: "&ZEICHEN(64+xa);"Zeile: "&xb;"Überschrift: "&xc))
=LET(za;A1:K10;xa;MAX(WENN(za="x";SPALTE(A:K)));xb;VERWEIS(9;1/(INDEX(za;;xa)="x");ZEILE(za));xc;INDEX(A1:K1;xa);VSTAPELN("Adresse: "&ZEICHEN(64+xa)&xb;"Überschrift: "&xc))

[cysu11]

Hallo Edgar,

das funktioniert perfekt, genauso!! :)

Vielen lieben Dank &  LG, Alexandra