Gesamtstunden für einen Tag mit unterschiedlichen Zeiten berechnen

[Rocco161]

Moin,

 

ich bin gerade dabei meine Stundennachweise für die Arbeit für mich digital zu festzuhalten.

 

Dabei bin ich an ein Problem gestoßen, welche meine Excel Kenntnisse leider überschreiten. Weiß hier vielleicht jemand, wie ich es hinbekomme, das in der rechten Spalte die Tagesgesamtstunden mit logischerweise Bezug auf das jeweilige Datum (automatisch) zusammengerechnet werden? Die Unterbrechungen der Zeiten müssen dort leider rein, da meine Arbeitszeitdoku je nach dem welche Tätigkeit ich gerade ausführe, variiert.

 

 

Anbei habt ihr die "Blanke" Version der Mappe.

  Blanko Version.xlsx (Größe: 11,57 KB / Downloads: 3)


Danke für mögliche Tipps schon einmal! :)

[echo]

Hallo
1. Uhr muss aus Spalte C:D raus, da sonst Text
2. Zellformat der Spalte N: Uhrzeit h:mm
3. Formel für N4 zum runter kopieren:

Code:

=WENN(ZÄHLENWENN(A4:$A$29;"="&A4)=1;SUMMENPRODUKT(($A$4:$A$28=A4)*($D$4:$D$28-$C$4:$C$28));"")

ZÄHLENWENN sorgt dafür das die Summe beim Letzen Eintrag von Datum angezeigt wird, SUMMENPRODUKT berechnet die Summe

Gruß Holger

[Rocco161]

Dankeschön für die Hilfe :)
Eine kleine Frage hätte ich noch. 
In der Formel wird für beispielsweise 3 Stunden Arbeitszeit ein Ergebnis von 0,08 angezeigt (ohne jegliche Zellenformatierung). Ich kann ja rein theoretisch per Zellenformatierung ein gewünschtes und richtiges Anzeigeformat auswählen jedoch finde ich keine Möglichkeit, das Ergebnis in Dezimalstunden anzeigen zu lassen. Gibt es eine Möglichkeit, dass noch in die Formel einzubauen?

[echo]

Hallo
Excel bewertet Uhrzeiten als Bruchteile eines Tages und nicht als Stunden.
3 Stunden sind halt mal 0,125 Tage. 
12 Stunden 1/2 Tag = 0,5 usw.

0,08 = 1:55:12 

Möchtest du den Dezimalwert (Industriezeit) haben, so multipliziere das Ergebnis mit 24.

Gruß Holger

[LCohen]

N4: =(A4<>A5)*SUMME({-1.1}*INDEX(C$4:D4;ZEILE(N4)-3;):INDEX(C$4:D4;VERWEIS(2;1/(A$3:A3<>A$4:A4);ZEILE(N$4:N4)-3);))
benDefFmt hh:mm;;

ist etwas länger und schlechter lesbar als echos Lösung, aber "ordnungspolitisch" besser, da bei echo "1,5x exponenziell" (ZÄHLENWENN und SUMMENPRODUKT). Zugegeben: Das merkt man hier bei den wenigen Zeilen noch lange nicht. Aber man sollte doch bereit sein, Formeln auch optimiert zu schreiben. Dann wirkt sich nur der VERWEIS "0,5x exponenziell" aus.

[BoskoBiati]

Hi,

die vorgestellte Formel von Holger entspricht aber nicht der Syntax von Zählenwenn:

Code:

=WENN(ZÄHLENWENN(A4:$A$29;A4)=1;SUMMENPRODUKT(($A$4:$A$28=A4)*($D$4:$D$28-$C$4:$C$28));"")

Da die Datumswerte chronologisch sind, reicht das:

=WENN(A6<>A5;SUMMENPRODUKT(($A$4:A5=A5)*($D$4:D5-$C$4:C5));"")

[LCohen]

Sein ZÄHLENWENN funktioniert. Du hast nur erkannt, dass man es nicht benötigt. "0,5x exponenziell" hast Du jetzt weg. "1x exponenziell" bleibt Dir aber noch via SUMMENPRODUKT.

Mit Pivot bzw. Power Pivot wäre es sogar "0x exponenziell". Aber dann müsste man zuviel rumfummeln, um die Daten in dem Formular an die richtige Stelle zu bekommen.

[BoskoBiati]

Hi,
mich hat nur das gestört:

Code:

ZÄHLENWENN(A4:$A$29;"="&A4)