MAXWENNS mit 2 Kriterien pro Spalte

[Umstaende_halber]

Hallo zusammen,

gesucht wird eine Formel die ähnlich wie MAXWENNS arbeitet. Leider kann man bei dieser Formel nur ein Kriterium pro Spalte angeben. Gebraucht werden aber in meinem Fall 2 Kriterien pro Spalte. Es geht hierbei um Auswertung einer Tabelle.

Beispiel:
=MAXWENNS($D$11:$D$24;$B$11:$B$24;F11;$C$11:$C$24;"B")

Es wird noch ein "A" Kriterium in der gleichen Spalte benötigt. Dabei soll grundsätzlich der Maxwert "A" oder "B" je nachdem was höher ist, ausgegeben werden. Das "C" Kriterium soll ignoriert werden. Per Pivot ist es sehr einfach umzusetzen (durch den Filter), geht es aber auch mit einer Formel? Oder ist das Formeltechnisch nicht umsetzbar?

Damit verständlicher wird was ich meine, habe ich Beispieldaten in Excel angefügt.

Danke und nette Grüße

Volker


  Beispieldaten_Forum.xlsx (Größe: 11,35 KB / Downloads: 3)

[Jockel]

Hallo, eine Variante ohne MAXWENNS()...

oder..: 

Code:

=WENN(F11="";"";MAX(INDEX(D$11:D$24*(B$11:B$24=F11)*($C$11:$C$24={"A"."B"});)))

Arbeitsblatt mit dem Namen 'Tabelle1'
	B	C	D	E	F	G
10	KW	Läufer	Km		KW	Km
11	2016_14	A	10		2016_14	12
12	2016_14	A	10		2016_15	17
13	2016_14	C	13		2016_16	18
14	2016_14	B	12
15	2016_15	B	14
16	2016_15	B	12
17	2016_15	A	16
18	2016_15	A	17
19	2016_15	C	20
20	2016_15	C	21
21	2016_16	B	8
22	2016_16	B	10
23	2016_16	A	18
24	2016_16	A	11

Zelle	Formel
G11	=WENN(F11="";"";MAX(INDEX(D$11:D$24*(B$11:B$24=F11)*($C$11:$C$24<>"C");)))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Umstaende_halber]

Danke @Jockel,
schon ein ziemlicher Formelklopper. Wäre ich nie drauf gekommen. Formel funktioniert einwandfrei.

Vielen, vielen Dank

[Jockel]

Hallo, das hab ich mir auch nicht selber ausgedacht, zuerst in dieser Art gesehen bei neopa...

[Umstaende_halber]

Ich hatte selbst vorher gegoogelt. Leider aber nichts gefunden. Versuche mit Summenprodukt/Summewenns/Maxwenns verliefen ohne Erfolg (Trial and Error). Trotzdem, erst durch Deinen Tipp war das Problem gelöst, selbst wenn der Tippgeber jemand anderer war. Habe auch schon öfter von Dir Hilfe bekommen. Die Schnelligkeit imponiert immer wieder, teilweise echt Rekordverdächtig. Komme daher gern immer wieder hierhin zurück.

Bis dahin und nette Grüße

[shift-del]

Hallo

Das geht natürlich auch:

Code:

=MAXWENNS($D$11:$D$24;$B$11:$B$24;F11;$C$11:$C$24;"<>C")

Oder das:

Code:

=MAX(MAXWENNS($D$11:$D$24;$B$11:$B$24;F11;$C$11:$C$24;{"A";"B"}))

[Umstaende_halber]

Auch genial die Formel, danke @shift-del.

Was ich super finde, dass ich bei der jetzt hier ausprobierten Formel weitere Kriterien hinzufügen kann. Gleichzeitig kann ich auch noch bei Maxwenns in Verbindung mit Max bleiben. Einfach in den geschweiften Klammern weitere Kriterien eintragen (funktionierte reibungslos). Wird wahrscheinlich auch bei der 1. Formel von @Jockel funktionieren. Nur, dass dort die Indexschreibweise beachtet werden muss oder sollte. Punkt statt Semikolon in den geschweiften Klammern sonst gibt es leider ein #NV.

Es gibt eben nicht nur einen Weg. Das mag ich an dem Programm.