Jubiläumsberechnung

[schadre]

Hallo an alle Excelprofis.

Auch heute habe ich mal wieder ein Excelproblem und hoffe auf eure Hilfe. Ich stehe mal wieder völlig auf dem Schlauch und finde keinen Ansatz/Lösung.
Also bitte ich euch um eure Hilfe.

Ich habe eine Datei in der ich verschiedene Teilnahmezeiträume eintrage. In den Spalten E, F und G lasse ich mir diese Zeiträume entsprechend der Spaltenüberschriften in Jahren, Monaten und Tagen ausrechnen. Zusätzlich in Zeile 25 die Gesamtsumme aller Zeilen 6 bis 24. 
Alles soweit ganz easy und simpel.
Jetzt kommt mein Wunsch (und zugleich auch die Offenbarung meines Versagens  :19: )

In dem Feld C 28 hätte ich gerne das Datum wann das  5-jährigen Jubiläum erreicht wurde, im Feld C 29 das des 10-jährigen Jubiläums usw. usw.
Leider weiß ich überhaupt nicht wie und finde auch keinen Ansatz.
Ich hoffe auf eure Hilfe

[steve1da]

Hola,

vielleicht versteh' ich es ja auch einfach nicht....aber das 5. Jubiläum von was?
Wie sieht dein Wunschergebnis aus?

Gruß,
steve1da

[schadre]

Hallo steve1da.

Sorry das ich mich nicht genau ausgedrückt habe. 

Ich versuche es noch einmal genauer zu erklären und nehme als Beispiel das 5-jährige Jubiläum.

Die 1 Teilnahme dauerte 5 Mo und 30 Tage, die 2. Teilnahme 2 Jahre, 6 Mo und 1 Tag.
Ergibt als Summe nach 2 Teilnahmen: 3 Jahre und 1 Tag.
Die 3. Teilnahme beginnt am 05.01.1995 und dauerte 2 Jahre und 3 Monate (bis zum 05.01.198).
Das bedeutet, das während der 3.Teilnahme das 5-jährige Jubiläum an teilgenommenen Tagen erreicht wird.
In meinem Beispiel müsste das der 03.10.1997 (habe ich per Hand ausgerechnet) sein. An diesem Tage hat der Teilnehmer 5 Jahre teilgenommen.

Dieses Ergebnis ( 03.10.1997 als Jubiläumstag für das 5-jährige Jubiläum) hätte ich gerne von Excel in der Zelle C 28 automatisch berechnet.

Und im weiteren Verlauf dann das selbe für das 10-jährige Jubiläum in C29 usw.usw.

Hoffe ich konnte das jetzt besser erklären.

Danke das ihr hier immer so grandios helft.

[schauan]

Hallöchen,

ich hab da mal ein paar Fragen.

Angenommen, ich mache nur im Juli und August mit, wann wären dann mein erstes Jahr rum? Wenn ich 12 Monate zur Bewertung heranziehe, wäre das im 6. Jahr der 31.8. ? Oder nicht?
Da das alles Monate mit 31 Tagen sind, komme ich nach 6 Jahren am 31.8. aber auf 372 Tage und nicht nur 365. Hab ich da das Einjährige schon am 24.8.? So, und bei 6 Jahren könnte es passieren, dass ich ein oder 2 Schaltjahre dabei habe. Müsste ich das auch berücksichtigen?

[Cadmus]

Merkwürdige Jubiläen. Wäre es nicht einfacher, nur mit Tagen zu rechnen? Die Schaltjahre können bei der Sache vermutlich vernachlässigt werden.

[happy-jack]

Merkwürdige Jubiläen. Wäre es nicht einfacher, nur mit Tagen zu rechnen? Die Schaltjahre können bei der Sache vermutlich vernachlässigt werden.

Hi,

dachte ich auch! Da die Teilnahme ja immer nur wenige Monate pro Jahr sind, würde ich bestenfalls nach Monaten "jubilieren" oder eben die Tage zählen (Fehlzeiten abrechnen) und dann den 2.000ten Teilnahmetag oder nach 1.825 Anwesenheits-Tagen eben das 5-Jahres-Jubiläum feiern!

Ansonsten könnte man ganz einfach den Tag der ersten Teilnahme plus 5 Jahre als den den 5ten Jahrestag nehmen !!

Jack ;)

[schauan]

Hallöchen,

Code:

Ansonsten könnte man ganz einfach den Tag der ersten Teilnahme plus 5 Jahre als den 5ten Jahrestag nehmen !!

mal was aus der Praxis - ich glaube, bei einem Saisonkennzeichen hat man nach 5 Jahren noch keine 5 Stufen "gewonnen" Wär' zu schön …

Ich würde, wie Cadmus schrieb, auch mit Tagen rechnen, eventuell, ohne Schaltjahre zu berücksichtigen.
Es wäre nur die Frage, ob man dann mit 365 Tagen rechnet oder es auf Montag bis Freitag reduziert oder Banktage pro Monat nimmt, also in jedem 30.
Wenn eine Teilnahme an einem Freitag endet, würde ich die Woche komplett zählen bzw. als Ende den Sonntag eintragen. Wäre ja ansonsten unfair gegenüber einer durchgängigen Teilnahme.  

Der TE schreibt:

Die 1 Teilnahme dauerte 5 Mo und 30 Tage,

Der letzte Monat wird also wohl 31 Tage haben. Ansonsten wären es ja 6 War nun eigentlich der 30. Tag ein Freitag und es hört deswegen an dem Tag auf?

die 2. Teilnahme 2 Jahre, 6 Mo und 1 Tag

Das könnte auch wieder an einem Freitag liegen? Der Teilnehmer macht immer die "Arbeitswoche" voll?

Übrigens enthält Diene Tabelle auch Fehler:

Arbeitsblatt mit dem Namen 'Zeitberechnung'
	B	C	D	E	F	G
9	4. Teilnahme	01.01.2001	30.11.2004	3	10	29

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Sind das nicht 3 Jahre und 11 Monate ???


So, jetzt ist erst mal der Bäcker dran - da gibt's schon Antworten Lecker Brötchen …  :17:

[schauan]

Hallöchen,

hier nun endlich mal ein Ansatz. Gerechnet habe ich mit 365,25 Tagen pro Jahr und das Ergebnis abgerundet, sodass z.B. bei 5 Jahren zumindest ein Schaltjahr mitgerechnet wird.
Für die Tage habe ich eine Hilfsspalte (H) verwendet, wo ich selbige kumuliere. Den Rechenweg kannst Du unten nachvollziehen. Per Vergleich bekomme ich die Zeile der Teilnahme vor dem Jubiläum. Per Index ziehe ich mir dann den kumulierten Tagesstand und das Datum des Beginns des Folgekurses. Diesem Datum addiere ich dann die Differenz zum Jubiläum.

Die Formeln hab ich hier nur für die jeweils erste Zeile, die musst Du noch nach unten ziehen.
 
Ich denke, wenn da was nicht passt, z.B. die 365,25 Tage oder das Abrunden oder eventuell muss noch irgendwo ein Tag verrechnet werden oder … bekommt man das einfach hin. Ebenso das Datum nach 25 Jahren wenn's da noch keinen Folgekurs gibt. Könnte ja auch schon bei den 5 Jahren so falsch anfangen

Arbeitsblatt mit dem Namen 'Zeitberechnung'
	B	C	D	E	F	G	H
5	Teilnahme	von	bis	Jahre	Monate	Tage	Kum Tage
6	1. Teilnahme	03.07.1990	02.01.1991	0	5	30	183
7	2. Teilnahme	02.07.1991	03.01.1994	2	6	1	1099
8	3. Teilnahme	05.10.1995	05.01.1998	2	3	0	1922
9	4. Teilnahme	01.01.2001	30.11.2004	3	10	29	3351
10	5. Teilnahme	01.07.2005	31.03.2012	6	8	30	5816
11	6. Teilnahme	01.04.2012	30.06.2014	2	2	29	6636
12	7. Teilnahme	01.07.2014	23.05.2018	3	10	22	8058
25	Ergebnis:			22	0	21
26
27	Jubiläen
28	5 Jahre	01.10.1997
29	10 Jahre	28.04.2006
30	15 Jahre	28.04.2011
31	20 Jahre	30.04.2016
32	25 Jahre	08.12.1902
33
34	Zeile	Tage ist	Tage Soll	Differenz	Beginn Folge	Jubiläum
35	2	1099	1826	727	05.10.1995	01.10.1997
36	4	3351	3652	301	01.07.2005	28.04.2006
37	4	3351	5478	2127	01.07.2005	28.04.2011
38	6	6636	7305	669	01.07.2014	30.04.2016
39	7	8058	9131	1073	00.01.1900	08.12.1902

Zelle	Formel
H6	=SUMME((D6-C6);H5)
C28	=INDEX($C$6:$C$26;VERGLEICH(ABRUNDEN(B28*365,25;0);$H$6:$H$26;1)+1;1)+ABRUNDEN(B28*365,25;0)-INDEX($H$6:$H$26;VERGLEICH(ABRUNDEN(B28*365,25;0);$H$6:$H$26;1);1)
B35	=VERGLEICH(ABRUNDEN(B28*365,25;0);$H$6:$H$26;1)
C35	=INDEX($H$6:$H$26;B35;1)
D35	=ABRUNDEN(B28*365,25;0)
E35	=D35-C35
F35	=INDEX($C$6:$C$26;B35+1;1)
G35	=F35+E35

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg