Logik-Chaos bei Summenprodukt

[stoxxii]

Hallo Guys,
Hallo Admins,

leider bleibe ich bei einer Logik mit der SummenProdukt- Formel hängen

Bitte seit so nett und schaut kurz in den Anhang in das Sheet  + Screenshot.

Es wäre schön, wenn Ihr in meinem " Summen-Produkt" den Fehler korrigiert
speziell für die Jahres-Abfrage :  2017 und 2018  ... Zelle G9 + H9 ...

weil die Logik-Abfragen eigentlich praktisch sind  (wenn man es rafft)
... anstatt mit Funktion Vergleich().

Danke für Tipps & Mühen vorab.

Beste Grüße
stoxxii

[steve1da]

Hola,
und was der "Fehler" ist, ist super geheim?
Sorry, du schmeißt hier ne Tabelle hin, sagst "irgendwas stimmt mit Summenprodukt nicht"....und das wars?

Code:

=SUMMEWENNS($D$2:$D$121;$B$2:$B$121;G9;$C$2:$C$121;$F$10;$A$2:$A$121;$F$2)

Mehr als raten kann man da nicht.
Gruß,
steve1da

[rate mit]

Hallo,

in G10:

Code:

=SUMMEWENNS($D$2:$D$121;$B$2:$B$121;$G$9;$C$2:$C$121;F10;$A$2:$A$121;INDIREKT(ADRESSE($G$2+1;6)))

[stoxxii]

Hallo " ",

Danke    so klappt es meiner deiner SummeWennS  + Adresse(indirekt....

Falls der Helmut oder Holger nochmal kurz drüber schauen könnten ...

kann man da an  meiner SummenProdukt noch etwas verbessern, damit es auch so klappt , wie mir der SummenWennS  ??

Danke vorab.

Beste Grüße
stoxxii

[Klaus-Dieter]

Hallo,

habe den Fehler gefunden, heiße aber nicht Helmut oder Holger ...

[BoskoBiati]

Hi,

ohne INDIREKT:

Code:

=SUMMEWENNS($D:$D;$B:$B;G$9;$C:$C;$F10;$A:$A;INDEX($F$2:$F$6;$G$2))

SUMMEWENNS ist auf jeden Fall besser als SUMMENPRODUKT, da Letzteres ein Ressourcenfresser ist.

Code:

=SUMMENPRODUKT($D:$D;($B:$B=G$9)*($C:$C=$F10)*($A:$A=INDEX($F$2:$F$6;$G$2)))

[stoxxii]

Hallo Klaus-Dieter,

sorry ... falls ich deinen Namen verwexelt habe  

obwohl ich hatte hier schon echte gute Lösungen von einem Helmut und Holger für diverse Problemstellungen bekommen.

aber bitte sag mir, welchen Fehler du bei mir gefunden hast ??

Danke vorab.

BG
stoxxii

[BoskoBiati]

Hi,

alternativ:

Code:

=AGGREGAT(15;6;$D:$D/($A:$A=INDEX($F$2:$F$6;$G$2))/($B:$B=G$9)/($C:$C=$F10);1)
=INDEX($D:$D;VERGLEICH(INDEX($F$2:$F$6;$G$2)&G$9&$F10;$A:$A&$B:$B&$C:$C;0))

[Klaus-Dieter]

Hallo,

sorry ... falls ich deinen Namen verwexelt habe 

es ging mir nicht um meinen Namen, sondern darum, das ich es irgendwie daneben finde, bestimmt Leute anzusprechen, dann fehlt mir eben die Motivation Lösungen zu präsentieren.

Schreibe die Formel in Zelle G10 so: =SUMMENPRODUKT(($C$2:$C$121=$F10)*($B$2:$B$121=G$9)*($A$2:$A$121=$F$2)*($D$2:$D$121))  dann kannst du sie nach rechts und unten ziehen und alles ist gut.

[BoskoBiati]

Hallo Klaus-Dieter,

das funktioniert aber nur für India, alle anderen Ländern ergeben dann die gleichen Werte, die India hat.