Jede 4. Zeile den Zeilenwert um 1 erhöhen

[Bifiboy]

Hallo,

ich habe folgendes Problem:

Ich möchte aus vier Tabellen jeweils die erste Zeile einer Spalte in eine 5. Tabelle untereinander kopieren und anschließend durch kopieren die nächsten Zeilen einfügen.
Bsp.:

Tabelle1 G1 --> Tabelle5 A1
Tabelle2 G1 --> Tabelle5 A2
Tabelle3 G1 --> Tabelle5 A3
Tabelle4 G1 --> Tabelle5 A4
Tabelle1 G2 --> Tabelle5 A5
Tabelle2 G2 --> Tabelle5 A6
Tabelle3 G2 --> Tabelle5 A7
Tabelle4 G2 --> Tabelle5 A8
Tabelle1 G3 --> Tabelle5 A9
Tabelle2 G3 --> Tabelle5 A10
Tabelle3 G3 --> Tabelle5 A11
Tabelle4 G3 --> Tabelle5 A12
... usw

Gibt es hierfür einen Algorithmus?
Danke

[Peter]

Hallo,

teste mal folgende Formel:

=INDIREKT("Tabelle"&1+REST(ZEILE(A3)-3;4)&"!"&"G"&GANZZAHL((ZEILE(A3)+1)/4))

[coemm]

Hallo,

teste mal folgende Formel:

=INDIREKT("Tabelle"&1+REST(ZEILE(A3)-3;4)&"!"&"G"&GANZZAHL((ZEILE(A3)+1)/4))

Hallo Peter,

bei mit funktioniert die Formel, verstehe sie aber leider nicht!

[Bifiboy]

Hallo,

teste mal folgende Formel:

=INDIREKT("Tabelle"&1+REST(ZEILE(A3)-3;4)&"!"&"G"&GANZZAHL((ZEILE(A3)+1)/4))

Besten Dank, es klappt

[Peter]

Hallo Conny,

einzeln aufgeführt würde man folgende Formeln benötigen:

Tabelle1!G1
Tabelle2!G1
Tabelle3!G1
Tabelle4!G1
Tabelle1!G2
Tabelle2!G2
etc...

Lösen wir die Formel auf und schauen uns zwei Teile genauer an:

=1+REST(ZEILE(A3)-3;4)

und

=GANZZAHL((ZEILE(A3)+1)/4)

Kopiere mal diese Formeln in B1 und C1 und ziehe Sie dann nach unten:

Arbeitsblatt mit dem Namen 'Tabelle1'
	B	C
1	1	1
2	2	1
3	3	1
4	4	1
5	1	2
6	2	2
7	3	2
8	4	2
9	1	3
10	2	3
11	3	3
12	4	3

Zelle	Formel
B1	=1+REST(ZEILE(A3)-3;4)
C1	=GANZZAHL((ZEILE(A3)+1)/4)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

In Spalte B stehen immer wieder die Werte von 1 bis 4 und in Spalte C stehen viermal der Wert 1, viermal der Wert 2 etc.

Schau dir einfach mal in der Formelauswertung an was in den einzelnen Zellen passiert.

Und das Ganze wird dann mit Hilfe von Indirekt einfach zusammengesetzt.

[WillWissen]

Hi Peter,

zum einen einen dicken wegen der ausgefallenen Formel und einen zweiten für deine super Erklärung. Danke.

[Jockel]

Hallo,

teste mal folgende Formel:

=INDIREKT("Tabelle"&1+REST(ZEILE(A3)-3;4)&"!"&"G"&GANZZAHL((ZEILE(A3)+1)/4))

Hallo Peter, wieso ZEILE(A3)+1..? ... es geht auch ..:
=INDIREKT("Tabelle"&1+REST(ZEILE(A3)-3;4)&"!"&"G"&KÜRZEN(ZEILE(A4)/4))

[Peter]

Hallo,

wieso ZEILE(A3)+1..? ... es geht auch ..:

das ist mein eingeschränkter Denkweise geschuldet.

Ich habe am ersten Teil der Formel rumgedoktert und dann einfach im zweiten Teil mit dem Zeile(A3) weitergemacht und dann nicht daran gedacht das abzuändern.

[chris-ka]

Hi,m
Ok einen hätte ich auch :)

Formel in A4 Tabelle5

=INDIREKT("Tabelle"&REST(ZEILE();4)+1&"!G"&KÜRZEN(ZEILE()/4))

zz. für A1
=INDIREKT("Tabelle"&REST(ZEILE()-1;4)+1&"!G"&KÜRZEN(ZEILE(A4)/4))

[BoskoBiati]

gelöscht