Input Box

[AndyExcel77]

Hallo,

ich habe eine größere Tabelle , hier würde ich gerne eine Input Box erstellen

Sie muss folgendes können ->

Eingabe für drei Spalten vornehmen und in die Spalten übernehmen

als Bezugs größe soll die Spalte D gelten , Zeile 8 - 202 , dort stehen Lagerorte (zb.5A08) wenn ich in die Inputmaske die Lagerorte eingebe soll diese Eingabe automatisch die Zeile zuordnen und die Daten übertragen.



Die Tabelle sieht so aus :

Spalte A = Artikelnummer / Spalte B = Charge / Spalte c = Stückzahl / Spalte D = Lagerort


würde mich sehr über Hilfe freuen

DANKE

[AndyExcel77]

ich habe eine einfach Input Box erstellt

Sub EingabeÜberInputbox()


Dim wert01$
wert01 = InputBox("Wert eingeben", "Bitte geben Sie einen Wert ein")
Range("a1").Value = wert01

 
End Sub

[Crazy Tom]

Hallo

in eine Inputbox kannst du nur 1 Eingabe machen
wo kommen denn dann die Daten her die du in die Zeile eintragen willst?
was soll passieren wenn an dem Lagerort schon ein Eintrag vorhanden ist?
überschreiben oder neue Zeile anlegen?

MfG Tom

[AndyExcel77]

Hallo,

danke

die Daten kommen von handschriftlich aufgenommen "Ein und Auslagerlisten"

Die Zeile soll überschrieben werden, weil dann jemand wahrscheinlich vergessen hat etwas zu löschen

Gruß

Andreas

[Crazy Tom]

Hallo

Excel wird wahrscheinlich nicht mit "handschriftlichen" Daten umgehen können
stehen die Daten in einem Tabellenblatt in einer Zelle oder willst du die Daten
über eine Eingabemaske in die Zielzeile schreiben?

als Ansatz würde ich das mit einer Userform mit 4 TextBoxen lösen
in einer der TextBoxen den Lagerort eingeben
in die anderen 3 TextBoxen deine Daten
der Lagerort würde dann in Spalte D über die Find-Methode ermittelt und
dann die Daten in dieser Zeile in die einzelnen Spalten

MfG Tom

[AndyExcel77]

Hey Tom,

Danke für die Antwort,

Ich meine das wir die Daten vor Ort mit der hand aufschreiben um Sie dann in unserer Lagerverwaltung einzugeben.

Die Daten sollen dann von der Maske in die Ziel Zeile übertragen werden.

als Ansatz würde ich das mit einer Userform mit 4 TextBoxen lösen
in einer der TextBoxen den Lagerort eingeben
in die anderen 3 TextBoxen deine Daten
der Lagerort würde dann in Spalte D über die Find-Methode ermittelt und
dann die Daten in dieser Zeile in die einzelnen Spalten

Das was du geschrieben hast ist genau so wie ich es mir vorstelle

So kann es funktionieren.
Hat jemand einen möglichen Code dafür ...

[Crazy Tom]

Hallo

in der Tasche hab ich den Code grad nicht
und gleich ist Feierabend
aber wenn ich daheim bin könnte ich dir einen Code erstellen
falls sich bis dahin noch keiner darum bemüht hat

MfG Tom

[AndyExcel77]

Hallo,

vielen dank ! wie du Zeit hast , da würde mich sehr freuen :)

[Crazy Tom]

Hallo

ich hoffe du weißt wie man eine Userform erstellt
in meinem Test habe ich eine Userform mit 4 TextBoxen 1 bis 4
dazu noch einen CommandButton1
in die TextBoxen 1 bis 3 kommen deine Daten zum Eintragen
in Textbox4 der Lagerort der gesucht wird

hier der Code

PHP-Code:

Private Sub CommandButton1_Click()
    Dim c As Range
    Dim rngBereich As Range
    Dim i As Integer
    Set rngBereich = Range("D8:D202")
    Set c = rngBereich.Find(TextBox4, LookIn:=xlValues, lookat:=xlWhole)
    If Not c Is Nothing Then
        For i = 1 To 3
            Cells(c.Row, i).Value = Controls("Textbox" & i).Value
        Next
    Else
        MsgBox "Lagerort nicht gefunden"
        With TextBox4
            .SetFocus
            .SelStart = 0
            .SelLength = Len(.Text)
        End With
        Exit Sub
    End If
    For i = 1 To 4
        Controls("Textbox" & i).Value = ""
    Next
End Sub 


MfG Tom

[AndyExcel77]

hallo,

FUNKTIONIERT :)!!! SUPER VIELEN DANK!!!!!

vielleicht kannst du mir noch bei zwei Sachen helfen,

1. Beschriftung der Userform Felder wie geht das ??