MONAT JAHR SUMME WENN FKT.

[fabsy123]

Moin,

bin neu hier und würde mich sehr über eure Hilfe freuen.

Ich arbeite immoment mit folgender formel, die auch bestens funktioniert:

=SUMME(WENN(($Q$41:$Q$3620="AI");WENN(MONAT($F$41:$F$3620)=2;$P$41:$P$3620)))

Es handelt sich um eine Tabelle, die die Werte in Spalte P addiert, sobald in Q "AI" steht, und der Monat in F Februar ist.
Ich habe noch weitere monate und Jahre in der Tabelle. Für alle Monate im Jahr 2016, werden die Werte auch korrekt addiert. Sobald es aber um die zu addierenden Werte im Jahr 2017 oder 2018 geht, funktioniert die Formel noch nicht. 

Die Formel müsste so erweitert warden, dass neben dem Monat auch das Jahr Berücksichtgung findet.

Danke im Voraus.

[steve1da]

Hola,

ungetestet:

Code:

=SUMMENPRODUKT((MONAT(F41:F43)=2)*(JAHR(F41:F43)=2016)*(Q41:Q43="ai")*(P41:P43))

oder

Code:

=SUMMENPRODUKT((TEXT(F41:F43;"MM.JJJJ")="02.2016")*(Q41:Q43="ai")*(P41:P43))

Gruß,
steve1da

[Rabe]

Hi,#

Ich arbeite immoment mit folgender formel, die auch bestens funktioniert:

=SUMME(WENN(($Q$41:$Q$3620="AI");WENN(MONAT($F$41:$F$3620)=2;$P$41:$P$3620)))

das glaube ich nicht, daß diese Formel funktioniert. Bei mir kommt da #WERT!, und da fehlt zwei Mal der "SONST"-Teil der WENN-Funktion.

Nimm mal diese Formeln:

Tabelle1

	F	G	H	I	J	K	L	M	N	O	P	Q
4					#WERT!
5
40				Monat	14
41	01.02.2016			Jahr/Monat	5	2017					5	AI
42	01.02.2016										3
43	01.02.2016										4	AI
44	01.02.2017										5	AI
45	02.02.2017										3
46	02.03.2017										4	AI
47

verwendete Formeln
Zelle	Formel	Bereich	N/A
J4	=SUMME(WENN(($Q$41:$Q$3620="AI");WENN(MONAT($F$41:$F$3620)=2;$P$41:$P$3620)))
J40	=SUMMENPRODUKT(($Q$41:$Q$3620="AI")*(MONAT($F$41:$F$3620)=2)*$P$41:$P$3620)
J41	=SUMMENPRODUKT(($Q$41:$Q$3620="AI")*(MONAT($F$41:$F$3620)=2)*(JAHR($F$41:$F$3620)=$K$41)*$P$41:$P$3620)

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 21.07 einschl. 64 Bit

[fabsy123]

Hola,

ungetestet:

Code:

=SUMMENPRODUKT((MONAT(F41:F43)=2)*(JAHR(F41:F43)=2016)*(Q41:Q43="ai")*(P41:P43))

oder

Code:

=SUMMENPRODUKT((TEXT(F41:F43;"MM.JJJJ")="02.2016")*(Q41:Q43="ai")*(P41:P43))

Gruß,
steve1da

Hello,

die zweite Formel funktioniert. Weltklasse, danke für die schnelle Hilfe :)

[steve1da]

Hola,

die zweite Formel funktioniert

die erste übrigens auch ;)

Deine mit einer Anpassung übrigens auch:

Code:

{=SUMME(WENN(($Q$41:$Q$3620="AI");WENN((MONAT($F$41:$F$3620)=2)*(JAHR($F$41:$F$3620)=2016);$P$41:$P$3620)))}

Gruß,
steve1da

[Rabe]

Hi,

Deine mit einer Anpassung übrigens auch:

Code:

{=SUMME(WENN(($Q$41:$Q$3620="AI");WENN((MONAT($F$41:$F$3620)=2)*(JAHR($F$41:$F$3620)=2016);$P$41:$P$3620)))}

ok, als Matrix-Formel. Da finde ich meine Summenproduktformel besser.

Oder gleich als Pivot-Tabelle:

Tabelle1

	F	G	H	I	J	K	L	M	N	O	P	Q	R
40	Datum										Anzahl	Kriterium	Datum
41	01.02.2016			Monat	14						5	AI	01.02.2016
42	01.02.2016			Jahr/Monat	5	2017					3		01.02.2016
43	01.02.2016										4	AI	01.02.2016
44	01.02.2017										5	AI	01.02.2017
45	02.02.2017										3		02.02.2017
46	02.03.2017										4	AI	02.03.2017
47
48
49
50			Zeilenbeschriftungen	Summe von Anzahl
51			'2016
52			Feb	9
53			AI	9
54			'2017
55			Feb	5
56			AI	5
57			Mrz	4
58			AI	4
59			Gesamtergebnis	18

verwendete Formeln
Zelle	Formel	Bereich	N/A
J41	=SUMMENPRODUKT(($Q$41:$Q$3620="AI")*(MONAT($F$41:$F$3620)=2)*$P$41:$P$3620)
J42	=SUMMENPRODUKT(($Q$41:$Q$3620="AI")*(MONAT($F$41:$F$3620)=2)*(JAHR($F$41:$F$3620)=$K$42)*$P$41:$P$3620)
R41:R46	=F41

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 21.07 einschl. 64 Bit

[BoskoBiati]

Hallo Ralf,

der Unterschied ist doch nur, dass das eine per se eine Matrixfunktion, mit allen Problemen von Matrizenoperation, ist, während das andere als Matrixformel eingegeben werden muß.
Allerdings würde ich die Matrixformel anders eingeben:

Code:

{=SUMME(WENN(($Q$41:$Q$3620="AI")*(MONAT($F$41:$F$3620)=2)*(JAHR($F$41:$F$3620)=2016);$P$41:$P$3620)))}

Dann sieht Sie schon aus wie die Summenprodukt-Formel