Ist eine ODER-Formel mit 6 Bedingungen kürzbar?

[Tommiks]

Hallo zusammen,

aus Datenschutzgründen dürfen die Abwesenheitstage der Kollegen im Schichtplan nicht mehr erkennbar dargestellt werden.

Nur eine Raute ist erlaubt. 

Meine folgende Formel funktioniert =WENN(ODER(_S1_1="k";_S1_1="U";_S1_1="G";_S1_1="F";_S1_1="S";_S1_1="T");"#";_S1_1)  , kann man meine Formel etwas professionaler gestalten?

_S1_1 ist ein Name aus dem Namensmanager.

K,U,G,F,S,T sind die Abwesenheitsarten , und sind nirgends als eine Legende abgelegt worden.

Bedanke mich im Voraus für Eure Unterstützung.

[BoskoBiati]

Hi,

versuche mal das:

Code:

=WENN(ODER(_S1_1={"F";"G";"k";"S";"T";"U"});"#";_S1_1)

[Tommiks]

 Funktioniert super. Danke...

[RPP63]

Moin und nur ergänzend!
Der Vergleich mittels = ist nicht case-sensitive!
Schließlich ergibt ="k"="K" WAHR.
Davon ab erzeugt bei mir das Schreiben des Vektors {"F";"G";"k";"S";"T";"U"} Krämpfe in den Findern. 

Deshalb als Alternative ein (auch noch etwas kürzerer) anderer Ansatz, der die Groß- und Kleinschreibung berücksichtigt:
=WENNFEHLER(WENN(FINDEN(_S1_1;"UGFSTk");"#");_S1_1)

Gruß Ralf

[LCohen]

=WENN(ISTZAHL(FINDEN(_S1_1;"UGFSTk"));"#";_S1_1)

gefällt mir ein klitzekleines bisschen besser, weil ich damit DANN und SONST auf einer Ebene habe. Außerdem klappt auch Antik-Excel.

[Tommiks]

Hallo Ralf, hallo LCohen ,

Eure Formeln haben auch die leeren Zellen mit Raute belegt.

Die Formel von BoskoBiati hat die Klein- und Großschreibung erkannt, und die leeren Zellen wurden nicht mit Raute belegt.

Vielen Dank Euch...

[RPP63]

Boskos Formel unterscheidet eben nicht case sensitive.
Aber ist ja auch egal.

[Kuwer]

Hallo,

das würde alles abdecken inklusive leer=leer ohne WENNFEHLER():

=WENN(ODER(CODE(_S1_1&"""")={70;71;83;84;85;107});"#";_S1_1&"")

Gruß, Uwe