Mail per VBA erzeugen und automatisch Link in Inhalt einfügen

[eitel91]

Hallo zusammen,

ich habe folgenden Wunsch:

in meiner Datei habe ich Buttons, mit denen sich automatisch das Outook-Versenden Fenster öffnet.

Der Code hierfür sieht so aus:

Code:

Sub MailMitOutlookEmpfang()
   Dim Nachricht As Object, OutApp As Object
   Set OutApp = CreateObject("Outlook.Application")
   Set Nachricht = OutApp.CreateItem(0)
   With Nachricht
       .to = "m.muster@muster.de"
       .Subject = "Formular Nr. " & Sheets("Tabelle1").Cells(1, 9).Value & " wurde eröffnet"
       .Body = "Formular Nr. " & Sheets("Tabelle1").Cells(1, 9).Value & " wurde eröffnet."
       'Hier wird die Mail nochmals angezeigt
       .Display 'oder .Send zum versenden
       End With
   'OutApp.Quit
   Set OutApp = Nothing
   Set Nachricht = Nothing
End Sub

Nun hätte ich gerne, dass sich der Bereich

Code:

& Sheets("Tabelle1").Cells(1, 9).Value & "

schon automatisch mit einem Link in ein bestimmtes Verzeichnis versehen kann, sodass die Mail empfangende Person auf diesen Link klickt und in diesem Verzeichnis landet.

Hat jemand eine Idee?

Vielen Dank euch

[nitrosworld]

Hey,

versuchs mal damit:

Code:

Sub hyperlink_in_email_body()
   Dim sPath As String
   Dim LinkText As String

   sPath = Sheets("Tabelle1").Cells(1, 9).Value
   LinkText = "Hello"

   Dim mailmsg As Object
   Dim OutLkApp As Object

   Set OutLkApp = CreateObject("Outlook.Application")
   Set mailmsg = OutLkApp.CreateItem(0)
   With mailmsg
       .To = "hello@world.com"
       .Subject = sPath
       .HTMLBody = "<a href='" & sPath & "'>" & LinkText & "</a>"
       .Display
   End With

End Sub

Gruß
Chris

[eitel91]

Hallo nitrosworld,

ich bin relativ unerfahren mit VBA.

Wie sieht dann der komplette Code zusammen aus? Wenn ich nur diesen Code verwende passiert nichts.

Gruß

[nitrosworld]

Eigentlich müsstest du nur eine Zeile Code ersetzen, und zwar diese

Code:

.Body = "Formular Nr. " & Sheets("Tabelle1").Cells(1, 9).Value & " wurde eröffnet."

durch diese:

Code:

.HTMLBody = "<a href='" & Sheets("Tabelle1").Cells(1, 9).Value  & "'>" & "Das ist der LinkText" & "</a>"

So wie ich es verstanden habe, steht der Pfad der geöffnet werden soll in dieser Zelle:

Code:

Sheets("Tabelle1").Cells(1, 9).Value

Gruß
Chris

[eitel91]

Super hat geklappt vielen Dank Chris