Jahre mit zwei Nachkommastellen

[Rabe]

Hallo,

ich habe gerade eine kleine Formelfrage aus der BR-Sitzung:

wenn ich zwei Daten habe, wie kann ich die Jahre mit zwei Nachkommastellen ausrechnen, so habe ich das ja nur in ganzen Jahren:

Code:

=WENN(ISTLEER([@Eintritt]);"";DATEDIF([@Eintritt];DATUM(2024;10;31);"y"))

Danke.

Gruß Ralf

[Egon12]

Hallo Ralf,

Runden auf 2 so:

=RUNDEN(DATEDIF([@Eintritt];DATUM(2024;10;31);"y")+DATEDIF([@Eintritt];DATUM(2024;10;31);"YM")/12+DATEDIF([@Eintritt];DATUM(2024;10;31);"MD")/365;2)

Gruß Uwe

[knobbi38]

Hallo Ralf,

eine genaue Lösung kann es dafür nicht geben, weil du es mit Schaltjahren zu tun hast. Ansatzweise kannst du die Differenz in Tagen berechnen und durch die Anzahl Tage eines durchschnittlichen Jahres teilen:

Code:

=Runden((<Endedatum> - <Startdatum>) / 365,2425);2)

Wenn dir die Kommastellen bezogen auf die Monatswerte ausreichen, kannst du das natürlich auch mit den Monatsangaben berechnen.

[BoskoBiati]

Hi,

geht auch so:

Code:

=WENN(ISTLEER([@Eintritt]);"";DATEDIF([@Eintritt];--"31.10.24";"y"))+DATEDIF([@Eintritt];--"31.10.24";"yd")/365

[Rabe]

Vielen Dank euch Dreien.

Ich habe die Formel von Edgar genommen.

Nun schaue ich mir noch die BRTEILJAHRE an.

Gruß Ralf

[Jockel]

Hallo Ralf, Ich würde es hier mit Power Query machen... Aber wenn du (d)eine Lösung hast, auch gut.

[Fred11]

...oder mit der Funktion BRTEILJAHRE ?

https://support.microsoft.com/de-de/offi...8454ddc6a8
https://www.schnelle-online.info/Excel/B...erenz.html

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	Startdatum	05.05.2023
2	Enddatum	17.10.2024
3	Ergebnis	1,45	Jahre

Zelle	Formel
B3	=RUNDEN(BRTEILJAHRE(B1;B2;1);2)

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

Gruß
Fred