Kontoauszug auswerten

[ws-53]

Ich habe vor rund 2J die Aufbereitung meiner Kontodaten auf Power Query umgestellt. Das ist wesentlich eleganter als meine vorherige Formellösung.

[{Boris}]

Hi,

alternativ:
In Deiner Excelversion brauchst Du die AGGREGAT-Variante nicht (mehr), da inzwischen die Verweisfunktionen wie SVERWEIS oder auch VERGLEICH arrayfähig sind.
Bezogen auf die Beispieldatei von rate mit folgende Formel AUSSERHALB der intelligenten Tabelle einfügen - z.B. in

E4:
=INDEX(Tabelle2[Kategorie];VERGLEICH("*"&Tabelle2[Suchbegriff]&"*";Tabelle1[Verwendungszweck];0))

Alternativ mit FILTER:
E4:
=FILTER(Tabelle2[Kategorie];ZÄHLENWENN(Tabelle1[Verwendungszweck];"*"&Tabelle2[Suchbegriff]&"*"))

Die Formel spillt alle Ergebnisse - und das ist auch der Grund, weshalb sie nicht innerhalb einer intelligenten Tabelle stehen darf - Spill und intelligente Tabelle beißen sich.

[ExcelHero]

Hallo zusammen,

kann man auch mehrere Suchbegriffe unter einer einmalig aufgeführten Kategorie zusammenfassen?

Dass man also nicht jede Police einzeln auflistet und in Spalte "D" für Kategorie jedes Mal einzeln "Versicherung" zuuordnet, sondern diese Kategorie nur einmalig aufführt und in Spalte "C" verschiedene Suchbegriffe einträgt.

Wenn man seine Kontoauszüge minutiös auch bei anderen Transaktionen gliedern will - z.B. sowas wie Gastronomie - müsste man sonst jedes einzelne Restaurant in eine eigene Zeile schreiben. Ich würde lieber mehrere Platzhalter in eine Zelle schreiben können - Frage wäre, ob und wie das geht - und darüber schon die meisten Restaurants, Kneipen, Bars etc. abfangen.


Viele Grüße
Ein Neuling

[rate mit]

Hallo ExelHero,

ja, das kann man zusammenfassen - in der Datei von Tober hätte auch *Versicherung* für alle drei Varianten gereicht...

Bei deinem Beispiel musst du dann nur den kleinsten gemeinsamen Nenner finden - sprich alle "Kneipen" oder alle "Restaurant" ...

[ExcelHero]

Hallo rate_mit,

vielen Dank, aber mir ist noch nicht klar wie genau man das macht.

Tippe ich bspw. *Rechtsschutzversicherung* und *Unfallversicherung* in Zelle C23 ein, wird in B9 keine Kategorie ausgegeben.
Ob ich mit Semikolon oder Komma trenne ist dabei unerheblich. 
Wie fasse ich denn mehrere Suchbegriffe einer Kategorie zusammen?

[rate mit]

Da hast du mich wohl falsch verstanden.... bei "Rechtschutzversicherung" ; "Unfallversicherung" ; "Krankenversicherung"  ist die kleinste Gemeinsamkeit "Versicherung" (wenn du immer weißt, das keine anderen Wortbestandteile vorkommen können, dann kannst du auch "Ver" nehmen).... weil die Wörter innerhalb der Zelle an verschiedenen Stellen stehen können, musst du nur noch ein * einfügen - also *Versicherung*

[HKindler]

Hi,

die Formel würde ich eher so schreiben (dann bleibt sie konsistent und es ist egal wo sich Tabelle2 befindet):

Code:

=WENNFEHLER(INDEX(Tabelle2[Kategorie];AGGREGAT(15;6;(ZEILE(Tabelle2[Suchbegriff])-ZEILE(Tabelle2[#Kopfzeilen]))/(ZÄHLENWENN([@Verwendungszweck];Tabelle2[Suchbegriff])>0);1));"")

Für neue Excel:

Code:

=INDEX(FILTER(Tabelle2[Kategorie];ZÄHLENWENN([@Verwendungszweck];Tabelle2[Suchbegriff]));1)

Die Index-Funktion braucht man hier um - wie bei der anderen Formel - nur die erste Übereinstimmung zurück zu geben. Will man alle Übereinstimmungen, dann so:

Code:

=TEXTVERKETTEN(", ";WAHR;FILTER(Tabelle2[Kategorie];ZÄHLENWENN([@Verwendungszweck];Tabelle2[Suchbegriff])))