Makro/VBA Reset Makro inkl. Dropdownmenüs

[Nordlicht85]

Moin moin liebe Forumgemeinde,

ich habe folgende Frage.

Ich habe einen Makro erstellt, in denen gewisse Zelleninhalte gelöscht werden.

Zusätzlich möchte ich das in 2 Dropdownmenüs auf den jeweiligen Anfangswert zurückgesetz wird.

Das die jeweiligen Zelleninhalte gelöscht werden, funktionniert auch wunderbar, nur leider setzt er die jeweiligen Dropdownmenüs nicht auf den gewünschten Wert zurück.

1. Dropdownmenü F7:H7 (Zellenverbund), hier ist der gewünschte Wert: bitte auswählen

2. Dropdownmenü F9, hier ist der gewünschte Wert: 12

Klasse wäre noch, wenn er durch auswählen des Rest Makro direkt in den Zellenverbund F3:H3 wechsel.

Ich hoffe ihr könnt mir helfen!

Vielen Dank vorab


Anbei der Code

Sub ResetEingaben()
'
' ResetEingaben Makro
'
'
    Range("F3:H3").Select
    Selection.ClearContents
    Range("F5:H5").Select
    Selection.ClearContents
    Range("F11").Select
    Selection.ClearContents
    Range("D12").Select
    Selection.ClearContents
    Range("D14").Select
    Selection.ClearContents
    Range("D15").Select
    Selection.ClearContents
    Range("F19").Select
    Selection.ClearContents
    Range("F20").Select
    Selection.ClearContents
    Range("F21").Select
    Selection.ClearContents
    Range("F22").Select
    Selection.ClearContents
    Range("F23").Select
    Selection.ClearContents
    Range("F24").Select
    Selection.ClearContents
    Range("F25").Select
    Selection.ClearContents
    ActiveWindow.SmallScroll Down:=12
    Range("F32").Select
    Selection.ClearContents
    Range("D33").Select
    Selection.ClearContents
    Range("D34").Select
    Selection.ClearContents
    Range("D35").Select
    Selection.ClearContents
    Range("D36").Select
    Selection.ClearContents
    Range("D37").Select
    Selection.ClearContents
    Range("D38").Select
    Selection.ClearContents
    Range("D39").Select
    Selection.ClearContents
    Range("D40").Select
    Selection.ClearContents
    Range("D41").Select
    Selection.ClearContents
    ActiveWindow.SmallScroll Down:=-30
    Range("F3:H3").Select
End Sub

[Crazy Tom]

Hallo

da haste aber ein schickes Makro
das hier sollte es aber auch tun

Code:

Sub ResetEingaben()
   Range("F3:H3,F5:H5").ClearContents
   Range("F11,D12,D14:D15").ClearContents
   Range("F19:F25").ClearContents
   Range("F32,D33:D41").ClearContents
End Sub

was für Dropdowns hast du denn in den Zellen?

MfG Tom

[atilla]

Hallo,

schau Dir mal unten stehenden Code an.

Code:

Sub ResetEingaben()
'
' ResetEingaben Makro
'

 Union(Range("F3:H3"), Range("F5:H5"), Range("F11"), Range("D12")).ClearContents
 
 Range("F7:H7").Value = "bitte auswählen" 'Zellen F7:H7 ausfüllen
 Range("F9") = 12                         'Zelle F9 12 reinschreiben

End Sub

Diese drei Zeilen sollten für Dich reichen.

Du musst nur, so wie ich es mit drei Bereichen gemacht habe, innerhalb der Klammern hinter Union
die anderen zu löschenden Bereiche einfügen.

[Nordlicht85]

Moin moin,

ich habe nun den Makro wie unten stehend editiert:

Folgende Probleme habe ich noch:

1.) Im Zellenbereich F7:H7 schreibt er zwar nun den Text "bitte auswählen", jedoch hatte ich urprünglich per VBA programiert, dass er bei dem Textinhalt "bitte auswählen" sämtliche Zeilen einblenden soll. Die Dropdown Auswahlliste ist nämlich so programiert, das je nach Auswahl einzelne Zeilen ausgeblendet werden.

Hier liegt nun das Problem vor, dass wenn ich über die Dropdown Liste z.B. "privat versichert" ausgewählt habe und den Makro ausführe, schreibt er zwar den Text "bitte auswählen" in die Zelle, blendet jedoch nicht alle Zeilen (gewünscht 13:42) wieder ein. Ich hoffe ihr versteht was ich meine.

2.) Springt er nach Ausführung des Makros noch nicht in den Zellenbereich F3:H3 (Zellenverbund)?

Vielen Dank für eure Hilfe!


Makro Programierung:

Sub ResetEingaben()
'
' ResetEingaben Makro
'
  Range("F3:H3,F5:H5").ClearContents
  Range("F11,D12,D14: D15").ClearContents
  Range("F19:F25").ClearContents
  Range("F32,D33: D41").ClearContents
 
  Range("F7:H7").Value = "bitte auswählen" 'Zellen F7:H7 ausfüllen
  Range("F9") = 12                         'Zelle F9 12 reinschreiben
End Sub

VBA Programierung:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address = "$F$7" Then
        Rows("13:42").Hidden = False
        Select Case Target.Value
            Case "gesetzl. pflichtversichert (KV)"
                Rows("13:15").Hidden = True
                Rows("33:40").Hidden = True
                Rows("42").Hidden = True
            Case "gesetzl. pflichtversichert (KV) inkl. Dienstwagen"
                Rows("33:40").Hidden = True
            Case "freiwillig gesetzl. versichert (KV)"
                Rows("13:15").Hidden = True
                Rows("22").Hidden = True
                Rows("25").Hidden = True
                Rows("38:40").Hidden = True
                Rows("42").Hidden = True
            Case "freiwillig gesetzl. versichert (KV) inkl. Dienstwagen"
                Rows("22").Hidden = True
                Rows("25").Hidden = True
                Rows("38:40").Hidden = True
            Case "privat versichert (KV)"
                Rows("13:15").Hidden = True
                Rows("22").Hidden = True
                Rows("25").Hidden = True
                Rows("35:38").Hidden = True
                Rows("40").Hidden = True
                Rows("42").Hidden = True
            Case "privat versichert (KV) inkl. Dienstwagen"
                Rows("22").Hidden = True
                Rows("25").Hidden = True
                Rows("35:38").Hidden = True
                Rows("40").Hidden = True
            Case "verbeamtet"
                Rows("13:15").Hidden = True
                Rows("22:25").Hidden = True
                Rows("33:37").Hidden = True
                Rows("42").Hidden = True
            Case "verbeamtet inkl. Dienstwagen"
                Rows("22:25").Hidden = True
                Rows("33:37").Hidden = True
        End Select
    End If
End Sub

[atilla]

Hallo,

das löst Du mit einem kleinen Befehl:

Code:

Sub ResetEingaben()
'
' ResetEingaben Makro
'
  Application.EnableEvents = False
  Range("F3:H3,F5:H5").ClearContents
  Range("F11,D12,D14Big Grin15").ClearContents
  Range("F19:F25").ClearContents
  Range("F32,D33Big Grin41").ClearContents
 
  Range("F7:H7").Value = "bitte auswählen" 'Zellen F7:H7 ausfüllen
  Rows("13:42").Hidden = False
  Range("F9") = 12                         'Zelle F9 12 reinschreiben
  Application.EnableEvents = True
  Range("F3:H3").Select 'spring dahin
End Sub

[Nordlicht85]

Hallo,

das er jetzt nach ausführen in den Zellenverbund  F3:H3 wechselt klappt wunderbar.

Leider blendet er jedoch noch nicht wieder die anderen Zeilen aus, er zeigt zwar in der Dropdownliste "bitte auswählen" an, nur die Bedingung die per VBA hinterlegt ist, das er dann sämtliche Zeilen wieder einblenden sollen, klappt leider noch nicht?

Hast du dazu noch eine Idee?

Besten Dank erstmal

[atilla]

Hallo,

o, da habe ich wieder mal zu schnell gelesen.

Hab im vorigen Beitrag den Code noch mal ergänzt. Bitt dort noch mal nachschauen.

[Nordlicht85]

Perfekt, vielen Dank!

Es funktioniert :15: