INDEX & VERGLEICH mit 2 Variablen (Datum)

[Avdbos]

Hallo Liebe Forums-Mitglieder,

ich werde leider nicht fündig und komme mit einem Problem einfach nicht weiter. Ich hoffe mir kann jemand mit meiner Matrix Formel weiterhelfen. Das wäre wirklich fantastisch!!  :15:

Das Grundproblem ist folgendes: Ich bekommen eine Datentabelle per Schnittstelle mit Kontosalden, welche ich analysieren muss. Leider gibt es nicht für jeden Tag eine Saldo Information, sondern immer nur dann wenn es eine Bewegung auf dem Konto gegeben hat und sich der Saldo verändert hat. Die Datentabelle kann ich von der Struktur her auch nicht bearbeiten. 
Ich brauche für meine Analyse aber immer einen Überblick über den Saldo für die 14 Tage. Sprich wenn es zB keine Kontobewegung in den letzten Tagen gegeben hat, dann muss halt in meiner Analyse der älteste Eintrag, welcher vorhanden ist angezeigt werden. Genau hier scheitere ich dran!  
Ich bekomme mittels VERGLEICH von zwei Suchkriterien (Kontonummer & Datum) zwar mit dem "Vergleichstyp 1" der Sache schon ziemlich nahe aber leider tauchen dann doch immer noch einige Fehler auf.
Ich befürchte, dass ich den Vergleichstyp 1 hier nicht verwenden kann, da einfach zu ungenau und fehleranfällig, ich habe aber auch keine Idee, wie ich sonst an das "nähste" Datum für meine Analyse Matrix kommen könnte.

Zur Verdeutlichung habe ich eine Excel Tabelle abgehangen. Im Grunde funktioniert meine Analyse für KONTO A-D soweit, allerdings schlägt meine Formel bei Konto E fehl (rot markiert). Meine originale Datei ist natürlich noch wesentlich komplexer und beinhaltet auch noch Fehler dich nicht mehr nachvollziehen kann, wie Excel hier bei der VERGLEICH Suche auf diese Werte kommen könnte aber für das Beispiel, halte ich es jetzt mal etwas simpler.

Kann mir jemand vielleicht freundlicherweise einen Tipp geben, wie ich die Formel verbessere, so dass nicht einfach irgendwelche Werte genommenem werden, sondern wirklich nur die Werte der entsprechenden Konten?

Das wäre wirklich sehr freundlich und ich bedanke mich schon mal im Vorfeld für alle Ideen und Vorschläge.

Danke
Arjen

[Jockel]

Hallo, probier mal so..:

Code:

=WENNFEHLER(INDEX($C$3:$C$21;AGGREGAT(14;6;ZEILE($A$3:$A$21)-2/($A$3:$A$21=$A26)/($B$3:$B$21<=B$25);1));"")

[Der Steuerfuzzi]

Hallo,

EDIT: Ich sehe gerade, dass wohl die alten Stände mitgezogen werden sollen, daher ist meine Formel leider falsch! Daher gelöscht.

[Ego]

Hallo Arjen,

du kannst auch deine Formel erweitern.
Du must nur dafür sorgen dass alle Zeilen, bei denen die Kontonummern nicht übereinstimmen zu einem Fehler führen und mit Wennfehler diesen abfangen. zB:

Code:

{
=WENNFEHLER(INDEX(Tabelle1[Schlußsaldo];VERGLEICH($A26&B$25;LINKS(Tabelle1[Kontonummer]&Tabelle1[Auszugsdatum];99/(Tabelle1[Kontonummer]=$A26));1));"")
}

[Der Steuerfuzzi]

Hallo,

hier noch eine Variante mit VERWEIS:

Code:

B26 =WENNFEHLER(INDEX(Tabelle1[Schlußsaldo];VERWEIS(1;1/(Tabelle1[Kontonummer]=$A26)/(Tabelle1[Auszugsdatum]<=B$25);ZEILE(Tabelle1[Kontonummer]))-2);"")

[Avdbos]

@ Jockel. Vielen Dank . Genau das halt geholfen. Mittels AGGREGAT hat's geklappt. Mir war die Formel so nicht bekannt, daher um so schöner wieder etwas gelernt zu haben.

Thema ist für mich hier erfolgreich beendet! 

nochmals danke für den super schnellen Input!

Gruß
Arjen

[Jockel]

Hallo, alternativ ginge auch..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O
24	Cashflow Analyse Matrix
25		17.04.2017	18.04.2017	19.04.2017	20.04.2017	21.04.2017	22.04.2017	23.04.2017	24.04.2017	25.04.2017	26.04.2017	27.04.2017	28.04.2017	29.04.2017	30.04.2017
26	KONTO A	1800	1900	2000	2000	2100	2100	2100	2200	2300	2300	2300	2400	2400	2400
27	KONTO B	2600	2600	2600	2600	2600	2600	2600	2600	2600	2600	2600	2600	2600	2600
28	KONTO C	2800	2800	2800	2800	2900	2900	2900	3000	3100	3100	3100	3200	3200	3200
29	KONTO D	3300	3300	3300	3300	3300	3300	3300	3300	3300	3300	3300	3300	3300	3400
30	KONTO E														3500

Zelle	Format	Wert
B26	Standard;;	1800

Zelle	Formel
B26	=MAX(INDEX($C$3:$C$21*($A$3:$A$21=$A26)*($B$3:$B$21<=B$25);))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Ego]

Hallo Arjen,

Achtung: Jockels Alternative ist nur dann richtig, wenn -wie in deinem Beispiel- das Schlusssaldo pro Kontonummer monoton steigend ist.

[Jockel]

Hallo Arjen,

Achtung: Jockels Alternative ist nur dann richtig, wenn -wie in deinem Beispiel- das Schlusssaldo pro Kontonummer monoton steigend ist.

Ähhhh...? Was stimmt mit der Variante denn nicht..?