Kombinationsfeld Werte mit Abhängigkeiten (mit Filtern)

[stefanlogo]

Hallo Gemeinde,

ich möchte gerne, ohne Basic, zwei Kombinationsfelder in eine Tabelle einbetten, die in Abhängigkeit zueinander stehen.
Meine mehrmaligen Versuche, z.B. mit SVERWEIS, blieben bisher ohne Erfolg, sodass ich fast schon am verzweifeln bin.
Nach langer Recherche hab ich zwar einen sehr guten Ansatz gefunden, aber leider konnte ich diesen bis jetzt nicht so umschreiben, das er auch bei mir funktioniert!

Was will ich machen?

Ich möchte gerne mit der ersten Auswahl (Kombinationsfeld) dem Anwender die Möglichkeit geben, eine Maschine auszuwählen. Mit der zweiten Auswahl wählt er explizit einen Artikel zu der zugehörigen Maschine aus.

Mein Ansatz sieht so aus:

Ich verknüpfe die Maschinen mit den Artikel in einer Tabelle. In einer neuen Tabelle, filtere ich nach den jeweiligen Maschinen die erste Tabelle. Die gefilterten Artikel lasse ich dann, nach Auswahl der Maschine, im Kombinationsfeld anzeigen. Fertig!

Hier der letzte Ansatz, den ich gefunden hatte:

[img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]
=WENNFEHLER(INDEX(Nachname[Nachname];KGRÖSSTE((Vorname[Vorname]=$E$1)*(ZEILE(Vorname[Vorname])-1);ZÄHLENWENN(Vorname[Vorname];$E$1)+1-ZEILE(A1)));"")

Mein Vorhaben:

[img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]

Gibt es eine andere Möglichkeit dies zu realisieren oder, was muss ich im Ansatz ändern? Freu mich über jede Hilfe - Danke!!!

lg Stefan

[WillWissen]

Hallo Stefan,

lade deine Datei bitte direkt hier hoch. So geht's:  http://www.clever-excel-forum.de/thread-326.html. Externe Uploader sind im Forum nicht gerne gesehen.

[stefanlogo]

Hier die Tabelle als Datei.

[BoskoBiati]

Hi,

so z.B.:

Code:

=WENNFEHLER(INDEX(D:D;AGGREGAT(15;6;ZEILE(INDEX($E$4:$G$6;;VERGLEICH($B$12;$E$3:$G$3;0)))/(INDEX($E$4:$G$6;;VERGLEICH($B$12;$E$3:$G$3;0))="x");ZEILE(A1)));"")

[stefanlogo]

Danke für den Tipp!

Leider aber funktioniert bei mir die AGGREGAT-Funktion nicht, da ich die 2007er Version habe.

[BoskoBiati]

Hi,

dann Matrixformel mit kkleinste(wenn(....

[neopa]

Hallo Stefan,

ich hab die AGGREGAT()-Formel  teils erweitert (damit man sie von  C12 bis C19 nach unten kopieren kann) und einen Teilbereich darin gekürzt (siehe unten).

Und nachfolgend dafür das Äquivalent als Matrixformel für Excel-Versionen vor 2010 (Formel einfach nach unten kopieren):

	B	C
12	MA-1	Knopf
13		Bügel
14
15	MA-2	Halter
16
17	MA-3	Knopf
18		Halter
19		Bügel
20

Formeln der Tabelle

Zelle Formel C12 {=WENNFEHLER(INDEX(D:D;KKLEINSTE(WENN((INDEX($E$4:$G$6;;VERGLEICH(VERWEIS(9;1/(B$12:B12<>"");B$12:B12);E$3:G$3;0))="x");ZEILE(B$4:B$6));ZEILE()+1-VERWEIS(9;1/(B$12:B12<>"");ZEILE(B$12:B12))));"")}

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Die AGGREGAT()-Formel benötigt den spez. Formelabschluss nicht und ist auch etwas kürzer:

=WENNFEHLER(INDEX(D:D;AGGREGAT(15;6;ZEILE(B$4:B$6)/(INDEX($E$4:$G$6;;VERGLEICH(VERWEIS(9;1/(B$12:B12<>"");B$12:B12);E$3:G$3;0))="x");ZEILE()+1-VERWEIS(9;1/(B$12:B12<>"");ZEILE(B$12:B12))));"")

[BoskoBiati]

Hallo Werner,

müsste es nicht ZEILEN(B$12:B12) heißen?

[neopa]

Hallo Edgar,

in beiden Formeln ist ZEILE(B$12:B12) korrekt.

[atilla]

Hallo Werner,

damit ist aber die Aufgabe noch nicht gelöst, oder?


Der TE schrieb:

ich möchte gerne, ohne Basic, zwei Kombinationsfelder in eine Tabelle einbetten, die in Abhängigkeit zueinander stehen.

Die Auflistungen sollten je nach Auswahl als Dropdown zur Verfügung stehen, so verstehe ich es jedenfalls.