Funktion gesucht

[paulupaul]

Hallo liebe clever Excellers,

einen guten Tag wünsche ich und hoffe das Ihr mir auch zu einem verhelfen könnt.
Ich bin kein Excel-Profi aber auch nicht ganz unbewandert, beiße mir jedoch bei diesem Problem die Zähne aus.

Also Problemstellung sieht wie folgt aus:

In einer Excel-Liste stehen über sehr viele Zeilen Kontaktdaten (Vorname, Nachname, etc.) unter Anderem auch E-Mailadressen. In einem anderem Blatt der selben Datei, sind nun zusätzlich noch eine Reihe an Domains aufgeführt.

Die Aufgabe der gesuchten Funktion wäre nun die E-Mailadressen nach den Domains zu durchsuchen und bei einer Übereinstimmung ein bestimmtes Wort in einer Spalte zu hinterlassen, zum Beispiel "Kunde". Mein Problem ist nur das die Zellen nicht genau übereinstimmen, da E-Mailadressen noch "voname.nachname@" oder Ähnliches vor der Domain stehen haben. Außerdem gibt es vereinzelt auch mehrere Adressen mit der selben Domain, die alle markiert werden sollen.


Bei Unklarheiten liefere ich gerne noch zusätzliche Informationen und verbleibe vorweg dankbar und freue mich auf baldige Antworten!

Liebster Gruß,
paulupaul

[WillWissen]

Hi Paul,

bitte stelle uns eine anonymisierte Beispieldatei vor. Sie sollte exakt so aussehen wie sei Original.

[RPP63]

Hallo!
Die Domain einer Mail-Adresse erhälst Du so:

	A	B
1	x.y@Domain.de	Domain.de

Formeln der Tabelle

Zelle Formel B1 =TEIL(A1;FINDEN("@";A1)+1;99)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Nun kann man in der anderen Tabelle per Verweis() prüfen, ob sie vorhanden ist:
C1: =WENN(VERGLEICH(B1;Tabelle2!A1:A100;0);"Kunde";"kein Kunde")

Gruß Ralf

[paulupaul]

  TEST.xlsx (Größe: 55,4 KB / Downloads: 4) WillWissen pid='24974' dateline='1443607357']Hi Paul,

bitte stelle uns eine anonymisierte Beispieldatei vor. Sie sollte exakt so aussehen wie sei Original.

Hey WillWissen,

sehr vereinfach aber prinzipiell genau diese Liste verwende ich. Das rot markierte Feld (U2) ist das in dem ich gerne die Markierung "Kunde" finden möchte wenn die Domain in dem zweiten Blatt auftaucht.

Danke für die schnellen Antworten!

[paulupaul]

Hallo!
Die Domain einer Mail-Adresse erhälst Du so:

	A	B
1	x.y@Domain.de	Domain.de

Formeln der Tabelle

Zelle Formel B1 =TEIL(A1;FINDEN("@";A1)+1;99)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Nun kann man in der anderen Tabelle per Verweis() prüfen, ob sie vorhanden ist:
C1: =WENN(VERGLEICH(B1;Tabelle2!A1:A100;0);"Kunde";"kein Kunde")

Gruß Ralf

Hey Ralf,

auch Dir lieben Dank für die schnelle Antwort. 
Ich fürchte allerdings damit ist mein Problem immer noch nicht vollends abgedeckt :/

[RPP63]

Hi!

Ich fürchte allerdings damit ist mein Problem immer noch nicht vollends abgedeckt :/

Du musst natürlich schon die Vorschläge prüfen und auf Deine Belange anpassen.  :s

	F	U
1	Email address	Response type
2	T.xx@ab.se	Kunde

Formeln der Tabelle

Zelle Formel U2 =WENN(ISTFEHLER(VERGLEICH(TEIL(F2;FINDEN("@";F2)+1;99);Kunden!A:A;0));"kein Kunde";"Kunde")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß Ralf

[paulupaul]

Hi!

Du musst natürlich schon die Vorschläge prüfen und auf Deine Belange anpassen.  :s

	F	U
1	Email address	Response type
2	T.xx@ab.se	Kunde

Formeln der Tabelle

Zelle Formel U2 =WENN(ISTFEHLER(VERGLEICH(TEIL(F2;FINDEN("@";F2)+1;99);Kunden!A:A;0));"kein Kunde";"Kunde")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß Ralf

Hey hey!

Vielen lieben Dank!! Mit ein wenig hin- und herprobieren hat es endlich geklappt! 

Habe vor Tagen das erste Mal versucht dieses Problem zu lösen und von solchen Ketten über den S-Verweis alles probiert  :s 
Ihr seid genial und ich muss noch einiges lernen!  

Wunderbaren Tag allen die dies lesen!

[Jockel]

Hallo, alternativ ginge auch..:

=WENN(ZÄHLENWENN(Kunden!A:A;TEIL(F2;FINDEN("@";F2)+1;99))=0;"kein ";"")&"Kunde"

[paulupaul]

Hallo noch einmal!

Mit eurer Hilfe habe ich in Kombination mit einigen Teilen die ich bereits hatte, diese Monstrum geschaffen:

=VERKETTEN(WENN(ISTFEHLER(VERGLEICH(TEIL(F2;FINDEN("@";F2)+1;99);'Leads (Domain)'!A:A;0));"";"Lead ");WENN(R2="unsubscribed";"unsubscribed ";"");WENN(ISTFEHLER(VERGLEICH(TEIL(F2;FINDEN("@";F2)+1;99);'No interest (Domain)'!A:A;0));"";"No interest ");WENN(ISTFEHLER(VERGLEICH(TEIL(F2;FINDEN("@";F2)+1;99);'DNC (email address)'!A:A;0));"";"Don't contact ");WENN(ISTFEHLER(VERGLEICH(TEIL(F2;FINDEN("@";F2)+1;99);'Pos. resp. (email address)'!A:A;0));"";"positive response"))

Ich habe insgesamt 7 Blätter in die entweder komplette E-Mail-Adressen oder Domains kopiert werden (steht auch in den Klammern jeweils dahinter), jeweils nur in Spalte A wie die Profis in der Formel sicher sehen.
So weit, so gut. 
Nun bilden sich aber teilweise relativ lange und unübersichtliche Kombinationen (     ) aus den möglichen Worten.

Hier meine Frage: Gibt es eine Möglichkeit nur eines der Ergebnisse anzeigen zu lassen und eine gewisse Hierarchie zu hinterlegen? (Evtl. so etwas wie verketten nur mit einer Auswahl und Hierarchie statt Addition aller Werte die in Frage kommen) 

Ich hoffe das euch die Beschreibung reicht, dies anonym darzustellen würde wahrscheinlich genauso lange dauern wie diese Formel zu erstellen  :20:

Liebsten Dank noch einmal im Voraus!

[shift-del]

Hallo paulupaul

Ich hoffe das euch die Beschreibung reicht, dies anonym darzustellen würde wahrscheinlich genauso lange dauern wie diese Formel zu erstellen  [img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]

Kein Problem.

Du bekommst exakt einen Lösungsvorschlag von mir. Denn die Daten liegen ja genau so vor wie ich es mir vorstelle.

Code:

{=WENN(R2<>"";R2;VERWEIS(42;1/ZÄHLENWENN(INDIREKT("'"&$D$15:$D$18&"'!A:A");WAHL($F$15:$F$18;F2;TEIL(F2;FINDEN("@";F2)+1;99)));$D$15:$D$18))}

In D5:D15 stehen die Blattnamen und in F15:F18 steht 1 oder 2 (je nach dem ob Email oder Domain gesucht wird).