Index mit 2 Vergleichen

[dertommy]

Hallo!

Folgende IST-Situation:

In Tabelle1 befinden sich von Q1 bis V1 eine Jahreszahl. Von P17 bis P19 steht jeweils ein Name. Von Q17 bis V17 stehen zu dem Namen jeweils eine Zahl.
In Tabelle2 befinden sich von Q6 bis Q8 jeweils der gleiche Name, wie von Tabelle 1 P17 bis P19.
Nun möchte ich in Tabelle2 in R6 den höchsten Betrag auf Bezug von Q6 auf die Tabelle1 P17 ermitteln und dann soll er mit in R6 nur die Jahreszahl hinschreiben.

Ich hoffe, ihr kennt euch aus. Ich habe ein Beispiel mit angehängt.

LGThomas

[Ego]

Hallo LGThomas,

bitte sehr:

Code:

=INDEX(Tabelle1!$Q$1:$V$1;;VERGLEICH(MAX(INDEX(Tabelle1!$Q$17:$V$19;VERGLEICH(Q6;Tabelle1!$P$17:$P$19;0);));INDEX(Tabelle1!$Q$17:$V$19;VERGLEICH(Q6;Tabelle1!$P$17:$P$19;0););0))

[dertommy]

Hallo Helmut!

Danke sehr, du hast mir sehr geholfen. Da wäre ich von alleine nie draufgekommen.

LG
Thomas

---

Ich hätte noch eine Frage. Du hast am Anfang der Formel zwei ;; gemacht, ist das bewusst so, oder gehört nur eines? Funktionieren tut es komischer Weise mit einem bzw. auch mit zwei.

LG
Thomas

[Ego]

Hallo Thomas,

normalerweise ist die Spalte, die hier gesucht wird, der dritte Parameter der Indexfunktion (daher mein ";;"). Wenn die Matrix aber nur eine Zeile hat, kann man den Zeilenparameter auch weglassen.

[dertommy]

Hallo Helmut!

Danke sehr für die Erläuterungen, es leuchtet mir etwas ein. Was ich noch vergessen habe. Wäre es möglich, dass mir zusätzlich zum Jahr noch der maximale Betrag hingeschrieben wird? Das habe ich nämlich vergessen zu erwähnen.

Wäre super, wenn du mir da helfen könntest.

LG
Thomas

[UweD]

Hallo


so....

=MAX(INDEX(Tabelle1!$Q$17:$V$19;VERGLEICH(Q6;Tabelle1!$P$17:$P$19;0);))


LG UweD

[Ego]

Hallo Thomas,

der maximale Wert ist doch Teil der bisherigen Formel.

Code:

MAX(INDEX(Tabelle1!$Q$17:$V$19;VERGLEICH(Q6;Tabelle1!$P$17:$P$19;0);))

[dertommy]

Hallo Helmut!

Danke nocheinmal. Ich habe einen Fehler in der Formel, war eh sehr ähnlich wie deine.

LG
Thomas

[snb]

In sheet2!R6

PHP-Code:

=YEAR(INDEX($Q$1:$V$1;MATCH(MAX(Q17:V17);Q17:V17;0))) 


oder

PHP-Code:

=2006+MATCH(MAX(Q17:V17);Q17:V17;0) 


In sheet2!R7

PHP-Code:

=YEAR(INDEX($Q$1:$V$1;MATCH(MAX(Q18:V18);Q18:V18;0))) 


oder

PHP-Code:

=2006+MATCH(MAX(Q18:V18);Q18:V18;0) 


In sheet2!R8

PHP-Code:

=YEAR(INDEX($Q$1:$V$1;MATCH(MAX(Q19:V19);Q19:V19;0))) 


oder

PHP-Code:

=2006+MATCH(MAX(Q19:V19);Q19:V19;0)