Letzten Wert eines definierten Bereiches in einer Spalte finden

[JoergPorsch]

Hallo zusammen,

ich weiss das es viele INDEX und VERWEIS Formeln dazu gibt, habe aber immer das Problem das mir bei meinen Versuchen nicht der richtige Wert angezeigt wird.

Folgendes Problem:


Ich habe eine Tabelle, in der ich in der Spalte A und B jeweils einen Bereich habe (z.B. Zeilen 7 -23) in der Werte stehen, es werden aber nicht in allen Zeilen Werte stehen, sondern z.B. nur bis Zeile 15.

Nun möchte ich in der Zelle A25 den letzten Wert aus dem Bereich A7-A23 stehen haben, also in diesem Fall sollte er mir den Wert der Zelle A15 ausgeben.

Ich habe euch mal eine Beispieltabelle angehängt. Evtl. hat hierzu einer eine Lösung auf die ich im Moment einfach nicht komme.

Danke schonmal.

Gruss Joerg

[shift-del]

Hallo Joerg

http://excelformeln.de/formeln.html?welcher=50

[coemm]

Hallo Joerg,

meinst du so?

=INDEX(A1:A23;SUMMENPRODUKT(MAX((A1:A23<>"")*ZEILE(A1:A23))))

[Jockel]

Hallo Jörg...:

Code:

=VERWEIS(9^99;A7:A23)

oder wenn sich doch mal ein Text verirrt..:

Code:

=VERWEIS(2;1/(A7:A23<>"");A7:A23)

[snb]

Code:

=INDEX($A$7:$A$23;MATCH(0;$A$7:$A$23;-1);1)

[Jockel]

Code:

=INDEX($A$7:$A$23;MATCH(0;$A$7:$A$23;-1);1)

Hallo, das Danke gab's für (du weißt schon)... Deine Formel klappt aber nur bei ausschließlich positiven Werten... ... ich würde da eher ff. nehmen..:

Code:

=INDEX($A$7:$A$23;VERGLEICH(-9^9;$A$7:$A$23;-1);)

[JoergPorsch]

Hallo zusammen,

danke erstmal für die schnellen und vilen Antworten.

Kurz der Reihe nach:

@shift-del: die Seite kenne ich bereits, allerdings sind bisher alle Versuche gescheitert.

@Conny: Funktioniert nicht, habe deine Formel noch an meinem Bereich angepasst

Code:

=INDEX(A7:A23;SUMMENPRODUKT(MAX((A7:A23<>"")*ZEILE(A7:A23))))

Im Bereich über A7 stehen bei mir nämlich noch andere Dinge die nicht in Bezuig genommen werden sollten. Leider funktioniert deine Formel nicht, bekomme immer nur 0 als Ausgabewert.

@Jockel: Danke, beide Formeln funktionieren.

@snb: die von Jockel angepasste Formel funktioniert ebenfalls.

DAnke an alle, ihr habt mir super geholfen.

Tolles Forum ;).

Gruss Joerg

[Jockel]

Hallo zusammen,

...
@Conny: Funktioniert nicht, habe deine Formel noch an meinem Bereich angepasst

Code:

=INDEX(A7:A23;SUMMENPRODUKT(MAX((A7:A23<>"")*ZEILE(A7:A23))))

Im Bereich über A7 stehen bei mir nämlich noch andere Dinge die nicht in Bezuig genommen werden sollten. Leider funktioniert deine Formel nicht, bekomme immer nur 0 als Ausgabewert.

...

Gruss Joerg

Hallöchen, du solltest wenn du schon anpaßt, richtig anpassen..:

Code:

=INDEX(A7:A23;SUMMENPRODUKT(MAX((A7:A23<>"")*ZEILE(A1:A17))))

[shift-del]

@shift-del: die Seite kenne ich bereits, allerdings sind bisher alle Versuche gescheitert.

Das liegt garantiert nicht an excelformeln.de.