Frage Summenprodukt plus Filter

[FK1985]

Hallo Community,

ich finde hierzu leider einfach keine Lösung. Weder in Internetforen oder sonst wo. Ich bin dazu noch ein absoluter Anfänger was Excel angeht. Für meine Tabelle habe ich bis jetzt den halben Tag gebraucht 

Ich verzweifle an der Formel. Es ist sicherlich einfach, das hinzubekommen, aber wenn ich andere Formeln sehe, die länger sind als diese hier, dann verzweifel ich, da ich den Sinn dahinter einfach nicht verstehen kann  :22:


Es geht um folgendes:

Ich habe ein Travel Diary erstellt um die Arbeitstage in Deutschland und Ungarn zu erfassen. Ich habe das Ganze als Tabelle formatiert.

Links in Spalte steht das Datum, hier habe ich einen Filter gesetzt bzw. der Standarttabellenfilter wo ich das Datum auswählen kann. Rechts daneben steht der Aufenthaltsort. Hier Deutschland oder Ungarn. In Spalte C der Aufenthaltszweck. Hier habe ich jeweils ein Dropdown eingefügt. Nun habe ich oben rechts eine Formel eingefügt, die mir nur Arbeitstage (also Tage bei denen in Spalte C "Arbeit" im dropdown ausgewählt wurde) in Deutschland und in Ungarn anzeigen. Die restlichen Daten im Dropdown Aufenthaltszweck beleiben unberührt und es summiert nur die Einträge mit Aufenthaltszweck "Arbeit". 

Nun setze ich den Filter in der Tabelle bei Datum und selektiere nach z.B. Juli. Angezeigt werden mir allerdings rechts oben die kompletten Tage der Tabelle für die Einträge mit Arbeit, also ohne Berücksichtigung des Datumfilters. 

Kann mir bitte jemand helfen und es auf "Excel for dummies" Art erklären, wie ich es schaffe, dass es mir dort oben rechts nur die Tage anzeigt, für den Monat wo ich den Tabellenfilter gesetzt habe? 


Über eure Hilfe wäre ich euch so sehr dankbar!!!! :100:

Danke und VG
Fabi

[shift-del]

Hallo

Code:

=SUMMENPRODUKT((Tabelle3[Aufenthaltsort]="Deutschland")*(Tabelle3[Aufenthaltszweck]="Arbeit")*TEILERGEBNIS(103;BEREICH.VERSCHIEBEN(Tabelle3[[#Kopfzeilen];[Datum]];ZEILE(Tabelle3[Datum])-ZEILE(Tabelle3[[#Kopfzeilen];[Datum]]);;;)))

[BoskoBiati]

Hi,

ich würde, wenn es nur um einzelne Monate geht, den 1. des Monats in D1 eintragen und mit Zählenwenns arbeiten:

Arbeitsblatt mit dem Namen 'Tabelle1'
	C	D
1	Arbeitstage für Auswahlmonat	Juli
2	Arbeitstage Deutschland:	9
3	Arbeitstage Ungarn:	13

Zelle	Formel
D2	=ZÄHLENWENNS($B$6:$B$189;"D*";$C$6:$C$189;"Arbeit";$A$6:$A$189;">="&MAX(1;$D$1);$A$6:$A$189;"<="&MONATSENDE(MIN(50000;$D$1);0))
D3	=ZÄHLENWENNS($B$6:$B$189;"U*";$C$6:$C$189;"Arbeit";$A$6:$A$189;">="&MAX(1;$D$1);$A$6:$A$189;"<="&MONATSENDE(MIN(50000;$D$1);0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Tabelle1'
	C	D
1	Arbeitstage für Auswahlmonat
2	Arbeitstage Deutschland:	13
3	Arbeitstage Ungarn:	16

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[FK1985]

Hallo

Code:

=SUMMENPRODUKT((Tabelle3[Aufenthaltsort]="Deutschland")*(Tabelle3[Aufenthaltszweck]="Arbeit")*TEILERGEBNIS(103;BEREICH.VERSCHIEBEN(Tabelle3[[#Kopfzeilen];[Datum]];ZEILE(Tabelle3[Datum])-ZEILE(Tabelle3[[#Kopfzeilen];[Datum]]);;;)))

SUPER!!!!

Ich danke euch!!! 

Viele Grüße
Fabi

[FK1985]

Hi,

ich würde, wenn es nur um einzelne Monate geht, den 1. des Monats in D1 eintragen und mit Zählenwenns arbeiten:

Arbeitsblatt mit dem Namen 'Tabelle1'
	C	D
1	Arbeitstage für Auswahlmonat	Juli
2	Arbeitstage Deutschland:	9
3	Arbeitstage Ungarn:	13

Zelle	Formel
D2	=ZÄHLENWENNS($B$6:$B$189;"D*";$C$6:$C$189;"Arbeit";$A$6:$A$189;">="&MAX(1;$D$1);$A$6:$A$189;"<="&MONATSENDE(MIN(50000;$D$1);0))
D3	=ZÄHLENWENNS($B$6:$B$189;"U*";$C$6:$C$189;"Arbeit";$A$6:$A$189;">="&MAX(1;$D$1);$A$6:$A$189;"<="&MONATSENDE(MIN(50000;$D$1);0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Tabelle1'
	C	D
1	Arbeitstage für Auswahlmonat
2	Arbeitstage Deutschland:	13
3	Arbeitstage Ungarn:	16

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

SUPER!!!!

Ich danke euch!!! 

Viele Grüße
Fabi