Komplizierte Formel?

[cysu11]

Hallo liebe Excelianer, 

ich wünsch Euch allen noch ein gesundes neues Jahr 2024! :)

Ich bin auf der Suche nach einer Formel die folgendes macht:

1. Prüfe in Bereich M8 bis R8 ob der Wert 8, 10, 12, oder 13 vorkommt
2. wenn ja, dann diesen Wert der da vorkommt per Sverweis weiter nutzen um diesen im Bereich D22:F27 suchen und Spaltenindex 3 ausgeben.
3. wenn nein dann nichts ausgeben

Den Tel mit dem Sverweis kann ich, aber ich weis nicht wie ich den ersten Teil (Punkt 1) lösen soll?
Kann mir jemand helfen?

Herzlichen Dank & LG
Alexandra

[Ego]

Hallo Alexandra,

schreibe deine gesuchten Werte in eine Liste (hier J2:J5) und vergleiche beide Listen.

=SUMME(1*(M8:R8=J2:J5))>0

[Kuwer]

Hallo Alexandra,

=WENNFEHLER(SVERWEIS(MAX(($M$8:$R$8=8)*8;($M$8:$R$8=10)*10;($M$8:$R$8=12)*12;($M$8:$R$8=13)*13);D22:F27;3;0);"")

Gruß, Uwe

[schauan]

Hallöchen,

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	11	9	2	Liste
2	1	2	3	Suchwerte für Summenformel
3	0
4	2			Suchwerte in Filter-(Vergleich-)funktion

Zelle	Formel
A3	=SUMME(1*(A1:C1=A2:C2))
A4	=FILTER(A1:C1;ISTZAHL(VERGLEICH(A1:C1;{1.2.3};0)))

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 365

Diese Tabelle wurde mit Tab2Html (v2.7.2) erstellt. ©Gerd alias Bamberg

[26865]

Code:

=SVERWEIS(MAX((M8:R8={8;10;12;13})*(M8:R8));D22:F27;3;0)
oder
=SVERWEIS(MAX(WENNFEHLER(SVERWEIS(M8:R8;{8;10;12;13};1;0);));D22:F27;3;0)

[Ego]

Hallo Alexandra,

Entschuldigung.
Die Formeln in meinem letzten Beitrag zeigen nur ob ein gesuchter Wert vorhanden ist.

Diese Formel gibt den ersten gefundenen Wert zurück:

=INDEX(M8:R8;VERGLEICH(1;1*(MMULT(MTRANS(1*(M8:R8={8;10;12;13}));{1;1;1;1})>0);0))

[26865]

Ergänzung für negative Suchwerte:

Code:

=WENNFEHLER(SVERWEIS(MAX(WENN(M8:R8={-5;8;10;12;13};M8:R8));D22:F27;3;0);"")

[Der Steuerfuzzi]

Hallo Alexandra,

1. Prüfe in Bereich M8 bis R8 ob der Wert 8, 10, 12, oder 13 vorkommt

Das ist mE nicht eindeutig, ob die Werte Teil eines Zelleninhalts oder ob einer der Werte in einer der Zelle steht.

Falls es die zweite Alternative ist, hier noch eine Variante:

PHP-Code:

=WENNFEHLER(SVERWEIS(AGGREGAT(15;6;M8:R8/({8;10;12;13}=M8:R8);1);D22:F27;3;FALSCH);"") 


Für die erste Alternative (der Wert steht im Text einer Zelle):

PHP-Code:

=WENNFEHLER(SVERWEIS(AGGREGAT(15;6;M8:R8/FINDEN({8;10;12;13};M8:R8);1);D22:F27;3;FALSCH);"") 


[cysu11]

Hallo zusammen,

vielen lieben Dank für die vielen Lösungen! Das sind interessante Formeln dabei, die alle zum Ziel führen, habe mich für diese hier von Uwe entschieden, weil für leichter zu verstehen ;)

Code:

=WENNFEHLER(SVERWEIS(MAX(($M$8:$R$8=8)*8;($M$8:$R$8=10)*10;($M$8:$R$8=12)*12;($M$8:$R$8=13)*13);D22:F27;3;0);"")

Ganz lieben Dank euch allen, Helmut, Uwe, Andre, Earlfred und Michael! :)

LG, Alexandra

[26865]

Danke für deine tolle Rückmeldung!