Listen per Monat

[delenn]

Hallo

habe ein Datum (register)
in denen Tage stehen und deren Inhalt.

Und ein List-Register
aus dem sollen sich für den angegebenen Monat die Tage anzeigen lassen
stehe mom aber auf dem schlauch wie ich das Lösen kann.

Also wenn im Datumsregister ein Datum Auftritt das in dem angegebenen Monat (a1) liegt,
soll des erste Datum in A2 erscheinen, das 2. Datum in A3 u.s.w.

Danke

[shift-del]

Hallo

Arbeitsblatt mit dem Namen 'Liste'
	A
1	01.01.2016
2	07.01.2016
3	12.01.2016
4	21.01.2016
5	22.01.2016
6	26.01.2016
7	30.01.2016
8
9
10	01.02.2016
11	04.02.2016
12	12.02.2016
13	19.02.2016
14	18.02.2016
15	23.02.2016
16
17
18
19	01.03.2016
20	03.03.2016
21	08.03.2016
22	17.03.2016
23	22.03.2016
24
25
26
27

Zelle	Formel
A2	=WENNFEHLER(INDEX(Datum!$A:$A;AGGREGAT(15;6;ZEILE(Datum!$A$2:$A$16)/(MONAT(Datum!$A$2:$A$16)=MONAT(A$1));ZEILEN(A$2:A2)));"")
A11	=WENNFEHLER(INDEX(Datum!$A:$A;AGGREGAT(15;6;ZEILE(Datum!$A$2:$A$16)/(MONAT(Datum!$A$2:$A$16)=MONAT(A$10));ZEILEN(A$11:A11)));"")
A20	=WENNFEHLER(INDEX(Datum!$A:$A;AGGREGAT(15;6;ZEILE(Datum!$A$2:$A$16)/(MONAT(Datum!$A$2:$A$16)=MONAT(A$19));ZEILEN(A$20:A20)));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[delenn]

#shift-del 


Danke
wie kann ich das in Excel 2007 anwenden?

[shift-del]

wie kann ich das in Excel 2007 anwenden?

Etwas länger und etwas mehr Tastendrücke.

Arbeitsblatt mit dem Namen 'Liste'
	A
1	01.01.2016
2	07.01.2016
3	12.01.2016
4	21.01.2016
5	22.01.2016
6	26.01.2016
7	30.01.2016
8
9
10	01.02.2016
11	04.02.2016
12	12.02.2016
13	19.02.2016
14	18.02.2016
15	23.02.2016
16
17
18
19	01.03.2016
20	03.03.2016
21	08.03.2016
22	17.03.2016
23	22.03.2016
24
25
26
27

Zelle	Formel
A2	{=WENNFEHLER(INDEX(Datum!$A:$A;KKLEINSTE(WENN(MONAT(Datum!$A$2:$A$16)=MONAT(A$1);ZEILE(Datum!$A$2:$A$16));ZEILEN(A$2:A2)));"")}
A11	{=WENNFEHLER(INDEX(Datum!$A:$A;KKLEINSTE(WENN(MONAT(Datum!$A$2:$A$16)=MONAT(A$10);ZEILE(Datum!$A$2:$A$16));ZEILEN(A$11:A11)));"")}
A20	{=WENNFEHLER(INDEX(Datum!$A:$A;KKLEINSTE(WENN(MONAT(Datum!$A$2:$A$16)=MONAT(A$19);ZEILE(Datum!$A$2:$A$16));ZEILEN(A$20:A20)));"")}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[steve1da]

Hola,


@delenn: ging dir das hier nicht schnell genug?

http://ms-office-forum.net/forum/showthr...p?t=330189

Gruß,
steve1da

[delenn]

#shift-del 
Danke
genau das wars