Kalkulation

[tomtom65]

Hallo,

ich  bin ünerwältigt von eurer Hilfsbereitschaft und eurem können! Ich werde jetzt mal versuchen das umzusetzten, falls ich noch Fragen habe melde ich mich. Vielen Dank nochmals!

gruß Thomas

[BoskoBiati]

Hallo,

hier mal eine Version ohne Hilfsspalten, allerdings müssen die Namen in der Preisliste umgestaltet werden:

Arbeitsblatt mit dem Namen 'Preisliste'
	B	C
1	Seiten BF	Seiten BHF

Zelle	Format	Wert
B1	"Seiten "@	BF
C1	"Seiten "@	BHF

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Das ergibt diese Formel:

Arbeitsblatt mit dem Namen 'Kalk'
	B	C	D
6	Auflage	8000	9000
7	Sorte	weiss	gelb
8	Format	BHF	BF
9	Seiten	88	32
10
11
12
13	Preis	3667,62	1278,17

Zelle	Formel
C13	=INDEX(Preisliste!$D:$I;VERGLEICH(C9;INDEX(Preisliste!$B$2:$C$16;;VERGLEICH(C8;Preisliste!$B$1:$C$1;0));0)-1+VERGLEICH(C7;Preisliste!$A:$A;0);VERGLEICH(C6;Preisliste!$D$1:$I$1;1))
D13	=INDEX(Preisliste!$D:$I;VERGLEICH(D9;INDEX(Preisliste!$B$2:$C$16;;VERGLEICH(D8;Preisliste!$B$1:$C$1;0));0)-1+VERGLEICH(D7;Preisliste!$A:$A;0);VERGLEICH(D6;Preisliste!$D$1:$I$1;1))

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
C7	Liste		weiss;gelb
D7	Liste		weiss;gelb
C8	Liste		BF;BHF
D8	Liste		BF;BHF

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Ohne die Namen in Preisliste zu ändern:

Arbeitsblatt mit dem Namen 'Kalk (2)'
	B	C	D
6	Auflage	8000	9000
7	Sorte	weiss	gelb
8	Format	BHF	BF
9	Seiten	88	32
10
11
12
13	Preis	3667,62	1278,17

Zelle	Formel
C13	=INDEX('Preisliste (2)'!$D:$I;VERGLEICH(C9;INDEX('Preisliste (2)'!$B$2:$C$16;;VERGLEICH("Seiten "&C$8;'Preisliste (2)'!$B$1:$C$1;0));0)-1+VERGLEICH(C7;'Preisliste (2)'!$A:$A;0);VERGLEICH(C6;'Preisliste (2)'!$D$1:$I$1;1))
D13	=INDEX('Preisliste (2)'!$D:$I;VERGLEICH(D9;INDEX('Preisliste (2)'!$B$2:$C$16;;VERGLEICH("Seiten "&D$8;'Preisliste (2)'!$B$1:$C$1;0));0)-1+VERGLEICH(D7;'Preisliste (2)'!$A:$A;0);VERGLEICH(D6;'Preisliste (2)'!$D$1:$I$1;1))

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
C7	Liste		weiss;gelb
D7	Liste		weiss;gelb
C8	Liste		BF;BHF
D8	Liste		BF;BHF

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[atilla]

Hallo Edgar,

ich habe auch eine Lösung ohne Hilfsspalte eingestellt.

Ich setze bei mir voraus, dass die Blöcke gleich hoch sind.
Du setzt voraus, dass die Blöcke mit gleichen Werten wiederkehren.
Woraus schließt Du das?

[WillWissen]

Hallo Atilla, hallo Edgar,

ich vermute mal, dass ihr beide mit euren jeweiligen Annahmen Recht habt. Thomas schrieb in seiner Frage:

Es gibt mehrere Sorten, Eine anzahl von verschiedenen Seiten 4, 6, 8, 10 usw und Zwei Seitenformate bezeichnet mit BF und BHF.

Ich denke, dass alle Seitenanzahlen pro Block gleich sein werden, denn der unterscheidet sich ja eigentlich nur durch die Sorten.

[BoskoBiati]

Hallo Atilla,

ich habe, wie Du, eine Annahme getroffen, die mir das Erstellen der Formel vereinfacht. Da wir nur die zwei Blöcke kennen, geht es nicht anders. Da beide Blöcke die gleichen Listen haben (ist ja auch logisch, da die Seitenzahlen durch das Papierformat und die Faltung vorgegeben sind), gehe ich davon aus, dass es auch bei den anderen Blöcken so sein wird. Aber der TE kann sich ja noch äußern. Im übrigen ist es kein Problem, die Formel zu ändern:

Arbeitsblatt mit dem Namen 'Kalk'
	B	C	D
3	Auflage	8000	9000
4	Sorte	weiss	gelb
5	Format	BHF	BF
6	Seiten	88	12
7
8
9
10	Preis	3667,62	479,31

Zelle	Formel
C10	=INDEX(Preisliste!$D:$I;VERGLEICH(C6;INDEX(INDEX(Preisliste!$B:$B;VERGLEICH(C4;Preisliste!$A:$A;0)):Preisliste!$C$9000;;VERGLEICH("Seiten "&C$5;Preisliste!$B$1:$C$1;0));0)-1+VERGLEICH(C4;Preisliste!$A:$A;0);VERGLEICH(C3;Preisliste!$D$1:$I$1;1))
D10	=INDEX(Preisliste!$D:$I;VERGLEICH(D6;INDEX(INDEX(Preisliste!$B:$B;VERGLEICH(D4;Preisliste!$A:$A;0)):Preisliste!$C$9000;;VERGLEICH("Seiten "&D$5;Preisliste!$B$1:$C$1;0));0)-1+VERGLEICH(D4;Preisliste!$A:$A;0);VERGLEICH(D3;Preisliste!$D$1:$I$1;1))

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
C4	Liste		weiss;gelb
D4	Liste		weiss;gelb
C5	Liste		BF;BHF
D5	Liste		BF;BHF

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[tomtom65]

Hallo Atilla, hallo Edgar, hallo Gerd

Die Blöcke sind immer gleich. Es sind aber mehr Sorten als Gelb und Weiss, momentan 5, und die Mengen sind in der Originaldatei mehr (Stückzahl bis zu 500.000)

Gruß Thomas

[atilla]

Hallo,

Gerd war nur indirekt beteiligt. Er stellt das Tool zur Verfügung, welches wir zum Einstellen der Tabellenausschnitte nutzen.
Aber zwei andere Mitglieder waren noch beteiligt. Einmal der Günter und dann auch noch Günther.


Hast Du denn eine der eingestellten Formeln mal eingesetzt und getestet????

[BoskoBiati]

Hallo,


Formel erweitert:

Code:

=INDEX('Preisliste (2)'!$D:$AI;VERGLEICH(C9;INDEX('Preisliste (2)'!$B$2:$C$16;;VERGLEICH("Seiten "&C$8;'Preisliste (2)'!$B$1:$C$1;0));0)-1+VERGLEICH(C7;'Preisliste (2)'!$A:$A;0);VERGLEICH(C6;'Preisliste (2)'!$D$1:$AI$1;1))

ungetestet!

[tomtom65]

Hallo,

ich möchte mich bei allen Beteiligte herzlichst für die Unterstützung hier bedanken. Ich habe die zweite Lösung von Günter für meine Tabelle angepasst und es funktioniert auch so wie ich es mir gedacht habe. Die anderen Lösungen werde ich mir aber auch nochmals ansehen.

Gruß Thomas

[atilla]

Hallo,

na, das ist ja dann eine sehr schöne Mitteilung und tolles Erfolgserlebnis für Günter.
Ich freu mich deshalb, weil er in letzter Zeit von Anderen und einige Male auch von mir scheinbar einen Dämpfer bekam.

Also Günter, weiter so

Es ist auch schön zu sehen, dass es noch Leute gibt, die sich nicht scheuen von den wenigen Zeilen und Spalten, die Excel anbietet, ein zwei als Hilfsspalten zu nutzen.