Kleinster Wert größer 0 aus versch. Zellen

[LCohen]

Wen hast Du denn wegen (H21;L21;P21;T21>0,01) konsultiert? Dein Arzt war es sicherlich nicht ...

[shift-del]

der mir schon 15 Stunden Zeit gekostet hat

Viel Erfolg noch.

[{Boris}]

Hi,

 Ich habe einen verweis in der zelle, also ='Tabellenblatt2'E11

Ist das störend?

Natürlich. So weit waren wir schon vor über 1 Stunde. Ein Bezug auf eine leere Zelle liefert nunmal 0 - und diese 0 wird von MIN natürlich berücksichtigt.
LCohen hat seinen alten Beitrag mit einer Formel editiert. Nutze diese.

---

Hi,

in Deiner Excelversion geht auch:

Code:

=MIN(LET(x;INDEX((I21;M21;Q21;U21);;1;{1.2.3.4});WENN(x=0;"";x)))

[vettelchen]

Hallo Boris, so. habe meine gebastelte Excel  (Ausschnit) mal beigefügt. Habe es mit der Hilfszahl 999 hinbekommen. Das geht aber nur, wenn die Werte unter 999 sind. Über 999 ist der kleinste Wert dann wieder 999.
Ich glaube dann wissen Sie auch was ich meine. Ich habe 8 Anbieter (also in diesem Fall reduziert auf 3).
Von denen gibt jemand einen Preis ab oder nicht. Ich habe aber eine Verknüpfung auf einen exportierten Preisspiegel.
Das heißt, wenn ein Bieter nichts abgibt ist es eine 0 und somit ist er der günstigste, was ja falsch ist.

Ich bin schon am verzweifeln... Alles ausprobiert. Nix hilft...
Gruß
Maik

[shift-del]

Moin

Nach 14 Beiträgen endlich eine Beispielmappe.
Wie ich vermutet habe liegt es an der Struktur.

Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B	C	D	E
1	Titel	Anbieter A - EP	Anbieter B - EP	Anbieter C - EP	Ideal-Anbieter
2	Kabel und Leitungen	10000	50000		10000
3	Verlegesysteme	150	80		80
4	Steckdosen	1111	2222		1111
5	Schrauben				0
6	Muttern				0
7	Irgendwas	0	0	0	0

Zelle	Formel
E2	=MINWENNS(B2:D2;B2:D2;">0")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[vettelchen]

Und genau das kann ich nicht als Formel nehmen da die Zellen nicht nebeneinander liegen, sondern außeinander:

In dem Fall von mir in Spalte G,K,O und so weiter.....!

[{Boris}]

Hi,

E10:
=LET(x;(G10;K10;O10);y;INDEX(x;;;SEQUENZ(BEREICHE(x)));MIN(WENN(y<>0;y)))

Runterkopieren. Der veränderliche Formelteil ist immer nur der Bereich (funktioniert mit jeweils Einzelzellen - kann beliebig erweitert werden).

[vettelchen]

Hallo Boris,
habe ich nun wie folgt in meine Tabelle eingefügt:
=LET(x;(H14;L14;P14;T14);y;INDEX(x;;;SEQUENZ(BEREICHE(x)));MIN(WENN(y<>0;y)))

Fehler: #NAME?

Was muss ich hier noch in der Forma eintragen?

[{Boris}]

Hi,

dann kennt Dein Excel die LET-Funktion noch nicht. Ohne diese wird es etwa länger (musst den Bereich insgesamt 4 mal angeben):

=MIN(WENN(INDEX((H14;L14;P14;T14);;;SEQUENZ(BEREICHE((H14;L14;P14;T14))))<>0;INDEX((H14;L14;P14;T14);;;SEQUENZ(BEREICHE((H14;L14;P14;T14))))))

[EDIT] Jetzt sehe ich,dass Du xl2019 benutzt (hatte irgendwie gedacht, es sei xl365) - da ist auch SEQUENZ noch nicht bekannt.
Damit wird es dann zu:

=MIN(WENN(INDEX((H14;L14;P14;T14);;;ZEILE(INDIREKT("1:"&BEREICHE((H14;L14;P14;T14)))))<>0;INDEX((H14;L14;P14;T14);;;ZEILE(INDIREKT("1:"&BEREICHE((H14;L14;P14;T14)))))))

Formelabschluss als ARRAY(!)formel mit gleichzeitig Strg+Shift+Enter (statt mit Enter allein).
Wenn es sich immer um 4 Zellen handelt, kann man es noch vereinfachen auf:

=MIN(WENN(INDEX((H14;L14;P14;T14);;;{1.2.3.4})<>0;INDEX((H14;L14;P14;T14);;;{1.2.3.4})))

Das ist dann KEINE Arrayformel mehr.

[vettelchen]

Lustigerweise kommt da auch wieder #NAME?
Echt krass dass das so kompliziert ist.

Hast du noch einen Lösungsansatz? Vielen dank!!!

---

Ja super geil!! Das war schonmal ein guter Ansatzpunkt.

Nur hat der jetzt nicht vorne den kleinsten Preis (555) sondern den Wert des ersten Bieters!