Inhalt einzelner Zellen mit Bedingung ausblenden

[Kexy28]

Hallo,

ich habe folgendes Problem:

Innerhalb der Zelle A1 habe ich die Wenn-Funktion, dass der Inhalt dieser Zelle einen Bestimmten Wert ergibt wenn Zelle A2 gleich A3 ist bzw. A2 ungleich A3 ist.

In A2 und A3 gebe ich manuell eine Zahl ein. Exel zeigt jedoch nun in Zelle A1 auch einen Wert an, wenn ich in A2 bzw. A3 keinen Inhalt habe, weil es ja denkt, dass A2=A3 ist, da dort ja nichts drinnen steht.


Meine Frage:

Mit Welcher Funktion oder Makro bekomme ich es hin, dass der gewünschte Wert in A1 nur dann angezeigt wird, wenn in A2 ODER A3 auch etwas eingetragen wurde?

Da ich ein Exel-Neuling bin, wäre ich glücklich wenn jeder Klick beschrieben wird. Ich bin jedoch auch für jede andere Antwort sehr dankbar.  


Liebe Grüße  :17:

[WillWissen]

Hi,

meinst du so?

Tabelle1

	A
1	200
2	10
3	12

Formeln der Tabelle

Zelle Formel A1 =WENN(ODER(A2="";A3="");"";WENN(A2=A3;100;200))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[Peter]

Hallo,

leider verrätst du uns deine Formel nicht.

Deswegen einfach mal ein Schuss ins Blaue.

Die Formel in A1 könnte, aufgrund deiner Beschreibung, den derzeitigen Ist-Zustand anzeigen.

Suchst du sowas ähnliches wie in B1?

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	Test
2
3

Zelle	Formel
A1	=WENN(A2=A3;"Test";"")
B1	=WENN(UND(ANZAHL(B2:B3)>0;B2=B3);"Test";"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Kuwer]

Hallo,

z.B.: =WENN(A2<>A3;"ungleich";WENN(LÄNGE(A2&A3);"gleich";""))

Gruß Uwe

[Kexy28]

Hallo,


danke für die schnellen Antworten, leider war noch nicht die endgültige Lösung dabei.

Meine Formel, die in A1 steht sieht so aus: 

fx==WENN(A2=A3;10;0)

da in A2 und A3  ja noch nichts eingetragen ist, steht in A1 ja jetzt die 10. Diese 10 soll aber nicht angezeigt werden. Sie soll nur dann angezwigt werden wenn in A2 oder (oder und) A3 auch etwas eingetragen wurde)

Ich möchte ja gerne die Formel (in A1) die ich schon habe so erweitern, dass die alte Funktion erhalten bleibt.

[WillWissen]

Hi,

Code:

=WENN(ANZAHL2(A2:A3)<2;"";WENN(A2=A3;10;0))

[Kexy28]

Hi,

Code:

=WENN(ANZAHL2(A2:A3)<2;"";WENN(A2=A3;10;0))

Könntest du mir die einzelnen Bausteine genau erklären?

Danke im Vorraus

[shift-del]

Hallo

Eine Alternative.

Code:

=(A2=A3)*(ANZAHL(A2:A3)>0)*10

[WillWissen]

Hi,

zur Erklärung bzw. zum Verstehen der Formel gibt es eine Formelauswertung. Du markierst eine Formel, gehst im Menüband auf "Formeln" und im Feld "Formelüberwachung" auf "Formelauswertung". Dort kannst du in Einzelschritten die Funktion der Formel nachvollziehen.

Code:

=WENN(ANZAHL2(A2:A3)<2;"";WENN(A2=A3;10;0))

ANZAHL2 zählt nichtleere Zellen im angegebenen Bereich. Bei der obigen Formel also: Wenn die Anzahl der nichtleeren Zellen im Bereich A2:A3 kleiner 2 ist, dann soll in A1 nichts geschrieben werden.
Im Ergebnis: es müssen, damit ein Wert geschrieben wird, beide Zellen gefüllt sein
Im Detail: WENN(ANZAHL2(A2:A3)<2 ist die Wahrheitsprüfung, der Leerstring nach dem ersten Semikolon ist die DANN-Funktion und die weitere WENN-Abfrage nach dem zweiten Semikolon eine Verschachtelung und bedeutet die SONST-Funktion.
Und hier im Detail: WENN(A2=A3;10;0) heißt: Wenn A2 gleich A3 ist, dann schreibe 10, sonst 0.