Krankheitstage filtern

[Mamamia]

Hallo Liebes Forum,

Ich habe unsere Stundenerfassung und möchte nun ( wenn möglich) die Krankheitstage / Unfall etc. filtern. 
Nun soll aber wenn die Krankheitstage mehr als 3 darauffolgende Tage sind diese Ausgeben, ansonsten nicht. wenn aber im selben Monat nochmals Krankheitstage sind ( welche nicht an das vorhergehende Datum mit dem lezten Krankheitstag folgen)von mehr als 3 Tage sollen diese auch ausgegeben werden.

Ist dies überhaupt möglich?

Ich möchte dies für jeden Monat dann machen damit ich dies auswerten kann und in einer anderen Liste Zusammenfassen kann.

Nur 1 Krankheitsfall auszuwerten ist nicht das Problem, soweit bin ich auch gekommen.

Anbei die Liste 

Liebe Grüsse Mammamia

[Gast 123]

Hallo  Mamamia

mir fallen als erstes die -verbundenen Zellen- auf.  Das macht kein Excel Profi, erschwert das Bearbeiten.
Das werden bestimmt auch die Formel Experten als erstes kritisieren.  Führt häufig zu Problemen.
Ich empfehle dir alle Daten in eine Spalte, und die -Spaltenbreite- entsprechend zu ändern!

Ob man das mit Formeln auswerten kann, weiss ich nicht.   Warte mal ab was die Kollegen dazu sagen.

mfg Gast 123

[Sigi.21]

Hallo Mamamia,

ich kann dir eine VBA-Fkt. zur Verfügung stellen, die ich für andere Zwecke mal brauchte.

Da werden jetzt nicht die einzelnen Tage ausgewiesen, sondern die Tage in der Form:  "von - bis - Nettotage" (jew. größer 3)
(s. Mappe)


Gruß Sigi

[{Boris}]

Hi,

=LET(x;SPALTENWAHL(FILTER(A3:Q33;L3:L33=V2;"");2;12);WENN(ZEILEN(x)<4;"";x))

Analog für Krank 50%

[Mamamia]

Guten Morgen,

Vielen Dank für Deine Hilfe, klappt aber nur bedingt. Aber der Lösungsvorschlag geht in die richtige Richtung.
wenn ich Zbsp. den 20.01.2025 raus nehme als Krank, zeigt es mir oben den 13.01.-16.01 auch nicht mehr an, obwohl dies ja 4 Tage sind

Umgekehrt aber schon. Wenn ich oben den 13.01.2025 rausnehme dafür den 20.01.2025 drin lasse listet Excel korrekt auf.

Ebenso müsste das Wochenende und auch Feiertage mitgerechnet werden.

Kann ja sein dass ein Mitarbeiter von 13.01.2025 durchgehend bis 26.01.2025 Krankgeschrieben ist ( dann müssten alle Tage mitgezählt werden inkl. Wochenende)

Liebe Grüsse Mamamia

---

Guten Morgen Boris,

Ich danke DIr auch, jedoch gibt Deine Formel eigentlich das gleiche aus wie ich auch bereits gehabt habe.
Den 20.01.2025 müsste es nicht auflisten da dies nur ein einzelner Tag ist und für mich nicht relevant ist.

Liebe Grüsse Mamamia

[EA1950]

Hallo,

folgende Formel sollte deine Anforderungen erfüllen (einfach in die Formeleditierzeile der Zielzelle kopieren):
=LET(Abw; $V$2; DtAbw; SPALTENWAHL($A$3:$Q$33; 2; 12); DtA; FILTER(DtAbw; INDEX(DtAbw; 0; 2) = Abw; ""); AbwNr; SCAN(0; SEQUENZ(ZEILEN(DtA)); LAMBDA(Akk;Zl; LET(AktDt; INDEX(DtA; Zl; 1); LztDt; WENN(Zl = 1; 1; INDEX(DtA; Zl - 1; 1)); Akk + WENN(AktDt - LztDt = 1; 0; 1)))); DtAbwNr; HSTAPELN(DtA; AbwNr); AbwNrCt; GRUPPIERENNACH(AbwNr; AbwNr; ANZAHL; ; 0); AbwNr4Ct; FILTER(INDEX(AbwNrCt; 0; 1); INDEX(AbwNrCt; 0; 2) >= 4; ""); WEGLASSEN(REDUCE(""; AbwNr4Ct; LAMBDA(Akk;Nr; VSTAPELN(Akk; FILTER(DtA; INDEX(DtAbwNr; 0; 3) = Nr; "")))); 1))

Dabei steht in Zelle V2 dein Abwesenheitsgrund (zB. "krank", "krank 50%", ...) und im Bereich A3:Q33 deine Daten, wie in der Beispieldatei enthalten. Dabei könnte der Datenbereich auch auf A3:L33 geschrumpft werden. Diese beiden Teile sind in obiger Formel mit fetter Schrift gekennzeichnet.

[Mamamia]

Guten Morgen,

Oh wow, das ist genau das was ich gesucht habe, vielen lieben Dank, Hammer!!!
Ich staune immer wieder was es da für Möglichkeiten gibt, wo ich als Laie niemals auf diese Formel gekommen wäre.

Dieses Forum ist einfach Gold Wert....

Ich wünsche ein sonniges Wochenende und nochmals vielen Dank.

Liebe Grüsse Mamamia