Korrektur bei mehreren Dateien und Reitern

[carusse88]

Hallo,

ich erläutere zunächst einmal den Sachverhalt:

Ich habe bei Excel 2007 mehrere Dateien angelegt. Jede dieser Dateien hat immer 9 Reiter. Nun möchte ich eine Änderung vornehmen, die alle angelegten Dateien in jeweils einem Reiter betrifft. Die Position der Reiter, in dem die Änderung vorgenommen wird, ist immer unterschiedlich. Gibt es eine simple Lösung, wie ich die Änderung in allen Dateien vornehmen kann?

Beispiel:

Datei A - Reiter 5
Datei B - Reiter 3
Datei C - Reiter 6
Datei D - Reiter 8

In dem jeweiligen Reiter steht immer die Information "X", diese soll immer in Information "Y" umbenannt werden.

Vielen Dank schon einmal vorab für Euer Feedback!

LG
carusse88

[UweD]

Hallo

das lege ich zu Grunde

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	Datei	Reiter
2	AAA	5
3	BBB	3
4	CCC	6
5	DDD	8

In ein Modul diesen Code

Code:

Sub XY()
    Dim Pfad As String, Ext As String, Datei As String, Reiter As Integer
    Dim TB As Worksheet, WB As Workbook
    Dim Z1 As Integer, Z As Integer, LR As Integer, SP As Integer
    Dim Alt As String, Neu As String
   
    Pfad = "E:\Excel\Temp\"
    Ext = ".xlsx"
    SP = 1 'Daten stehen in A
    Z1 = 2 'ab Zeile
   
    Alt = "X"
    Neu = "Y"
   
    With Sheets("Tabelle1")
        LR = .Cells(.Rows.Count, SP).End(xlUp).Row 'letzte Zeile der Spalte
       
        For Z = Z1 To LR
            Datei = .Cells(Z, SP)
            Reiter = .Cells(Z, SP + 1) 'Nr. des Reiters
           
            If Dir(Pfad & Datei & Ext) <> "" Then
                Set WB = Workbooks.Open(Filename:=Pfad & Datei & Ext)
               
                WB.Sheets(Reiter).Cells.Replace What:=Alt, Replacement:=Neu, LookAt:=xlWhole
                WB.Close True
           
            Else
                MsgBox Datei & Ext & ": nicht gefunden"
            End If
        Next
    End With
       
End Sub

Durchläuft deine Einträge
öffnet die Datei
Tauscht auf dem N ten Reiter alle X, die alleine in einer Zelle stehen in ein Y
schließt die Datei mit speichern


LG UweD