KW Woche und bedingte Formatierung

[schauan]

Hallöchen,

dann dröseln wir das Ganze nochmal auf ... Ziel wäre ja, eine Formel zu entwickeln, die ich nur in B2 eingebe und dann über das ganze Jahr nach rechts ziehen kann.

Ich habe hier mal für den Januar die Formeln etwas ausführlicher geschrieben, auch wenn man z.B. *0 oder *1 normalerweise nicht braucht. Ganz deutlich wird das z.B. in B2.
In der Formel habe ich noch 4 Bestandteile, die sich viertelweise oder monatsweise ändern.
Ab B3 habe ich versucht, diese Daten zu berechnen, sodass keine feste Eingabe nötig ist. Gib mal die Formeln in B3:B5 ein und ziehe sie nach rechts in den Februar und weiter. Du wirst dann sehen, dass sich die Daten entsprechend dem Monat und dem Viertel anpassen oder wiederholen.

Nächster Step wäre dann, die Formel in B2 anhand der Bestandteile von B3:B6 anzupassen und dann geht's von links nach rechts ...
---> und dann wäre noch das Ding mit der GANZZAHL ... habe ich hier leider außen vor gelassen.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1		Januar
2	17. Jan			x
3		1	1	1	1
4		31	31	31	31
5		1	2	3	0
6		0	1	2	3

Zelle	Formel
B2	=WENN(UND(TAG($A2)>31/4*0;TAG($A2)<=31/4*1);"x";"")
C2	=WENN(UND(TAG($A2)>31/4*1;TAG($A2)<=31/4*2);"x";"")
D2	=WENN(UND(TAG($A2)>31/4*2;TAG($A2)<=31/4*3);"x";"")
E2	=WENN(UND(TAG($A2)>31/4*3;TAG($A2)<=31/4*0);"x";"")
B3	=GANZZAHL((SPALTE()+2)/4)
B4	=TAG(DATUM(JAHR($A2);B3+1;))
B5	=REST(SPALTE()+3;4)
B6	=REST(SPALTE()+2;4)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[DieHappy]

Hi,


okay.

Könntest du für das Verständnis auch Februar hintendran hängen?
Denn die Ganzzahl in Feb müsste ja dann 2 sein, in den Formeln B2:E2 wird aber nicht auf die 1 in Jan eigegangen. Wie soll dann monatsweise unterschieden werden?

[schauan]

Hallöchen,

so, nun hier komplett. Wie gesagt, in den Zeilen 3 bis 6 habe ich mir schrittweise überlegt, wie ich die einzelnen fest in den Formeln in Zeile 2 eingetragenen Bestandteile berechnen kann.  In Zeile 7 habe ich das dann übertragen - habe dort als Grundlage die Formel aus B2 genommen und mit den "Schritten" bearbeitet. Nun kann die Formel beliebig nach rechts gezogen werden.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I
1		Januar				Februar
2	17. Jan			x
3		1	1	1	1	2	2	2	2
4		31	31	31	31	28	28	28	28
5		1	2	3	0	1	2	3	0
6		0	1	2	3	0	1	2	3
7	flexibel:			x

Zelle	Formel
B2	=WENN(UND(TAG($A2)>31/4*0;TAG($A2)<=31/4*1;GANZZAHL((SPALTE()+2)/4)=MONAT($A2));"x";"")
C2	=WENN(UND(TAG($A2)>31/4*1;TAG($A2)<=31/4*2;GANZZAHL((SPALTE()+2)/4)=MONAT($A2));"x";"")
D2	=WENN(UND(TAG($A2)>31/4*2;TAG($A2)<=31/4*3;GANZZAHL((SPALTE()+2)/4)=MONAT($A2));"x";"")
E2	=WENN(UND(TAG($A2)>31/4*3;TAG($A2)<=31/4*0;GANZZAHL((SPALTE()+2)/4)=MONAT($A2));"x";"")
F2	=WENN(UND(TAG($A2)>31/4*0;TAG($A2)<=31/4*1;GANZZAHL((SPALTE()+2)/4)=MONAT($A2));"x";"")
G2	=WENN(UND(TAG($A2)>31/4*1;TAG($A2)<=31/4*2;GANZZAHL((SPALTE()+2)/4)=MONAT($A2));"x";"")
H2	=WENN(UND(TAG($A2)>31/4*2;TAG($A2)<=31/4*3;GANZZAHL((SPALTE()+2)/4)=MONAT($A2));"x";"")
I2	=WENN(UND(TAG($A2)>31/4*3;TAG($A2)<=31/4*0;GANZZAHL((SPALTE()+2)/4)=MONAT($A2));"x";"")
B3	=GANZZAHL((SPALTE()+2)/4)
B4	=TAG(DATUM(JAHR($A2);B3+1;))
B5	=REST(SPALTE()+3;4)
B6	=REST(SPALTE()+2;4)
B7	=WENN(UND(TAG($A2)>TAG(DATUM(JAHR($A2);GANZZAHL((SPALTE()+2)/4)+1;))/4*REST(SPALTE()+2;4);TAG($A2)<=TAG(DATUM(JAHR($A2);GANZZAHL((SPALTE()+2)/4)+1;))/4*REST(SPALTE()+3;4);GANZZAHL((SPALTE()+2)/4)=MONAT($A2));"x";"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg