Letzter Wert in Spalte, dann Nachbarzelle anzeigen

[Silvio]

Hallo Leute,
könnte mir bitte jemand bei folgenden Problem behilflich sein.
Es ist ein Auszug einer Datei als Anlage beigefügt, der die Frage veranschaulicht.
In Spalte C sind die Tage des Monats, in Spalte D die Einträge.
In C37 sollte nun das Datum (Spalte C) der letzten Eintragung (Spalte D) erscheinen.
Im vorliegenden Beispiel der 24. Sept. 2024.
Danke, Gruß und einen schönen Vorfeiertagsabend
Silvio

[juvee]

Hi,

=INDEX($C$4:$C$34;VERWEIS(2;1/($D$4:$D$34<>"");ZEILE($A$1:$A$31));1)

VG Juvee

[Jockel]

Hallo, eine Möglichkeit wäre..:

PHP-Code:

=INDEX(C1:C34;VERGLEICH(0;D:D;-1)) 


bzw..:

PHP-Code:

=INDEX(C1:C34;VERGLEICH("";D:D;-1)) 


[Jack_d]

Moin

In deinem Beispiel geht folgende Formel =)

Code:

=INDEX(C:C;SUMMENPRODUKT(MAX((D4:D34<>"")*ZEILE(4:34))))

Grüße Jack

[BoskoBiati]

Hi,

oder auch:

Code:

=INDEX(C:C;MAX(WENN(D:D<>"";ZEILE(D:D))))

[Jockel]

Hallo Edgar, deine letzte Formel kann ich nicht anwenden. Ich kann keinen Tastenkombination (Matrixformel-abschluss) aufgrund meiner Behinderung.  Außerdem benutze ich XL2019. da müßte man noch so abschließen.Also nehme ich meine Formeln. Jede(r) wie er (sie) es braucht...

[Silvio]

Hallo,
vielen Dank für die schnelle Antwort.
So viele Lösungen und mir ist keine eingefallen, dass ist schon etwas peinlich. 
Aber ich habe wieder etwas gelernt!
Nochmals vielen Dank und einen schönen Abend
Gruß
Silvio

[knobbi38]

Ich kann keinen Tastenkombination (Matrixformel-abschluss) aufgrund meiner Behinderung.

Das könnte man z.B. mit dem OnScreenKeyboard umgehen. Damit kannst du auf jeden Fall die Formel so abschließen.
Das OnScreenKeyboard kann per ausführen "osk" gestartet werden.

[snb]

PHP-Code:

=INDEX(C:C;MAX((D:D<>"")*ROW(D:D))) 


ctrl-shft-Enter

[Jockel]

Hallo, ich muss die Finger von der Tastatur lassen oder mich besser ausdrücken. ich brauche diese matrix-Formel nicht. Trotzdem dankeAußerdem hatte ich zwei einfache Formeln gepostet...