KW + xWochen mit KW als Ergebnis

[StephPsc]

Hello,

ich habe folgendes Problem:
Eine KW ist gegeben und ich muss jeweils 12 Wochen addieren.

zb Zelle A1: KW33/2016
    Zelle B1: KW45/2016

Ich weiß leider nicht wie ich die Formel so aufbaue das er nach KW52 ein Jahr höher springt... sonnst hätte ich es einfach mit =Links(A1;2)+12 probiert

Danke und LG!

[shift-del]

Hallo

Verwende Kalenderdaten.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Datum	KW	Datum	KW
2	15.08.2016	33	07.11.2016	45
3	28.11.2016	48	20.02.2017	8

Zelle	Formel
B2	=ISOKALENDERWOCHE(A2)
C2	=A2+12*7
D2	=ISOKALENDERWOCHE(C2)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo, ich habe das so verstanden..:

Arbeitsblatt mit dem Namen 'Tabelle7'
	A	B	C
1	KW33/2016		KW45/2016
2	KW48/2016		KW08/2017

Zelle	Format	Wert
C1	TT.MM.JJJJ	KW45/2016
C2	TT.MM.JJJJ	KW08/2017

Zelle	Formel
C1	="KW"&TEXT(KALENDERWOCHE(("4.1."&RECHTS(A1;4))+TEIL(A1;3;2)*7-7-REST("2.1."&RECHTS(A1;4);7)+12*7;21);"00")&"/"&JAHR(("4.1."&RECHTS(A1;4))+TEIL(A1;3;2)*7-7-REST("2.1."&RECHTS(A1;4);7)+12*7)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[StephPsc]

Danke euch beiden!

und ja Jockel, so habe ich es gemeint...deine Formel funktioniert halt leider nicht bei mir...
soll ich da noch was änders wenn das Orginaldatum immer in Spalte G steht und das neue Datum immer in Spalte I?
Habs jetzt mal so...aber bekomme leider keine Ergebnisse

="KW"&TEXT(KALENDERWOCHE(("4.1."&RECHTS(G9;4))+TEIL(G9;3;2)*7-7-REST("2.1."&RECHTS(G9;4);7)+12*7;21);"00")&"/"&JAHR(("4.1."&RECHTS(G9;4))+TEIL(G9;3;2)*7-7-REST("2.1."&RECHTS(G9;4);7)+12*7)

Danke und LG

[Jockel]

Hallo, poste doch bitte (d)eine (Beispiel)Datei... ... oder ein Tabellenausschnitt, damit man sieht wo was (genau) steht.

Ich habe jetzt mal "deine" Formel probiert..:

Arbeitsblatt mit dem Namen 'Tabelle7'
	G	H	I	J
9	KW33/2016			KW45/2016
10	KW48/2016			KW08/2017

Zelle	Formel
J9	="KW"&TEXT(KALENDERWOCHE(("4.1."&RECHTS(G9;4))+TEIL(G9;3;2)*7-7-REST("2.1."&RECHTS(G9;4);7)+12*7;21);"00")&"/"&JAHR(("4.1."&RECHTS(G9;4))+TEIL(G9;3;2)*7-7-REST("2.1."&RECHTS(G9;4);7)+12*7)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[StephPsc]

Oki :)

[Jockel]

Hallo, wenn KW fehlt, dann muss TEIL(Gn;1;2) -->

Code:

=TEXT(KALENDERWOCHE(("4.1."&RECHTS(G2;4))+TEIL(G2;1;2)*7-7-REST("2.1."&RECHTS(G2;4);7)+12*7;21);"00")&"/"&JAHR(("4.1."&RECHTS(G2;4))+TEIL(G2;1;2)*7-7-REST("2.1."&RECHTS(G2;4);7)+12*7)

... aber das kannst du doch einfacher haben..:

Code:

=KALENDERWOCHE(H2;21)&"/ "&JAHR(H2)

[StephPsc]

Mit dieser Code bekommt man doch nicht immer die richtige Ergebnisse? z.B. mit KW45/ 2016 als Ausgangsdatum

Code:

=KALENDERWOCHE(H2;21)&"/ "&JAHR(H2)

Und der längere Code funktioniert irgendwie nicht.. hat der in mein test File richtige Ergebnisse geliefert?

Danke!

[Jockel]

Mit dieser Code bekommt man doch nicht immer die richtige Ergebnisse? z.B. mit KW45/ 2016 als Ausgangsdatum

Code:

=KALENDERWOCHE(H2;21)&"/ "&JAHR(H2)

Und der längere Code funktioniert irgendwie nicht.. hat der in mein test File richtige Ergebnisse geliefert?

Danke!

Hallo, bei mir sieht das so aus (in deiner Datei) ..:

Das Datum in H habe ich anders berechnen lassen...:

Code:

=12*7+("4.1."&RECHTS(G2;4))+LINKS(G2;2)*7-7-REST("2.1."&RECHTS(G2;4);7)+4

Arbeitsblatt mit dem Namen 'Tabelle1'
	G	H	I	J	K
1	Datum1	Datun2	Datun3
2	33/ 2016	11.11.2016	45/ 2016	45/2016	45/ 2016
3	33/ 2016	11.11.2016	45/ 2016	45/2016	45/ 2016
4	33/ 2016	11.11.2016	45/2016	45/2016	45/ 2016
5	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
6	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
7	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
8	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
9	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
10	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
11	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
12	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
13	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
14	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017
15	10/ 2017	02.06.2017	22/ 2017	22/2017	22/ 2017

Zelle	Formel
J2	=TEXT(KALENDERWOCHE(("4.1."&RECHTS(G2;4))+TEIL(G2;1;2)*7-7-REST("2.1."&RECHTS(G2;4);7)+12*7;21);"00")&"/"&JAHR(("4.1."&RECHTS(G2;4))+TEIL(G2;1;2)*7-7-REST("2.1."&RECHTS(G2;4);7)+12*7)
K2	=KALENDERWOCHE(H2;21)&"/ "&JAHR(H2)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[snb]

schau mal die angehängte Datei.

Formel:

=WEEKNUM(DATE(RIGHT(G2;4);1;4)+7*(VALUE(LEFT(G2;SEARCH("/";G2)-1))+11);21)&"/"&YEAR(DATE(RIGHT(G2;4);1;4)+7*(11+VALUE(LEFT(G2;SEARCH("/";G2)-1) )))

Numberformat:

"KW "@