Herauslesen und Verketten

[Albina_96]

Hallo zusammen,

ich bin hier ganz neu und habe zwar schon geguckt, ob es ein ähnliches Thema gibt, aber dem scheint nicht so zu sein, dehslab nun mein Problem:

Im ersten Tabellenblatt (Tabelle 1) ist eine Tabelle bestehend aus zwei Spalten.
Spalte A heißt "Pallete", Spalte B "Code". Jeder Code ist einer Pallete zugeordnet.
Das Problem hierbei ist, dass manche Codes doppelt vorkommen.
Deswegen, habe ich in einem neuem Tabellenblatt (Tabelle 2) alle Codes eindeutig auslesen lassen: also, dass jeder Code nur noch einmal auftaucht. Nun möchte ich, dass die Palettennummern aus Spalte A (Tabelle 1) für den jeweiligen Code ausgelesen werden. Diese müssen ggf verkettet werden, da für ein- und denselben Code mehrere Palleten vorhanden sein könnten.

Kann mir hierbei irgendjemand helfen?
Eine Beispieldatei ist angehangen.
Schonmal vielen Dank im Voraus!

[Klaus-Dieter]

Hallo,

zwei dinge sind mir aufgefallen:

1. es gibt in deiner Liste verbundenen Zellen, das führt nur zu Problemen.
2. verschiedene Werte in einer Zelle, durch Komma getrennt, geht gar nicht.

[shift-del]

Moin

Für Abonnenten und Onliner:

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	A	B	C	D	E
1	Pallete	Code		Code
2	1	aaa		aaa	1, 4
3	2	abb		abb	2
4	3	aba		aba	3, 8
5	4	aaa		abc	5, 9
6	5	abc		abd	6
7	6	abd		cde	7
8	7	cde		cdf	7
9	7	cdf		cdg	7
10	7	cdg		dge	10
11	8	aba
12	9	abc
13	10	dge

Zelle	Formel
D2	=EINDEUTIG(B2:B13)
E2	=TEXTVERKETTEN(", ";WAHR;MTRANS(FILTER(A2:A13;B2:B13=D2)))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[Albina_96]

Hallo,
danke für deine Antwort.
Es mag sein, dass verbundene Zellen Probleme verursachen aber genau dafür ist doch so ein Forum da, oder?
Die Datei, die ich als Beispiel angehangen habe ist um ein Vielfaches reduziert und vereinfacht worden, nur um das Problem veranschaulichen zu können. In der Originaldatei handelt es sich um einige Spalten und Zeilen mehr. Dort alle verbundenen Zellen erst manuell trennen zu müssen, wäre etwas aufwendig. Wenn du einen Lösungsvorschlag dazu hättest, würde ich ihn mir gerne anschauen.
Und zu zweitens: Die Werte können auch gern durch ein Semikolon getrennt werden. Daran soll es nun nicht scheitern.

VG Albina

---

Hallo Shift-Del,

Danke für deinen Lösungsvorschlag!
Leider gibt es bei mir die Funktionen EINDEUTIG, TEXTVERKETTEN und FILTER nicht. Statt TEXTVERKETTEN kann man bestimmt auch normal VERKETTEN nehmen oder? Und gibt es für FILTER eine Alternative?

Danke!!

VG Albina

[shift-del]

Ich wollte dich nur auf den Geschmack bringen um auf die Abo-Version umzusteigen, Albina.

Formel-Lösungen für ältere Versionen sind um einiges länger.

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1	Pallete	Code		Code	Paletten		Code	Paletten		Paletten	Code	1	2	3	4
2	1	aaa		aaa	1, 4		aaa	1, 4		aaa	2, 5	2	5
3	2	abb		abb	2		aba	3, 8		abb	3	3
4	3	aba		aba	3, 8		abb	2		aba	4, 11	4	11
5	4	aaa		abc	5, 9		abc	5, 9		abc	6, 12	6	12
6	5	abc		abd	6		abd	6		abd	7	7
7	6	abd		cde	7		cde	7		cde	8	8
8	7	cde		cdf	7		cdf	7		cdf	9	9
9	7	cdf		cdg	7		cdg	7		cdg	10	10
10	7	cdg		dge	10		dge	10		dge	13	13
11	8	aba								#NV
12	9	abc								#NV
13	10	dge								#NV
14
15				18	58					63	52	69	69	69	69

Zelle	Formel
D2	=EINDEUTIG(B2:B13)
E2	=TEXTVERKETTEN(", ";WAHR;MTRANS(FILTER(A2:A13;B2:B13=D2)))
J2	=INDEX($B$2:$B$13;VERGLEICH(0;ZÄHLENWENN(J$1:J1;$B$2:$B$13);0))
K2	=WECHSELN(GLÄTTEN(L2&" "&M2&" "&N2&" "&O2);" ";", ")
L2	=WENNFEHLER(AGGREGAT(15;6;ZEILE($B$2:$B$13)/($B$2:$B$13=$J2);L$1);"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

Als weitere Lösung gibt es noch die Datenmodell-Pivot mit einem Measure.

[Jockel]

Hallo, man kann aber alternativ Power Query einsetzen, in der angegebenen Version zwar noch nicht impementiert, aber das kann man ja mit dem kostenlosen Add-In nachholen...

[Albina_96]

Hallo shift-del,

und wieder einmal danke für die Lösung!
Sieht auf jeden Fall super aus. Die Kombination aus Index, Vergleich und Zählenwenn habe ich auch bereits so benutzt.
Nur komme ich beim Rest nicht ganz mit.
Woher kommen die Daten aus Spalte G und H? Gibst du bei L1 einfach die 1 ein und ab L2 dann die Formel? Die Formel funktioniert bei mir übrigens nicht. Der Divisionsteil "/($B$2:$B$13=$J2)" ruft einen Fehler hervor.
So habe ich die Formel eingegeben: =WENNFEHLER(AGGREGAT(15;6;ZEILE($A$2:$A$13)/($A$2:$A$13=$J5);L$1);"")
Ich habe es auch mit Strg+Shift+Enter und einfach nur Enter ausprobiert. ändert leider nichts daran.

Und was haben die Zahlen in Spalte L überhaupt zu bedeuten? Sie gehen ja bis 13 also sind es nicht die Paletten-Nr. oder handelt es sich hierbei nur um die Zeilennummern? Gibt man bei Spalten M-O dann die gleiche Formel wie bei Spalte L ein nur halt statt dem L am Ende den jeweils anderen Buchstaben?

Sorry, für die vielen Fragen!! Ich hoffe, du kannst mir trotzdem weiterhelfen. :)


Hallo Jockel,

da es sich hier um Excel auf Arbeit handelt, werde ich wohl eher die Finger von Add-Ins und sonstigem lassen müssen. Aber trotzdem danke für den Hinweis. :)

VG Albina

[Jockel]

...
Hallo Jockel,
da es sich hier um Excel auf Arbeit handelt, werde ich wohl eher die Finger von Add-Ins und sonstigem lassen müssen. Aber trotzdem danke für den Hinweis. :)
VG Albina

Aber gerade da wird Power Query sicher immer wichtiger. es ist ein kostenloses Add-In von Microsoft. Safe. Und absolut unbedenklich... Ab XL2016 ist es eh fester Bestandteil...

[shift-del]

Ein paar Fehler ausradiert.

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
1	Pallete	Code		Code	Paletten		Code	Paletten		Paletten	Code	1	2	3	4
2	1	aaa		aaa	1, 4		aaa	1, 4		aaa	1, 4	1	4
3	2	abb		abb	2		aba	3, 8		abb	2	2
4	3	aba		aba	3, 8		abb	2		aba	3, 8	3	8
5	4	aaa		abc	5, 9		abc	5, 9		abc	5, 9	5	9
6	5	abc		abd	6		abd	6		abd	6	6
7	6	abd		cde	7		cde	7		cde	7	7
8	7	cde		cdf	7		cdf	7		cdf	7	7
9	7	cdf		cdg	7		cdg	7		cdg	7	7
10	7	cdg		dge	10		dge	10		dge	10	10
11	8	aba								#NV
12	9	abc								#NV
13	10	dge								#NV
14
15				18	66					63	52	82	82	82	82

Zelle	Formel
D2	=EINDEUTIG(B2:B13)
E2	=TEXTVERKETTEN(", ";WAHR;MTRANS(FILTER($A$2:$A$13;$B$2:$B$13=D2)))
J2	=INDEX($B$2:$B$13;VERGLEICH(0;ZÄHLENWENN(J$1:J1;$B$2:$B$13);0))
K2	=WECHSELN(GLÄTTEN(L2&" "&M2&" "&N2&" "&O2);" ";", ")
L2	=WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE($B$2:$B$13)/($B$2:$B$13=$J2);L$1));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

Spalte G und H ist die Lösung mit Datenmodell-Pivot.
Die Formeln werden nach unten kopiert und die Formel in L2 auch nach rechts.
Du kannst ja mal die Zahlen in L1:O1 weg lassen und schauen was passiert.

[Klaus-Dieter]

Hallo Albina,

Es mag sein, dass verbundene Zellen Probleme verursachen aber genau dafür ist doch so ein Forum da, oder?

genau, ein Forum ist dazu da, vor der Verwendung solcher Dinge zu warnen. Das habe ich getan. Das Problem der verbundenen Zelle ist es ganz einfach, dass viele Excel-Funktionen dadurch behindert werden. Du kannst ja mal versuchen, so eine Liste zu sortieren.  :05: 

Im übrigen ist es so, dass die Zellen nicht wirklich verbunden werden, sondern die linke, obere Zelle des Verbundbereichs, wird einfach auf den gewählten Bereich vergrößert. Die anderen zellen sind noch da, nur sieht man sie eben nicht.