Formelhilfe

[Thomas78]

Hallo liebes Forum,

jetzt habe ich doch noch eine Frage...

Dieses Mal geht es mir um 2 Berechnungen:

Zum einem um Zeile 6 : 
Hier würde ich gerne per Formel ermitteln ob der Tag ein Freitag oder ein Wochentag vor einem Feiertag und kein Feiertag ist. (Also jeden Freitag, der kein Feiertag ist und wenn z.B. Donnerstag ein Feiertag ist soll er den Mittwoch vorher auch markieren.) Ich habe die entsprechenden Tage in der angehängten Datei händisch mit x markiert.
Evtl. muss man noch berücksichtigen bei 2 aufeinander folgenden Feiertagen (Weihnachten usw.)
Freitage habe ich bisher mit =WENN(REST(G5;7)=6;"x";"") ermittelt.

Zum anderen um Spalte AK:
Hier würde ich gerne bei den mit x gekennzeichneten Mitarbeitern (Spalte AJ) prüfen ob an einem mit x markierten Tag kein Eintrag (Urlaub, Krank usw.) im Kalender ist und diese Tage zählen. (Auch hier habe ich das Wunschergebnis händisch eingetragen.

Ich selbst bringe die Formel einfach nicht hin und wäre sehr froh nochmal eure Hilfe in Anspruch nehmen zu dürfen.

Vielen Dank und schöne Grüße

Thomas

[BoskoBiati]

Hi,

z.B. so:

Code:

=WENN(ZÄHLENWENN(FeiertagDatum;D5)=0;WENN(ODER(REST(D5;7)=6;ZÄHLENWENN(FeiertagDatum;E5)>0);"x";"");"")

[Thomas78]

Hallo Opa Edgar,

danke schonmal für deine Hilfe !

Im Oktober funktioniert deine Formel einwandfrei, im November habe ich aber am 31. (den es kalendarisch nicht gibt) ein x. (liegt wohl daran das ich mir den 31. nur ausblenden lasse, hier müsste ich wohl noch eine Prüfung einfügen ob das Datum noch im aktuellen Monat liegt).
Im Dezember habe ich am 23. und 30. (Samstage) jeweils ein x zuviel und da die Feiertage auf Montag und Dienstag fallen, bräuchte ich am Freitag zuvor eigentlich kein x da es eh ein Freitag ist. 

Es soll an jedem Freitag ein x stehen solange der Freitag selbst kein Feiertag ist. Und es soll an jedem Wochentag vor einem Feiertag ein x erscheinen.

Hast du hier noch Tipps?

Schöne Grüße

Thomas

[BoskoBiati]

Hi,

dann ggf. so:

Arbeitsblatt mit dem Namen 'Lohnabrechnung'
	B	C	D	E	F	G	H
4	Fr	Sa	So	Mo	Di	Mi	Do
5	01	02	03	04	05	06	07
6							x

Zelle	Formel
B4	=AI4
C4	=WENN(MONAT($B$4+SPALTE(A1))<>MONAT($B$4);"";$B$4+SPALTE(A1))
B5	=B$4
C5	=C$4
B6	=WENN(B5="";"";WENN(ZÄHLENWENN(FeiertagDatum;B5)=0;WENN(ODER(REST(B5+1;7)=6;UND(REST(B5;7)>2;ZÄHLENWENN(FeiertagDatum;C5)>0));"x";"");""))
C6	=WENN(C5="";"";WENN(ZÄHLENWENN(FeiertagDatum;C5)=0;WENN(ODER(REST(C5+1;7)=6;UND(REST(C5;7)>2;ZÄHLENWENN(FeiertagDatum;D5)>0));"x";"");""))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Thomas78]

Hallo Opa Edgar,

hat nicht ganz funktioniert aber ich konnte dank deiner Formel die Änderungen selbst vornehmen.

Mit 

Code:

=WENN(WOCHENTAG(B$5;2) > 5;"";WENN(MONAT(B$5)>MONAT($AI$4);"";WENN(ZÄHLENWENN(FeiertagDatum;B$5)=0;WENN(ODER(REST(B$5;7)=6;ZÄHLENWENN(FeiertagDatum;C$5)>0);"x";"");"")))

scheint es jetzt zu funktionieren. Bisher konnte ich keinen Fehler feststellen.

Vielen Dank und schöne Grüße

Thomas