Komplexe WENN Formel reduzieren

[Excel_F]

Hallo zusammen

ich habe eine komplexe Excel Formel. Würde die gerne kürzen und suche nach Alternativen.

=WENN($A$2=0;WENN(ODER(A1=1;A1=2);
WENNFEHLER(WENN($C$36="YTD";CUBEWERT("ThisWorkbookDataModel";$C$44;$C8;$C$37);WENN($C$36="FY";CUBEWERT("ThisWorkbookDataModel";$C$44;$C8);CUBEWERT("ThisWorkbookDataModel";$C$44;$C8;$C$36)));"");
WENNFEHLER(WENN($C$36="YTD";CUBEWERT("ThisWorkbookDataModel";$C$43;$C8;$C$37);WENN($C$36="FY";CUBEWERT("ThisWorkbookDataModel";$C$43;$C8);CUBEWERT("ThisWorkbookDataModel";$C$43;$C8;$C$36)));""));"")



Danke für Hilfe.

Viele Grüße Michael

[ralf_b]

ein versuch

Code:

=WENNFEHLER(
    WENN(
        $A$2 = 0;
        CUBEWERT(
            "ThisWorkbookDataModel";
            WENN(ODER(A1 = 1; A1 = 2); $C$44; $C$43);
            $C8
        );
        CUBEWERT(
            "ThisWorkbookDataModel";
            WENN(ODER(A1 = 1; A1 = 2); $C$44; $C$43);
            $C8;
            WENN($C$36 = "YTD"; $C$36; $C$37)
        )
    );"")

[Excel_F]

Hallo Ralf,

funktioniert leider nur teilweise, da fehlt noch etwas nämlich, das FY

=WENN($A$2=0;WENN(ODER($A$1=1;$A$1=2);
WENNFEHLER(WENN($C$36="YTD";CUBEWERT("ThisWorkbookDataModel";$C$44;$C8;$C$37);WENN($C$36="FY";CUBEWERT("ThisWorkbookDataModel";$C$44;$C8);CUBEWERT("ThisWorkbookDataModel";$C$44;$C8;$C$36)));"");WENNFEHLER(WENN($C$36="YTD";CUBEWERT("ThisWorkbookDataModel";$C$43;$C8;$C$37);WENN($C$36="FY";CUBEWERT("ThisWorkbookDataModel";$C$43;$C8);CUBEWERT("ThisWorkbookDataModel";$C$43;$C8;$C$36)));""));"")

Ansonsten ein sehr guter Ansatz bekomme das aber nicht geändert.

Lieben Gruß

Michael

[ralf_b]

wie schon geschrieben ein Versuch. 

Code:

=WENN(
    $A$2 = 0;
    WENNFEHLER(
        WENN(
            $C$36 = "FY";
            CUBEWERT(
                "ThisWorkbookDataModel";
                WENN(ODER(A1 = 1; A1 = 2); $C$44; $C$43);
                $C8
            );
            CUBEWERT(
                "ThisWorkbookDataModel";
                WENN(ODER(A1 = 1; A1 = 2); $C$44; $C$43);
                $C8;
                WENN($C$36 = "YTD"; $C$37; $C$36)
            )
        );
        ""
    );"")

[BoskoBiati]

Hi,

da der Kollege 365 benutzt, wäre das vielleicht möglich, allerdings kann ich nicht testen ob es funktioniert:

Code:

=LET(xa;WENN((A1=1)+(A1=2);$C$44;$C$43);WENN($A$2=0;WENNFEHLER(WENN($C$36="YTD";CUBEWERT("ThisWorkbookDataModel";xa;$C8;$C$37);WENN($C$36="FY";CUBEWERT("ThisWorkbookDataModel";xa;$C8);CUBEWERT("ThisWorkbookDataModel";xa;$C8;$C$36)));"")))

[Excel_F]

Hallo zusammen,

vielen Dank  für eure Unterstützung funktioniert.

Habe mich für Formel mit LET.... entscheiden, da ich diese noch nicht kannte und wieder was dazugelernt habe.

Vielen herzlichen Dank.

Liebe Grüße

Michael