Gesamtnotenberechnung aus Einzelnoten (war: schwierige Aufgabe)

[racecat]

Wollte meinem Enkel bei der Aufgabe unterstützen - bringe aber keine funktionierende Formel zusammen!
Bitte um Unterstützung :22:

[steve1da]

Hola,

dein Enkel braucht:
Anzahl()
Zählenwenn()
Mittelwert()
Wenn()

Gruß,
steve1da

[WillWissen]

Hi,

so?

Arbeitsblatt mit dem Namen 'Angabe'
	A	B	C	D
11	Schüler	Test-Note	Übungs-Note	Gesamt-Note
12	Bauer	4,2	5	5
13	Bytyqi	1,1	1,3	1
14	Fent	-	2,1	n.b.
15	Hochreiter	3,8	2,2	3
16	Jeremic	3,4	4,2	4
17	Kaar	2,1	2,5	2
18	Kouka	2,8	-	n.b.
19	Meier	4,8	4,5	5
20	Mihok	1,2	1,1	1
21	Müller	3,5	3,4	3
22	Obradovic	4,2	3,8	4
23	Ölmetz	-	-	n.b.
24	Peric	2,3	1,9	2
25	Pirhan	1,4	1,5	1
26	Won	2,9	2,3	3
27	Wurlitz	4,5	2,3	3
28	Mittelwert:	3,01	2,72	2,85

Zelle	Formel
D12	=WENN(ANZAHL(B12:C12)<2;"n.b.";RUNDEN(MITTELWERT(B12:C12);0))
B28	=RUNDEN(MITTELWERT(B12:B27);2)
C28	=RUNDEN(MITTELWERT(C12:C27);2)
D28	=RUNDEN(AGGREGAT(1;6;D12:D27);2)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[racecat]

Danke für die rasche Antwort!
2 Punkte sind noch nicht drin, wo ich trotzdem nicht zurechtkomme:
*) Sollte eine Note negativ sein (d.h. größer/gleich 4,5), so ist die Gesamt-Note: 5
*) Sind beide Noten positiv, so ergibt sich die Gesamt-Note zu 40% aus der Test-Note und zu 60% aus der Übungs-Note.
 Es eilt nicht, vielleicht hat da auch noch wer eine Lösung?
 
 

[WillWissen]

Hi,

ändere die Formel für die Einzelnote ab 4,5 so ab:

Code:

=WENN(ANZAHL(B12:C12)<2;"n.b.";WENN(ODER(B12>=4,5;C12>=4,5);5;RUNDEN(MITTELWERT(B12:C12);2)))

Dir werden jetzt Dezimalzahlen mit 2 Stellen angezeigt; diese Spalte musst du mit dem Zellenformat Zahl, 0 Dezimalstellen formatieren. Jetzt wird dir auch das Gesamtergebnis korrekt angezeigt.

Das mit den 40% und 60% verstehe ich nicht. Zeig mir bitte anhand einem Beispiel, was du meinst. Mit den vorgeschlagenen Formeln bekomme ich jedenfalls die in deinem Beispiel angeführten Wunschergebnisse (Ok, die Mittelwert/Gesamtnote weicht um 1/100 ab - ich denke aber, dass das der Rundung geschuldet ist.).

[snb]

Code:

=IF((B12="-")+(C12="-")>0;"nb";IF((B12>4,4)+(C12>4,4)>0;5;ROUND((4*B12+6*C12)/10;0)))

[racecat]

Ich versteh das so:
          Test-Note     Übungs-Note        Gesamt-Note
                4,5                 4,2                         4,32
Wenn die Summe 100% sein soll
4,5/100x40=1,8
4,2/100x60=2,52
     Summe=4,32

Wenn ich das in jeder Zeile händisch so rechne komm ich bei dem Gesamt-Note-Mittelwert auf die 3,07
aber das in einer Formel darstellen und ob das wirklich so richtig ist????

[steve1da]

Hola,

irgendwas muss das Enkelchen doch auch mal machen, oder?

Gruß,
steve1da

[racecat]

das stimmt, aber ich wollt mich einfach wichtig machen!!!
nochmals vielen Dank - ich hab auf jeden fall dazugelernt! :100:

[WillWissen]

Hi,

wenn dein Enkel meint, die Lösung gefunden zu haben, kannst du hiermit das Ergebnis überprüfen:

Arbeitsblatt mit dem Namen 'Angabe'
	A	B	C	D
11	Schüler	Test-Note	Übungs-Note	Gesamt-Note
12	Bauer	4,2	5	5
13	Bytyqi	1,1	1,3	1
14	Fent	-	2,1	n.b.
15	Hochreiter	3,8	2,2	3
16	Jeremic	3,4	4,2	4
17	Kaar	2,1	2,5	2
18	Kouka	2,8	-	n.b.
19	Meier	4,8	4,5	5
20	Mihok	1,2	1,1	1
21	Müller	3,5	3,4	3
22	Obradovic	4,2	3,8	4
23	Ölmetz	-	-	n.b.
24	Peric	2,3	1,9	2
25	Pirhan	1,4	1,5	1
26	Won	2,9	2,3	3
27	Wurlitz	4,5	2,3	5
28	Mittelwert:	3,01	2,72	3,07

Zelle	Formel
D12	=WENN(ANZAHL(B12:C12)<2;"n.b.";WENN(ODER(B12>=4,5;C12>=4,5);5;B12*40%+C12*60%))
B28	=RUNDEN(MITTELWERT(B12:B27);2)
C28	=RUNDEN(MITTELWERT(C12:C27);2)
D28	=RUNDEN(AGGREGAT(1;6;D12:D27);2)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg