Hyperlink mit indirektem Zellbezug

[Huzzim]

Hallo,

ich habe ein Problem mit einer Hyperlink-Formel. Folgende Formel funktioniert wie gewünscht:

Code:

=HYPERLINK(
    "C:\Pfad\" &
    WENN(UND(ISTTEXT(B8); B8="B");
    "B"; "Q") & Fortschritt!$D$41 & ".xlsm";
    )

Ich möchte den Zellbezug zu B8 aber dynamisch gestalten (Zelle B8 ist immer zwei Zeilen darüber, eine Spalte nach rechts), deshalb mein Ansatz:

Code:

=HYPERLINK(
    "C:\Pfad\" &
    WENN(UND(ISTTEXT(INDIREKT(ADRESSE(ZEILE()-2; SPALTE()+1)));
    INDIREKT(ADRESSE(ZEILE()-2; SPALTE()+1))="B");
    "B"; "Q") & Fortschritt!$D$41 & ".xlsm";
    )

Bei der zweiten Formel formatiert Excel die Zelle als Hyperlink. Wenn ich dann draufklicke, öffnet sich keine Datei. Wenn ich mit der Maus darüber schwebe, erscheint auch nicht eine Vorschau für den (nicht) generierten Link. Hat Excel Probleme mit Hyperlink + indirekte Adresse? Wie kann ich meine Formel umbauen, damit ich dynamisch auf B8 referenziere?

Danke & Gruß
Huzzim

//e
Beispieldatei angehängt

[snb]

PHP-Code:

=HYPERLINK("C:\Pfad\" & IF(INDIRECT((ADDRESS(ROW()-2;COLUMN()+1)))="B";"B";"Q") &Fortschritt!$D$41 & ".xlsm") 


[maninweb]

Hallo,

Du könntest folgende Formel in A10 verwenden ...

PHP-Code:

=HYPERLINK("C:\Pfad\"&WENN(BEREICH.VERSCHIEBEN(A10;-2;1;1;1)<>"B";"Q";"B")&Fortschritt!$D$41&".xlsm") 


Gruß

[Huzzim]

Beim Lösungsansatz von snb ändert bleibt bei mir das Problem eines Links, der nichts öffnet.

Mit der Formel von maninweb klappts.

Danke für die Hilfe!