Funktion gesucht

[hotrod]

  24_10_14hochladen.xlsx (Größe: 10,51 KB / Downloads: 17)
Guten Abend,

ich habe ein Problem Werte automatisch in einer Excel Liste in eine weitere Spalte zu kopieren.
Es gibt bestimmt eine Lösung unter Excel, aber ich komme nicht auf die Formel, bzw die benötigte Funktion.

1.) Spalta A: Ich habe in mehreren Zeilen die gleiche Nummer, bis irgendwann die nächst größere Nummer folgt und dann die nächste etc.
2.) In Spalte B gibt es manchmal eine weitere Sortierung mit X, Y oder Z oder keine.
3.) In Spalte C ist manchmal ein Wert angegeben für die Nummern unter eins.

Ergebnis soll sein, das:
Wenn es einen Wert in Spalte C gibt, soll dieser in die oberste Zeile der jeweiligen Nummer von Spalte A übertragen werden.
UND
steht in Spalte B das "X", soll dieser Wert in Spalte E
steht in Spalte B das Y soll dieser Wert in Spalte F
steht in Spalte B das Z soll dieser Wert in Spalte G

Ich hab bisher eine Hilfsspalte für eine Sortierung in "1" und "2":
=WENN(A3>A4;1;2)

Sowie eine Hilfsspalte für eine durchgehende Nummerierung der Nummern:
=SUMME(WENN($Hilfsspalte:Hilfsspalte=1;1;0))

Ich weiß aber nicht ob mich das nun weiterbringt.
Und ich kann auch leider nichts googlen, dessen Frage ich nicht weiß.

Möglichkeiten in meinen Formeln waren bisher: Wenn, Zählenwenn, Wenn und SVERWEIS, allerdings ohne nennenswerten erfolg.

Vielleicht kann mir ja hier jemand eine Richtung zeigen nach welcher Funktion ich suche.

Danke vorweg und einen guten Start in die Woche.

hotrod.

[shift-del]

Und ich kann auch leider nichts googlen, dessen Frage ich nicht weiß.

Ah ja.

Klingt für mich nach einer Art Aggregierung.

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	I	J	K
2	Zahlenreihe	Sortierung	Wert
3	10500	X	1,2
4	10600	Y	0
5	11200	Z	2,8
6	13700	Y	1,4
7	14500		0

Zelle	Formel
I3	=EINDEUTIG(A3:A20)
J3	=TEXTKETTE(WENN(($A$3:$A$20=I3)*($B$3:$B$20<>"");$B$3:$B$20;""))
K3	=SUMMEWENNS($C$3:$C$20;$A$3:$A$20;I3#)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[ws-53]

Die Formel: 

Code:

=WENN($A3<>$A2;SUMMEWENNS($C$3:$C$17;$B$3:$B$17;RECHTS(E$2;1);$A$3:$A$17;$A3);"")

in E3 und nach rechts und nach unten ziehen.

[snb]

Studiere mal Pivottables:

[EA1950]

Hallo,

in Zelle E3 folgende Formel eingeben/kopieren:

Code:

=FILTER($C$3:$C$17;($A$3:$A$17=$A3)*($A3<>$A2)*($B$3:$B$17=RECHTS(E$2));"")

und diese durch Formelkopieren in den Bereich E3:G13 kopieren.

[EA1950]

Hallo,

ich habe dir im Arbeitsblatt "Tabelle2" in Zelle E2 folgende Formel eingefügt:

Code:

=LET(
    Ein; $A$3:$C$17;
    NrL; INDEX(Ein; ; 1);
    Sor; INDEX(Ein; ; 2);
    Wrt; INDEX(Ein; ; 3);
    NrV; VSTAPELN(0; NrL);
    SpA; MTRANS(SORTIEREN(EINDEUTIG(FILTER(Sor; Sor <> ""))));
    Aus; MATRIXERSTELLEN(
        ZEILEN(NrL);
        SPALTEN(SpA);
        LAMBDA(i; j;
            LET(
                NrI; INDEX(NrL; i; 1);
                NrK; INDEX(NrV; i; 1);
                SpJ; INDEX(SpA; 1; j);
                FILTER(Wrt; (NrL = NrI) * (NrI <> NrK) * (Sor = SpJ); "")
            )
        )
    );
    VSTAPELN("Ausgabe " & SpA; Aus)
)

In der Variablen "Ein" wird der Eingabereich (zB. $A$3:$C$17) vorgegeben, der deine 3 Spalten ohne Überschriftsbereich A2:C2 enthält. Die Formel ermittelt ihrerseits den Überschriftenbereich (E2:G2) und den unterhalb anschließenden Ausgabereich (E3:G17).

Datei liegt bei.

[hotrod]

Guten Morgen zusammen,

vielen Dank für eure Hilfestellungen vorweg.
Ich werde das diese Woche bei etwas "Luft" mal testen und gebe euch dann natürlich nochmal ein Feedback meinerseits.

Dies jetzt nur als zwischen Feedback, damit ihr nicht glaubt, ich hätte euch vergessen. Ist nur wie immer viel los..


VG hotrod.