Frage rechnen mit Zeiten

[Cpt. Obvious]

Guten morgen zusammen,

ich sitze derzeit an einer kleiner Tabelle zur Berechnung der Arbeitszeit dran und wollte zum Schluss meine Gleitzeit ausrechnen lassen. Erst für jeden Tag und dann Gesamt.
Das mit der Gleitzeit für jeden Tag klappt inzwsichen, hier habe ich mich an den folgenden Link gehalten und das Problem bei Gesamt ist natürlich das man mit Text versucht zu rechnen, was logischerweise nicht geht. http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=240
Für Gesamt habe ich erstmal eine Übergangslösung, da ich eigentlich nie im negativen Bereich bin, aber trotzdem möchte ich für den Fall der Fälle dass das trotzdem funktioniert.
Die Uhrzeiten in der unteren Tabelle sind für Testzwecke ausgedacht und stimmen so natürlich nicht. ^^


Tabelle1

	A	B	C	D	E	F
21		Montag	Dienstag	Mittwoch	Donnerstag	Freitag
22	Start	8:00	8:00	8:00	8:00	8:00
23	Ende	16:11	16:55	16:45	17:15	17:25
24	Arbeitszeit	8:45	8:45	8:45	8:45	8:45
25	Gleitzeit	'-00:34	0:10	0:00	0:30	0:40
26	Gesamt:	0:46

verwendete Formeln
Zelle	Formel	Bereich	N/A
B25:F25	=WENN(B23-(B22+B24)<0;TEXT((B22+B24)-B23;"-[hh]:mm");B23-(B22+B24))
B26	=(B23-(B22+B24)+C23-(C22+C24)+D23-(D22+D24)+E23-(E22+E24)+F23-(F22+F24))

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 18.19 einschl. 64 Bit

Ich hoffe mir kann jemand weiterhelfen und bedanke mich schonmal im voraus für Eure Antworten. :D

[Kl@us-M.]

Hi,

wenn ich Deine Frage richtig interpretiere, möchtest Du die Formel in B26 vereinfachen?

Ich würde hier mit einer Hilfszeile (im Beispiel Zeile 26) arbeiten, die Du ja ausblenden kannst ...

	A	B	C	D	E	F
21		Montag	Dienstag	Mittwoch	Donnerstag	Freitag
22	Start	08:00	08:00	08:00	08:00	08:00
23	Ende	16:11	16:55	16:45	17:15	17:25
24	Arbeitszeit	08:45	08:45	08:45	08:45	08:45
25	Gleitzeit	-00:34	00:10	00:00	00:30	00:40
26		##########	00:10	00:00	00:30	00:40
27	Gesamt:	00:46

Zelle	Formel
B25	=WENN(B23-(B22+B24)<0;TEXT((B22+B24)-B23;"-[hh]:mm");B23-(B22+B24))
C25	=WENN(C23-(C22+C24)<0;TEXT((C22+C24)-C23;"-[hh]:mm");C23-(C22+C24))
D25	=WENN(D23-(D22+D24)<0;TEXT((D22+D24)-D23;"-[hh]:mm");D23-(D22+D24))
E25	=WENN(E23-(E22+E24)<0;TEXT((E22+E24)-E23;"-[hh]:mm");E23-(E22+E24))
F25	=WENN(F23-(F22+F24)<0;TEXT((F22+F24)-F23;"-[hh]:mm");F23-(F22+F24))
B26	=B23-B22-B24
C26	=C23-C22-C24
D26	=D23-D22-D24
E26	=E23-E22-E24
F26	=F23-F22-F24
B27	=SUMME(B26:F26)

[Cpt. Obvious]

Hi,

danke für die Antwort. Stimmt ich habe mich da ein bisschen blöd ausgedrückt. ^^
Ich habe dein Vorschlag mal ausprobiert und danach für Montag anstatt 8Uhr 10Uhr eingetragen und das Problem ist, das im negativen Bereich lauter Rauten angezeigt werden, wenn ich eine einfache SUMME-Funktion benutze.
Kann ich das irgendwie, wie mit der WENN-Funktion von B25 bis F25 regeln? Hab das nämlich mal probiert aber dann steht da nur #WERT!, aber denk mal das bei mir ein Denkfehler drin ist. Habe den Befehl dann eingetragen =WENN(SUMME(B26:F26)<0;TEXT(SUMME(B26:F26);"-[hh]:mm");SUMME(B26:F26)) und für mich logisch würde er jetzt alle Zahlen, wie in deiner angegebenen Tabelle, zusammenfassen.

[BoskoBiati]

Hallo,

ich würde es so machen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	B	C	D	E	F	G
1		Montag	Dienstag	Mittwoch	Donnerstag	Freitag
2	Start	08:00	08:00	08:00	08:00	08:00
3	Ende	16:11	16:55	16:45	17:15	17:25
4	Arbeitszeit	08:45	08:45	08:45	08:45	08:45
5	Gleitzeit	-00:34	+00:10	+00:00	+00:30	+00:40
6	Gesamt:	+00:46

Zelle	Formel
C5	=WENN(REST(C3-C2;1)<C4;"-";"+")&TEXT(ABS(REST(C3-C2;1)-C4);"hh:mm")
C6	=WENN(SUMMENPRODUKT((C3:G3-C2:G2)-(C4:G4))<0;"-";"+")&TEXT(ABS(SUMMENPRODUKT((C3:G3-C2:G2)-(C4:G4)));"hh:mm")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Cpt. Obvious]

Ah vielen dank, nu klappt alles.
Vielen vielen dank für die Hilfe :D