Inch in cm umrechnen

[mrtc]

Hallo,

wüsste jemand eine Lösung wie ich folgendes einfach oder am einfachsten umrechnen könnte.
Also von Inch in cm.

aus 3,1"/3,5" sollte 8/9 cm werden.

Die Datei ist leider rießig und somit ist es händisch einfach nicht machbar.

[WillWissen]

Hi,

Voraussetzung, deine Maße sind einzeln in der Zelle (sonst müsstest du sie eventuzell mit Text in Spalten extrahieren):

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	3,1	7,874

Zelle	Formel
B1	=UMWANDELN(3,1;"in";"m")*100

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[mrtc]

leider sind sie nicht einzeln, sondern genau so in einer Spalte: 3,1"/3,5"

Wie könnte ich beide trennen, also in 3,1 und 3,5?

[WillWissen]

Hi,

da bleibt dir nichts anderes übrig, als sie zu trennen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	3,1"/3,5"	3,1	3,5	7,9	8,9

Zelle	Formel
B1	=LINKS(A1;3)
C1	=TEIL(A1;FINDEN("/";A1)+1;3)
D1	=RUNDEN(UMWANDELN(B1;"in";"m")*100;1)
E1	=RUNDEN(UMWANDELN(C1;"in";"m")*100;1)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

---

oder, wie gewünscht einstellig und zusätzlich wieder als Text für eine Zelle. Die farbig markierten Spalten kannst du nach der Aktion entweder ausblenden oder du markierst die Ergebnisspalte und fügst sie als Werte wieder ein und löscht dann die Hilfsspalten.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	3,1"/3,5"	3,1	3,5	8	9	8 cm / 9 cm

Zelle	Formel
B1	=LINKS(A1;3)
C1	=TEIL(A1;FINDEN("/";A1)+1;3)
D1	=RUNDEN(UMWANDELN(B1;"in";"m")*100;0)
E1	=RUNDEN(UMWANDELN(C1;"in";"m")*100;0)
F1	=D1&" cm / "&E1&" cm"

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[mrtc]

Perfekt :28:

Herzlichen Dank für die schnelle Antwort.

[LCohen]

Für Dein nächstes Excel (365, 2019 oder Online): Ohne Hilfszellen, gerundet auf 1 Nachkomma (=mm), für bis zu 5 Werte:

B1: =WECHSELN(TEXTVERKETTEN(" cm/";;RUNDEN(UMWANDELN(GLÄTTEN(TEIL(WECHSELN(WECHSELN($A1&"/0/0/0/0/0";"""";);"/";WIEDERHOLEN(" ";39));SPALTE(A1:E1)*39-38;39));"in";"cm");1))&" cm";"/0 cm";)

[RPP63]

Moin!
Außer Konkurrenz mal die Konkurrenz (Google Sheets):
=ARRAYFORMULA(TEXTJOIN("cm/";1;ROUND(SPLIT(SUBSTITUTE(A1;"""";"");"/")*2,57;1)))&"cm"

EDIT:
Korrekt ist natürlich die Umrechnung 2,54
obige Formel führt dann zu 7,9cm/8,9cm

   

Gruß Ralf

[WillWissen]

Moin Ralf,

da geht Google von einem höheren Wissensstand als MS und setzt voraus, dass der User den Faktor kennt. Wenn ich so darüber nachdenke, hatte ich im Laufe meines Lebens schon Faktoren von 2,2 bis hin zu Zahlen mit 3 Dezimalstellen gehört. Am häufigsten ist die "Schnellumwandlung" mit 2,5 und 2,6 zuhören gewesen.

[RPP63]

Google Sheets kann das auch, war mir in obiger Formel erstmal zu "kompliziert".
=CONVERT(3,1;"in";"m")*100
ergibt 7,874

Gruß Ralf

[LCohen]

Google war schon bei =SORT() und =FILTER() Vorreiter ... und MS wird mit =AUFTEILEN() oder =SPLITTEN() hoffentlich auch hier folgen. Eine logische Folge der impliziten Matrix.

(=SPLIT() ist ja die Gegenfunktion zu =TEXTJOIN() ... dann braucht es meine Mehrfach-Hampelei nicht mehr)