Gesamtbewertung aus verschiedenen Einzelbewertungen in einer Excelzeile

[AnneST]

Hallo,

Ich bräuchte etwas Hilfe mit einer Bewertung in Excel. Ich habe eine Tabelle, wo verschiedene Daten in Prozenten angegeben werden und je nach Prozentzahl mit A,B oder C (z.B. >90% mit A, 90-50% mit B und < 50% mit C) bewertet wurden. Jetzt möchte ich eine Gesamtbewertung erstellen von der Zeile, d.h. wenn ein Kriterium C ist soll die Gesamtbewertung auch C sein, wenn keine Bewertung mit C erfolgte, sondern mit B oder A soll die Gesamtbewertung B sein und nur wenn alle Einzelkriterien mit A bewertet wurden soll die Gesamtbewertung ein A sein. Für die Bewertung der Einzelkriterien (A,B,C) habe ich Formeln in der Tabelle hinterlegt. Leider finde ich keine Lösung, wie ich eine Gesamtbewertung hinbekomme. Ich habe bereits versucht A mit 1, B mit 2 und C mit 3 zu hinterlegen und wollte dann Max oder Min-werte anzeigen lassen, aber da sich in den Zellen Formeln und keine Zahlen befinden, zeigt es mir als Ergebnis immer Null an?! Hat jemand eine Idee, wie ich das besser machen könnte?
Vielen lieben Dank für eure Hilfe.
LG
Anne

[atilla]

Hallo Anne,

stell bitte einen Tabellenausschnitt oder eine Beispieldatei ein.

Lies dazu hier: http://www.clever-excel-forum.de/Forum-N...gshinweise

[shift-del]

Hallo

Code:

=WAHL((ZÄHLENWENN(D2:E2;"A")=ANZAHL2(D2:E2))+(ZÄHLENWENN(D2:E2;"C")>0)*2+1;"B";"A";"C")

[atilla]

Hallo shift-del,

stell bitte einen Tabellenausschnitt oder eine Beispieldatei ein.

Ich kann das nicht nachvollziehen :19:

[AnneST]

Vielen lieben Dank für eure schnelle Hilfe. Leider habe ich es mit der Formel noch nicht hinbekommen. Vielleicht habe ich ja etwas verkehrt gemacht???
Ich hänge meine Tabelle mal an. In der Auswertung soll dann bei "Gesamtbewertung" die Bewertung der Zeile stehen. Also in der ersten Zeile müsste C rauskommen in der zweiten B und in der dritten A.
Vielen Dank nochmal.
LG
Anne

[atilla]

Vielen lieben Dank für eure schnelle Hilfe. Leider habe ich es mit der Formel noch nicht hinbekommen. Vielleicht habe ich ja etwas verkehrt gemacht???

Hallo Anne,

da hat Detlef (shift-fdel) direkt ins Schwarze getroffen.
Du musst die Bereiche wie unten anpassen oder auf shift-del warten, wenn ich es falsch verstanden habe:

I2: =WAHL((ZÄHLENWENN(B2:H2;"A")=ANZAHL2(B2:E2))+(ZÄHLENWENN(B2:E2;"C")>0)*2+1;"B";"A";"C")

[lupo1]

In A1:A9 stehen Deine Buchstaben A, B oder C. Der höchste auftretende Buchstabe "verschmutzt" die Daten entsprechend mit

=ZEICHEN(MAX(INDEX(CODE(A1:A9&" ");)))

(Mit Datenüberprüfung sorgst Du im Vorfeld dafür, dass keine anderen Buchstaben erlaubt sind)

Stehen in A1:A9 statt dessen Werte zwischen 0 und 1, dann

=SVERWEIS(MIN(A1:A9);{0."C";0,5."B";0,9."A"};2) oder
=ZEICHEN(68-VERGLEICH(MIN(A1:A9);{0;0,5;0,9}))

[AnneST]

Es hat geklappt!!! Tausend Dank euch Beiden!!!
Ich hatte gestern vor lauter freudiger Aufregung über so schnelle Hilfe ganz vergessen, dass ich eine englische Version habe und die Formel nicht umgewandelt.
Ich wünsche euch ein schönes Wochenende und ich melde mich ganz bestimmt bald wieder, wenn ich wieder irgendwo festhänge ;)
Liebe Grüße,
Anne