Listbox zeigt nur ersten Eintrag

[Robby]

Hallo wer kann helfen?


Mit einer UserForm trage ich Name,Vorname und Email in eine Tabelle ein. In der ListBox erscheinen dann auch die Namen jeweils zum durchblättern, falls man was ändern möchte.
Da funktioniert allerdings nur so lange, wenn es den Namen nur einmal gibt. Ist der Name "Meier" zum Beispiel mehrfach vorhanden mit verschiedenen Vornamen, werden nur die Daten des zuerst
eingetragenen "Meier" in die TextBoxen der UserForm eingetragen. Wer hat eine Idee? Es muss irgendwie mit einer zweispaltigen ListBox funktionieren. Mit RowSource Eigenschaften komm ich auch nicht weiter.
Hier der Code:

Code:

Option Explicit
Option Compare Text


'Neuer Eintrag Schaltfläche Ereignisroutine
Private Sub CommandButton1_Click()
   Dim lZeile As Long
     'Wenn der Benutzer einen neuen Eintrag erzeugen möchte,
     'erstellen wir einen neuen Eintrag in der ListBox und markieren
     'diesen, damit der Benutzer die Daten eintragen kann
    
     lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die überschriftrn
     'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
     Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
         lZeile = lZeile + 1 'Nächste Zeile bearbeiten
     Loop
    
     'Nach Durchlauf dieser Schleife steht lZeile in der ersten leeren Zeile von Tabelle1
     'Neuen Eintrag in die Tabelle1 schreiben, Spalte ID muss gefüllt sein, damit
     'unsere Routinen die Zeile wiederfinden!
     Tabelle1.Cells(lZeile, 1) = CStr("Neuer Eintrag Zeile " & lZeile)
    
     'Und neuen Eintrag in die UserForm eintragen

     'ListBox1.AddItem CStr("Neuer Eintrag Zeile " & lZeile)
    
     'Den neuen Eintrag markieren mit Hilfe des ListIndexes
     ListBox1.ListIndex = ListBox1.ListCount - 1
     'Durch das Click Ereignis der ListBox werden die Daten automatisch geladen
    
End Sub

Code:

'Löschen Schaltfläche Ereignisroutine
Private Sub CommandButton2_Click()
   Dim lZeile As Long
  
     'Wenn kein Datensatz in der ListBox markiert wurde, wird die Routine beendet
     If ListBox1.ListIndex = -1 Then Exit Sub
  
     'Zum Löschen benötigen wir die Zeilennummer des ausgewählten Datensatzes
     lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die Überschriften
     'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
     Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
    
         'Datensatz ID Spalte mit selektiertem Eintrag der ListBox vergleichen
         If ListBox1.Text = Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) Then
            
             'Eintrag gefunden, die ganze Zeile wird nun gelöscht
             Tabelle1.Rows(CStr(lZeile & ":" & lZeile)).Delete
            
             'Die ListBox muss nun neu geladen werden!
             Call UserForm_Initialize
             If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
            
             Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
            
         End If
    
         lZeile = lZeile + 1 'Nächste Zeile bearbeiten
     Loop
    
End Sub

Code:

'Speichern Schaltfläche Ereignisroutine
Private Sub CommandButton3_Click()
   Dim lZeile As Long
  
     'Wenn kein Datensatz in der ListBox markiert wurde, wird die Routine beendet
     If ListBox1.ListIndex = -1 Then Exit Sub
    
     'Wir müssen prüfen, ob die ID Spalte auch gefüllt ist!!
     If Trim(CStr(TextBox1.Text)) = "" Then
         'Meldung ausgeben
         MsgBox "Sie müssen mindestens einen Namen eingeben!", vbCritical + vbOKOnly, "FEHLER!"
         'Abbrechen der Speicherroutine
         Exit Sub
     End If
     'Ausbauoption: Prüfen, ob die ID in Tabelle1 Spalte 1 schon vorhanden ist!
    
     'Zum Speichern benötigen wir die Zeilennummer des ausgewählten Datensatzes
     lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die Überschriften
     'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
     Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
    
         'Datensatz ID Spalte mit selektiertem Eintrag der ListBox vergleichen
         If ListBox1.Text = Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) Then
            
             'Eintrag gefunden, TextBoxen in die Zellen schreiben
             Tabelle1.Cells(lZeile, 1).Value = Trim(CStr(TextBox1.Text)) 'Name
             Tabelle1.Cells(lZeile, 2).Value = TextBox2.Text 'Vorname
             Tabelle1.Cells(lZeile, 3).Value = TextBox3.Text 'email
      
            
             'Die ListBox muss nun neu geladen werden
             'allerdings nur, wenn sich der Name (ID) geändert hat
             If ListBox1.Text <> Trim(CStr(TextBox1.Text)) Then
                 Call UserForm_Initialize
                 If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
             End If
            
             Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
            
         End If
    
         lZeile = lZeile + 1 'Nächste Zeile bearbeiten
     Loop
    
End Sub

'Beenden Schaltfläche Ereignisroutine
Private Sub CommandButton4_Click()
     Unload Me
End Sub

Code:

'Klick auf die ListBox Ereignisroutine
Private Sub ListBox1_Click()
   Dim lZeile As Long
     'Wenn der Benutzer einen Namen anklickt, suchen wir
     'diesen in der Tabelle1 heraus und tragen die Daten
     'in die TextBoxen ein.
    
     'Wir löschen standardmäßig alle bisherigen TextBoxen-Inhalte
     TextBox1 = ""
     TextBox2 = ""
     TextBox3 = ""

    
     'Nur wenn ein Eintrag selektiert/markiert ist
     If ListBox1.ListIndex >= 0 Then
    
         lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die Überschriften
         'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
         Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
        
             'Wenn wir den Namen aus der ListBox1 in der Tabelle1 Spalte 1
             'gefunden haben, übertragen wir die anderen Spalteninhalte
             'in die TextBoxen!
             If ListBox1.Text = Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) Then
            
                 'TextBoxen füllen
                 TextBox1 = Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) 'Name
                 TextBox2 = Tabelle1.Cells(lZeile, 2).Value 'Vorname
                 TextBox3 = Tabelle1.Cells(lZeile, 3).Value 'email
                 

            
                 Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
            
             End If
        
             lZeile = lZeile + 1 'Nächste Zeile bearbeiten
        
         Loop
        
     End If
    
End Sub

Code:

Private Sub UserForm_Activate()
     'Wenn die Eingabemaske angezeigt wird, markieren wir den ersten Namen
     'jedoch nur, wenn auch Einträge in der Liste stehen
     If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
End Sub

'Startroutine, wird ausgeführt bevor die Eingabemaske angezeigt wird
Private Sub UserForm_Initialize()
   Dim lZeile As Long
  
     'Alle TextBoxen leer machen
     TextBox1 = ""
     TextBox2 = ""
     TextBox3 = ""

  
     'In dieser Routine laden wir alle vorhandenen
     'Einträge in die ListBox1
     ListBox1.Clear 'Zuerst einmal die Liste leeren
    
     lZeile = 2 'Start in Zeile 2, Zeile 1 sind ja die Überschriften
     'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
     Do While Trim(CStr(Tabelle1.Cells(lZeile, 1).Value)) <> ""
        
         'Aktuelle Zeile in die ListBox eintragen
         
        ListBox1.AddItem Trim(CStr(Tabelle1.Cells(lZeile, 1).Value))
        
         lZeile = lZeile + 1 'Nächste Zeile bearbeiten
        
     Loop
    
End Sub

[Klaus-Dieter]

Hallo Robby,

ich glaube nicht, dass jemand an Hand des Quelltextes dein UserForm zum Testen nachbauen wird.

[Glausius]

Hallo,

RowsSource kann dir da nicht helfen, denn das ist die Zeilenzahl.
Du musst in der Listbox ColumnCount für die Spaltenanzahl und ColumnWidths für die Spaltenbreiten verwenden.
z.B. ColumnCount - 2
      ColumnWidths - 5 cm,6 cm

[Robby]

die UserForm nachbauen ist eigentlich ein Kinderspiel:
Ich schaue mir den Quelltext an und erzeuge mir eine leere Userform (und copiere den Code dort hinein) und anschliessen die Elemente  (wie im Quelltext- ListBox1, TextBox1, TextBox2,TextBox3, usw)  mit der Toolbox und fertig.


Ich kann sie aber auch noch gerne hochladen.

LG
Robert

[Robby]

mit dem ColumnCount ist mir schon klar, ich habe aber keine Lösung gefunden, wie und wo genau ich das einfügen soll.
Wer hat eine Idee?

[Klaus-Dieter]

Hallo Robby,

die UserForm nachbauen ist eigentlich ein Kinderspiel:

das weiß ich auch, aber bitte nicht vergessen: du möchtest etwas von uns, da solltest du schon etwas mehr liefern.
Dann gibt es auch noch Spezialisten, (zu denen du wenigstens nicht gehörst), die finden es toll, sämtliche Objekte mit eigenen Namen zu versehen, aus denen oft nicht zu erkennen ist, um was es sich handelt. - Also ich helfe nur, wenn das UserForm dabei ist.

[Robby]

ist jetzt hochgeladen. Danke

[schauan]

Hallo Robby,

wenn Du in Deiner Listbox ein komplettes Abbild der Zeilen Deiner Übersicht hast, kannst Du anhand der Nummer des in der Listbox gewählten Eintrages einen direkten Bezug zur Zeile der Übersicht herstellen. RowSource für den Datenbereich könntest Du dabei auch benutzen.

Ausprobieren kannst Du das mit diesem Code:

Code:

Private Sub ListBox1_Click()
MsgBox Me.ListBox1.ListIndex
End Sub

Wenn Du den ersten Eintrag anklickst, bekommst Du 0 als Meldung.
Wenn Deine Daten in Zeile 2 beginnen, musst Du dann immer nur 2 zum Listindex dazuzählen und bist in der richtigen Zeile.