Clever-Excel-Forum › Office-Anwendungen › Excel v
Formel zu lang? Serienbrief stürzt ab

Thema geschlossen 
Baumstrukturmodus
Formel zu lang? Serienbrief stürzt ab
Terrabyte77 Offline
pausiert
Registriert seit: 22.08.2018
Version(en): 2010
#1
22.08.2018, 15:26
Hallo zusammen, ich habe folgende Formel in meiner Datenbank und seit dem stürzt mit der Serienbrief beim zusammen führen auch nur eines Datensatzes ab.

Die Datei hat ohen die Formel 2 MB und mit 3,6 MB.

Was kann man da tun?

Danke euch.

Die Formel:

WENNFEHLER(WENN(A3="";"";WENN(A3<43101;"";WENN(UND(S3="";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");WENN(UND(S3<>"";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");WENN(UND(S3<>"";AC3<>"";AE3="";AC3<=HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d"))));WENN(UND(S3<>"";AC3<>"";AE3="";AC3>HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;HEUTE();"d"))));WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3<=AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AC3;"d"))));WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3>AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AE3;"d"))));WENN(UND(S3="";AC3="";AE3<>"");DATEDIF(A3;AE3;"d");WENN(UND(S3="";AC3<>"";AE3<>"");DATEDIF(A3;AE3;"d");WENN(UND(S3<>"";AC3="";AE3<>"");DATEDIF(A3;AE3;"d"))))))))))));0)
Suchen
Top
Jockel Offline
VUP & {Formelsympathisant}
Registriert seit: 10.04.2014
Version(en): Office 2019
#2
22.08.2018, 15:29
Hallo, ich sehe ja deine Datei nicht, aber what the hell soll das denn..?


PHP-Code:
... SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d")))... 


Ist das n' Scherz?
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Freund einer excellenten Power Query-Abfrage
Suchen
Top
LCohen Offline
Benutzer
Registriert seit: 21.12.2017
Version(en): MS 365 Family (6 User x 5 Geräte für jeden) Insider-Beta
#3
22.08.2018, 16:10 (Dieser Beitrag wurde zuletzt bearbeitet: 22.08.2018, 16:24 von LCohen.)
Erst mal ist bei Dir was anderes zu lang: Es heißt Terabyte.

Deine Formel braucht ein wenig Case-Modeling (rot wird zu halb so viel blau), und Deine 4malige SUMME ist Blöd-Zinn.

=WENNFEHLER(WENN(A3="";"";WENN(A3<43101;"";
WENN(UND(S3="";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");
WENN(UND(S3<>"";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");
WENN(UND(S3<>"";AC3<>"";AE3="";AC3<=HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d"))));
WENN(UND(S3<>"";AC3<>"";AE3="";AC3>HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;HEUTE();"d"))));
WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3<=AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AC3;"d"))));
WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3>AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AE3;"d"))));
WENN(UND(S3="";AC3="";AE3<>"");DATEDIF(A3;AE3;"d");
WENN(UND(S3="";AC3<>"";AE3<>"");DATEDIF(A3;AE3;"d");
WENN(UND(S3<>"";AC3="";AE3<>"");DATEDIF(A3;AE3;"d"))))))))))));0)

...
UND(AC3="";AE3="")*(HEUTE()-A3)+
UND(S3<>"";AC3<>"";AE3="")*(HEUTE()-A3+S3-MIN(HEUTE();AC3))+
UND(S3<>"";AC3<>"";AE3<>"")*(AE3-A3+S3-MIN(AC3;AE3))+
UND(S3="";AE3<>"")*(AE3-A3)+
...

Statt WENN geht es auch mit WAHL mit 8 Ausgängen, obwohl Du nur 5 hast. Drei davon schiebt man dann noch zusammen.
WIN/MSO schicken angeblich alle 5 Sekunden Deinen Screen heim zu Papa (recall-Klausel). 
Suchen
Top
BoskoBiati Offline
नौसिखिया [vidyaarthi]

Registriert seit: 13.04.2014
Version(en): 365
#4
22.08.2018, 16:10
Hi,

ich würde die Formel mal so kürzen (UNGETESTET!!!):


Code:
=WENN((A3="")+(A3<--"1.1");"";WENN((AC3="")*(AE3="");HEUTE()-A3;WENN((S3<>"")*(AC3<>"");WENN(AE3<>"";AE3-A3+S3-MIN(AE3;AC3);HEUTE()-A3+S3-MIN(HEUTE();AC3));WENN(AE3<>"";AE3-A3;AC3-S3))))
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Suchen
Top
BoskoBiati Offline
नौसिखिया [vidyaarthi]

Registriert seit: 13.04.2014
Version(en): 365
#5
22.08.2018, 18:45 (Dieser Beitrag wurde zuletzt bearbeitet: 22.08.2018, 18:45 von BoskoBiati.)
Hi,

getestet:

Arbeitsblatt mit dem Namen 'Tabelle1'
ASACAEAFAGAHAI
201.10.2017 0
301.01.2018 233233233233
401.01.2018 16.08.2018227227227227
501.01.2018 11.08.201814.08.2018225225225225
601.01.201815.05.2018 14.08.2018225225225225
701.01.201815.05.2018 233233233233
801.01.201815.05.201817.05.2018 231231231231
901.01.201815.05.201823.08.2018 134134134134
1001.01.201815.05.201825.05.201801.06.2018141141141141
1101.01.201815.05.201825.05.201820.05.2018134134134134

ZelleFormel
AF2=WENNFEHLER(WENN(A2="";"";WENN(A2<43101;"";WENN(UND(S2="";AC2="";AE2="");DATEDIF(A2;HEUTE();"d");WENN(UND(S2<>"";AC2="";AE2="");DATEDIF(A2;HEUTE();"d");WENN(UND(S2<>"";AC2<>"";AE2="";AC2<=HEUTE());SUMME((DATEDIF(A2;HEUTE();"d")-(DATEDIF(S2;AC2;"d"))));WENN(UND(S2<>"";AC2<>"";AE2="";AC2>HEUTE());SUMME((DATEDIF(A2;HEUTE();"d")-(DATEDIF(S2;HEUTE();"d"))));WENN(UND(S2<>"";AC2<>"";AE2<>"";AC2<=AE2);SUMME((DATEDIF(A2;AE2;"d")-(DATEDIF(S2;AC2;"d"))));WENN(UND(S2<>"";AC2<>"";AE2<>"";AC2>AE2);SUMME((DATEDIF(A2;AE2;"d")-(DATEDIF(S2;AE2;"d"))));WENN(UND(S2="";AC2="";AE2<>"");DATEDIF(A2;AE2;"d");WENN(UND(S2="";AC2<>"";AE2<>"");DATEDIF(A2;AE2;"d");WENN(UND(S2<>"";AC2="";AE2<>"");DATEDIF(A2;AE2;"d"))))))))))));0)
AG2=WENN((A2="")+(A2<--"1.1");"";WENN((AC2="")*(AE2="");HEUTE()-A2;WENN((S2<>"")*(AC2<>"");WENN(AE2<>"";AE2-A2+S2-MIN(AE2;AC2);HEUTE()-A2+S2-MIN(HEUTE();AC2));WENN(AE2<>"";AE2-A2;AC2-S2))))
AH2=WENN((A2="")+(A2<--"1.1");"";WENN((AC2="")*(AE2="");HEUTE()-A2;WENN((S2<>"")*(AC2<>"");S2-A2+WENN(AE2<>"";AE2-MIN(AE2;AC2);HEUTE()-MIN(HEUTE();AC2));WENN(AE2<>"";AE2-A2;AC2-S2))))
AI2=(A2<>"")*(A2>=--"1.1")*(WENN(AE2="";HEUTE();AE2)-WENN(ANZAHL(S2:AC2)<2;0;MIN(HEUTE();MIN(AC2;AE2))-S2)-A2)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Suchen
Top
Terrabyte77 Offline
pausiert
ThreadStarter
Registriert seit: 22.08.2018
Version(en): 2010
#6
23.08.2018, 06:49
(22.08.2018, 15:29)Jockel schrieb: Hallo, ich sehe ja deine Datei nicht, aber what the hell soll das denn..?


PHP-Code:
... SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d")))... 


Ist das n' Scherz?

Guten Morgen,
die Formel zieht Wartezeiten ab, in der der Sachbearbeiter nichts machen kann.
Die Formel berechnet Bearbeitungszeiten im Unternehmen.
Suchen
Top
Terrabyte77 Offline
pausiert
ThreadStarter
Registriert seit: 22.08.2018
Version(en): 2010
#7
23.08.2018, 06:50
(22.08.2018, 16:10)LCohen schrieb: Erst mal ist bei Dir was anderes zu lang: Es heißt Terabyte.

Deine Formel braucht ein wenig Case-Modeling (rot wird zu halb so viel blau), und Deine 4malige SUMME ist Blöd-Zinn.

=WENNFEHLER(WENN(A3="";"";WENN(A3<43101;"";
WENN(UND(S3="";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");
WENN(UND(S3<>"";AC3="";AE3="");DATEDIF(A3;HEUTE();"d");
WENN(UND(S3<>"";AC3<>"";AE3="";AC3<=HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;AC3;"d"))));
WENN(UND(S3<>"";AC3<>"";AE3="";AC3>HEUTE());SUMME((DATEDIF(A3;HEUTE();"d")-(DATEDIF(S3;HEUTE();"d"))));
WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3<=AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AC3;"d"))));
WENN(UND(S3<>"";AC3<>"";AE3<>"";AC3>AE3);SUMME((DATEDIF(A3;AE3;"d")-(DATEDIF(S3;AE3;"d"))));
WENN(UND(S3="";AC3="";AE3<>"");DATEDIF(A3;AE3;"d");
WENN(UND(S3="";AC3<>"";AE3<>"");DATEDIF(A3;AE3;"d");
WENN(UND(S3<>"";AC3="";AE3<>"");DATEDIF(A3;AE3;"d"))))))))))));0)

...
UND(AC3="";AE3="")*(HEUTE()-A3)+
UND(S3<>"";AC3<>"";AE3="")*(HEUTE()-A3+S3-MIN(HEUTE();AC3))+
UND(S3<>"";AC3<>"";AE3<>"")*(AE3-A3+S3-MIN(AC3;AE3))+
UND(S3="";AE3<>"")*(AE3-A3)+
...

Statt WENN geht es auch mit WAHL mit 8 Ausgängen, obwohl Du nur 5 hast. Drei davon schiebt man dann noch zusammen.


Guten Morgen,
ich habe deine Änderungen einmal eingegeben, da kommt die Fehlermeldung "ZU WENIG ARGUMENTE FÜR DIE FUNKTION"
Suchen
Top
Terrabyte77 Offline
pausiert
ThreadStarter
Registriert seit: 22.08.2018
Version(en): 2010
#8
23.08.2018, 06:57
(22.08.2018, 18:45)BoskoBiati schrieb: Hi,

getestet:

Arbeitsblatt mit dem Namen 'Tabelle1'
ASACAEAFAGAHAI
201.10.2017 0
301.01.2018 233233233233
401.01.2018 16.08.2018227227227227
501.01.2018 11.08.201814.08.2018225225225225
601.01.201815.05.2018 14.08.2018225225225225
701.01.201815.05.2018 233233233233
801.01.201815.05.201817.05.2018 231231231231
901.01.201815.05.201823.08.2018 134134134134
1001.01.201815.05.201825.05.201801.06.2018141141141141
1101.01.201815.05.201825.05.201820.05.2018134134134134

ZelleFormel
AF2=WENNFEHLER(WENN(A2="";"";WENN(A2<43101;"";WENN(UND(S2="";AC2="";AE2="");DATEDIF(A2;HEUTE();"d");WENN(UND(S2<>"";AC2="";AE2="");DATEDIF(A2;HEUTE();"d");WENN(UND(S2<>"";AC2<>"";AE2="";AC2<=HEUTE());SUMME((DATEDIF(A2;HEUTE();"d")-(DATEDIF(S2;AC2;"d"))));WENN(UND(S2<>"";AC2<>"";AE2="";AC2>HEUTE());SUMME((DATEDIF(A2;HEUTE();"d")-(DATEDIF(S2;HEUTE();"d"))));WENN(UND(S2<>"";AC2<>"";AE2<>"";AC2<=AE2);SUMME((DATEDIF(A2;AE2;"d")-(DATEDIF(S2;AC2;"d"))));WENN(UND(S2<>"";AC2<>"";AE2<>"";AC2>AE2);SUMME((DATEDIF(A2;AE2;"d")-(DATEDIF(S2;AE2;"d"))));WENN(UND(S2="";AC2="";AE2<>"");DATEDIF(A2;AE2;"d");WENN(UND(S2="";AC2<>"";AE2<>"");DATEDIF(A2;AE2;"d");WENN(UND(S2<>"";AC2="";AE2<>"");DATEDIF(A2;AE2;"d"))))))))))));0)
AG2=WENN((A2="")+(A2<--"1.1");"";WENN((AC2="")*(AE2="");HEUTE()-A2;WENN((S2<>"")*(AC2<>"");WENN(AE2<>"";AE2-A2+S2-MIN(AE2;AC2);HEUTE()-A2+S2-MIN(HEUTE();AC2));WENN(AE2<>"";AE2-A2;AC2-S2))))
AH2=WENN((A2="")+(A2<--"1.1");"";WENN((AC2="")*(AE2="");HEUTE()-A2;WENN((S2<>"")*(AC2<>"");S2-A2+WENN(AE2<>"";AE2-MIN(AE2;AC2);HEUTE()-MIN(HEUTE();AC2));WENN(AE2<>"";AE2-A2;AC2-S2))))
AI2=(A2<>"")*(A2>=--"1.1")*(WENN(AE2="";HEUTE();AE2)-WENN(ANZAHL(S2:AC2)<2;0;MIN(HEUTE();MIN(AC2;AE2))-S2)-A2)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Hallo Edgar,
das wirft bei mir falsche Ergebnisse aus.

Es soll so sein:

Spalte A = EINGANGSDATUM ANTRAG
Spalte S = Datum, an dem der Sachbearbeiter fehlende Unterlagen nachgereicht hat
Spalte AC = Datum, an dem die Unterlagen spätestens wieder eingehen müssen
Slpalte AE = Datum, an dem der Antrag geschlossen wurde.

Die Zeit zwischen S und AC darf maximal 33 Tage beteragen.
Diese Zeit soll dem Sachbearbeiter nicht angerechnet werden.

Sofern es nur Daten in A gibt, soll immer mit Datum HEUTE die Zeit berechnet werden.

Danke für deine Mühe.
Suchen
Top
BoskoBiati Offline
नौसिखिया [vidyaarthi]

Registriert seit: 13.04.2014
Version(en): 365
#9
23.08.2018, 07:40
Hi,

in AF stehen die Ergebnisse Deiner Formel, in den weiteren Spalten die meiner Formeln. Siehst Du da einen Unterschied?
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Suchen
Top
Terrabyte77 Offline
pausiert
ThreadStarter
Registriert seit: 22.08.2018
Version(en): 2010
#10
23.08.2018, 09:28
(23.08.2018, 07:40)BoskoBiati schrieb: Hi,

in AF stehen die Ergebnisse Deiner Formel, in den weiteren Spalten die meiner Formeln. Siehst Du da einen Unterschied?

Hallo Edgar,
sorry, ich bin wohl zu blöd.
Wenn ich deine Formel aus AI2 in meine Tabelle kopiere, kommt immer 0 raus.
Bei allen anderen bleibt das Feld weiß???
Suchen
Top
Thema geschlossen 


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 2 Gast/Gäste