Leere Zeile löschen mit SVERWEIS bei Kreuz setzen

[Hoshy1]

Grüß Gott an die Exceltüftler,
ich brauche Eure Hilfe,

ich möchte in einer Exceltabelle leere Zeile aus einer Auflistung entfernen.
Es klappt auch recht gut mit der Formel: {=WENN(ZEILE(B1)>ANZAHL2(B:B);"";INDEX B:B;KKLEINSTE(WENN(B$1:B$1000<>"";ZEILE($1:$1000));ZEILE(B1))))}
.
(siehe dazu Tabelle2 Spalte F)

Als Steigerung möchte ich gerne z.B.: bei Tabelle2, wenn in Spalte A ein "X" steht genau dieselbe Funktion ausführen lassen. Zusätzlich möchte ich gerne die Informationen aus der Tabelle Spalte C und D mit anzeigen lassen. Also quasi die Funktion zum löschen der leeren Zeilen und einem SVERSWEIS für die anderen Informationen beim setzen eines Kreuzes.

Hier meine Versuchsformel: {=WENN(A1:A100="X";WENN(ZEILE(B1)>ANZAHL2(B:B);"";INDEX B:B;KKLEINSTE(WENN(B$1:B$1000<>"";ZEILE($1:$1000));ZEILE(B1))));"")}.


Leider bekomme ich das bisher nicht hin und ich finde den Fehler nicht. Wenn ich in Tabelle2 Spalte A1 ein Kreuz setzen erscheinen in der Tabelle3 Spalte F gleich alle Daten aus B. Nehme ich das Kreuz wieder weg, sind auch alle Daten wieder verschwunden.
Wie ich dann auch noch dort den SVERWEIS einbauen soll, übersteigt leider meine Kenntnisse.

Ich möchte also nur die Daten aus Spalte B anzeigen lassen die mit einem Kreuz in A gekennzeichnet wurden und dann auch noch die leeren Zeilen löschen mit SVERSWEIS Funktion

Ich hoffe es ist verständlich ausgedrückt und hoffe auf Eure Hilfe


Tim Kretschmann

[steve1da]

Hola,

Code:

=WENNFEHLER(INDEX(Tabelle2!$B$1:$B$12;AGGREGAT(15;6;ZEILE($A$1:$A$12)/((Tabelle2!$A$1:$A$12="x")*(Tabelle2!$B$1:$B$12<>""));ZEILE(A1)));"")

Gruß,
steve1da

[Hoshy1]

Große Klasse,

das funktioniert richtig prima und die leeren Zeilen sind auch gelöscht. Wo kann man dann denn jetzt aber noch den SVERWEIS einbauen?
Oder ist das sogar schon in der fuktion mit enthalten?

Tim Kretschmann

[steve1da]

Hola,

ändere die Formel:

Code:

=WENNFEHLER(INDEX(Tabelle2!B$1:B$12;AGGREGAT(15;6;ZEILE($A$1:$A$12)/((Tabelle2!$A$1:$A$12="x")*(Tabelle2!$B$1:$B$12<>""));ZEILE(A1)));"")

und zieh sie nach rechts und nach unten.

Gruß,
steve1da

[Hoshy1]

Wahnsinn  :18:

total Klasse! Es funktioniert einfach Klasse.
Vielen Dank.

Und ich tüftle ewig umher  :20:



Tim Kretschmann