ISTLEER Formel Problem

[benutzer der 1.]

leute ich brauche Hilfe :)

ich versuche seit Tagen diese Formel zu knacken leider ohne erfolg.

ich möchte wenn mindestens einer von 5 Feldern Leer ist, soll "5 Eintrag fehlt" erscheinen.

Leider sagt mir excel immer das zu viele bedingungen in der formel stehen.

PHP-Code:

=WENN(ODER(ISTLEER([@Wiederkehrend]);([@[Was ist zu tun?]]); ([@Zuständig]); ([@Terminabschluss]); ([@[Fristeinstellung in Tagen]]));"5 Eintrag fehlt";"") 


Wenn die Obere Formel funktioniert möchte ich die obere mit der Unteren zusamenknüpfen. Die untere Formel funktioniert nur die obere funktioniert nicht .

PHP-Code:

=WENN(ISTZAHL([@[Erledigt am:]]);"4 Erledigt";WENN(ODER(ZAHLENWERT([@[Deadline in Tage ]])<0; UND(ZAHLENWERT([@[Deadline in Tage ]])>1; (ZAHLENWERT([@[Deadline in Tage ]])<4))); "1 Sehr Wichtig ";WENN(UND(ZAHLENWERT([@[Deadline in Tage ]]) >3;ZAHLENWERT([@[Deadline in Tage ]])<18);"2 Wichtig";WENN(UND(ZAHLENWERT([@[Deadline in Tage ]]) > 17;ZAHLENWERT([@[Deadline in Tage ]])<32);"3 Normal";"")))) 


Was mache ich falsch?

[Jockel]

leute ich brauche Hilfe :)
...
Was mache ich falsch?

Hallo, du postest keine (Beispiel)Datei... wo man die relevanten Zellen sehen kann und was du genau vorhast...

... aber das hattest du beim letzten Mal auch schon "vergessen"...

[benutzer der 1.]

Ja stimmt ich dachte wieder an einfacher so ist drin :)

[MisterBurns]

Du gebrauchst den ODER-Teil falsch. Jede Möglichkeit muss mit ISTLEER abgefragt werden

Code:

=WENN(ODER(ISTLEER([@Wiederkehrend]);ISTLEER([@[Was ist zu tun?]]);ISTLEER([@Zuständig]);ISTLEER([@Terminabschluss]);ISTLEER([@[Fristeinstellung in Tagen]]));"5 Eintrag fehlt";"")

Ginge vermutlich wesentlich kürzer und einfacher mit ANZAHLLEEREZELLEN.

[benutzer der 1.]

Vielen vielen Dank komischer weise hatte ich die Formel auch ausprobiert leider weiß ich nicht was dann noch falsch war

Super vielen Vieln Dank :)
Daran lag das aber verstehe.

Nur eine frage stellt sich noch für mich

Bei der Formel die du geschickt hast wie bekomme ich noch hin wenn alle 5 felder leer sind soll auch die zelle leer sein ("5 Eintrag fehlt")??

das war für mich genauso ein rätzel??

[Jockel]

Hallo, was wird das mit ZAHLENWERT()...? ... SUMME([@[Fristeinstellung in Tagen]])  was soll SUMME() hier ..? Das ganze Konstrukt ist mir zu "hoch" am späten Abend... ... ich bin raus... sorry, viel Erfolg noch.

[benutzer der 1.]

Dennoch Danke Jockel "Daumen hoch"

[shift-del]

Ginge vermutlich wesentlich kürzer und einfacher mit ANZAHLLEEREZELLEN.

Ja, man muss nur die fünf Felder nebeneinander setzen.

Code:

=ANZAHLLEEREZELLEN(Tabelle1[@[Wiederkehrend]:[Fristeinstellung in Tagen]])>0

---

@benutzer der 1.
Die Prioritätsformel hat Lücken bei den Werten 0 und 1. Ist das Absicht?

[MisterBurns]

Code:

=WENN(UND(ISTLEER([@Wiederkehrend]);ISTLEER([@[Was ist zu tun?]]);ISTLEER([@Zuständig]);ISTLEER([@Terminabschluss]);ISTLEER([@[Fristeinstellung in Tagen]]));"";WENN(ODER(ISTLEER([@Wiederkehrend]);ISTLEER([@[Was ist zu tun?]]);ISTLEER([@Zuständig]);ISTLEER([@Terminabschluss]);ISTLEER([@[Fristeinstellung in Tagen]]));"5 Eintrag fehlt";""))

Erscheint mir aber ziemlich unsinnig das Konstrukt, die Formel ist ja kaum noch nachzuverfolgen.

[Cadmus]

hallo,

Vorschlag:

Code:

=WENN(ANZAHL2([@Wiederkehrend];[@[Was ist zu tun?]];[@Zuständig];[@Terminabschluss];[@[Fristeinstellung in Tagen]])=0;"";WENN(ANZAHL2([@Wiederkehrend];[@[Was ist zu tun?]];[@Zuständig];[@Terminabschluss];[@[Fristeinstellung in Tagen]])<5;"5-Eintrag fehlt";WENN(ISTZAHL([@[Erledigt am:]]);"4 Erledigt"; SVERWEIS(MAX(@[[Deadline in Tage ]];0);{0."1-Sehr Wichtig";4."2-Wichtig";18."3-Normal";32.""};2;1))))