Hilfe für einen Anfänger

[Tschoko]

Hallo zusammen,

ich versuche eine Ausgabe zu erstellen zu einem Produkt was hergestellt werden soll. In der Beispieltabelle wird bei B2 über Dropdown das Produkt ausgewählt. Die Daten der Produkte und was für Teile die Produkte benötigen werden in einer Extratabelle angelegt. Die Ausgabe sollte nur wirklich anzeigen was das Produkt zum herstellen benötigt. Wenn z.B. wie beim Schrank keine Nägel gebraucht werden, dann sollte es bei der Ausgabe nicht erscheinen. 
Wie mache ich das am besten? 

Schönen Gruß
Tschoko


  Beispiel.xlsx (Größe: 9,99 KB / Downloads: 10)

[Jockel]

Hallo, eine Formellösung könnte so aussehen..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
19	Ausgabe
20	Produkt	Material	Anzahl
21	Tisch	Schrauben	12
22		Dübel	5
23		Knöpfe	0

Zelle	Formel
B21	=INDEX($B$6:$E$6;;ZEILE(A1))
C21	=INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);ZEILE(A1))

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Tschoko]

Hallo, das funktioniert Super. Herzlichen Dank hierfür. Kann man bei der Ausgabe die Sachen, z.B. bei den Knöpfen wo 0 steht, die Zeile weglassen mit Knöpfe. Kann man das irgendwie nicht anzeigen lassen wenn da 0 ist?

[Jockel]

Hallo, ich würde das aber nicht per Formel machen die würde unnötig verlängert. Sondern per benutzerbedingten Formatierung "0;;" Ohne " "

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
19	Ausgabe
20	Produkt	Material	Anzahl
21	Tisch	Schrauben	12
22		Dübel	5
23		Knöpfe
24		Nägel	3

Zelle	Format	Wert
C21	0;;	12

Zelle	Formel
B21	=INDEX($B$6:$E$6;;ZEILE(A1))
C21	=INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);ZEILE(A1))

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Tschoko]

Dann ist die Null weg und wie bekomm ich vorne die Knöpfe weg? Kann man die komplette Zeile löschen so das die Nägel nach oben rutschen? Geht sowas?

[Jockel]

Hallo, ja...: 

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
20	Produkt	Material	Anzahl
21	Tisch	Schrauben	12
22		Dübel	5
23		Nägel	3
24

Zelle	Formel
A21	=auswahl
B21	=WENNFEHLER(INDEX($B$6:$E$6;;AGGREGAT(15;6;SPALTE($A$1:$D$1)/(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);0)<>0);ZEILE(A1)));"")
C21	=WENNFEHLER(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);AGGREGAT(15;6;SPALTE($A$1:$D$1)/(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);0)<>0);ZEILE(A1)));"")
B22	=WENNFEHLER(INDEX($B$6:$E$6;;AGGREGAT(15;6;SPALTE($A$1:$D$1)/(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);0)<>0);ZEILE(A2)));"")
C22	=WENNFEHLER(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);AGGREGAT(15;6;SPALTE($A$1:$D$1)/(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);0)<>0);ZEILE(A2)));"")
B23	=WENNFEHLER(INDEX($B$6:$E$6;;AGGREGAT(15;6;SPALTE($A$1:$D$1)/(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);0)<>0);ZEILE(A3)));"")
C23	=WENNFEHLER(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);AGGREGAT(15;6;SPALTE($A$1:$D$1)/(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);0)<>0);ZEILE(A3)));"")
B24	=WENNFEHLER(INDEX($B$6:$E$6;;AGGREGAT(15;6;SPALTE($A$1:$D$1)/(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);0)<>0);ZEILE(A4)));"")
C24	=WENNFEHLER(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);AGGREGAT(15;6;SPALTE($A$1:$D$1)/(INDEX($B$7:$E$8;VERGLEICH($A$21;$A$7:$A$8;0);0)<>0);ZEILE(A4)));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Frogger1986]

Ich hätte ein umstrukturiertes Beispiel mit einer intelligenten Tabelle.

[Tschoko]

Wow super. Funktioniert alles. Herzlichen Dank Jockel für deine Hilfe.
Auch dir Frogger für die Mühe. Das von Jockel funktioniert und das lass ich jetzt lieber so

[Jockel]

Hallo, als kleines easteregg habe ich eine Power Query Variante mit dazu eingebaut... War eine schöne kleine Übun (PQ ist ja ab der angegebenen Version kostenfrei implementierbar...) Die Tabelle ist erweiterbar. Einziges "Manko" man muss auf die PQ Tabelle (ab G6) klicken und Aktualisieren... Also wer Lust hat (oder und Verbesserungsvorschläge)  tadaa...


  20200410_easteregg.xlsx (Größe: 21,6 KB / Downloads: 6)