Clever-Excel-Forum › Office-Anwendungen › Excel v
Mehrere Bedingungen in Spalte nach oben überprüfen

Thema geschlossen 
Baumstrukturmodus
Mehrere Bedingungen in Spalte nach oben überprüfen
HerrPlanlos Offline
pausiert
Registriert seit: 24.04.2017
Version(en): 2010
#1
24.04.2017, 11:59 (Dieser Beitrag wurde zuletzt bearbeitet: 24.04.2017, 12:57 von HerrPlanlos.)
Hallo zusammen,

ich habe eine Frage und komme nicht weiter (mein Freund Google konnte nicht helfen). Ich hoffe ihr könnt mir weiterhelfen:

In der anliegenden Tabelle sind mehrere Qualitätsabnahmen von Prüflosen unterschiedlicher Lieferanten eingetragen (im Original ca. 1400).
Wenn ich eine Zeile für eine neue Abnahme anlege, sollen die letzten drei Abnahmen mit dem:
  • gleichen Lieferanten
  • gleichen Maschinentyp
  • gleicher Version
überprüft werden, ob die Prüflose akpzeptiert wurden. Wenn dem so ist, soll Stichprobe andernfalls 100%-Prüfung automatisch eingetragen werden.

Ich finde keine passende Formel die nur die letzten drei Abnahmen des gleichen Lieferanten etc. kontrolliert.
Ich hoffe ich konnte mein Problem einigermaßen beschreiben.

Gruß
HerrPlanlos


Angehängte Dateien
.xlsx   Beispiel.xlsx (Größe: 12,32 KB / Downloads: 0)
Suchen
Top
shift-del Offline
{Irrtum / Versuch * Glaskugel}
Registriert seit: 12.04.2014
Version(en): Office 365
#2
24.04.2017, 12:29
Hallo Herr Planlos

Code:
=WENN(ZÄHLENWENNS(B$1:B1;B2;C$1:C1;C2;D$1:D1;D2;F$1:F1;"Ja")=3;"Stichprobe";"100%")
Allerdings erhalte ich für Zeile 2 bis 10 abweichende Ergebnisse.
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.

Homepage Suchen
Top
HerrPlanlos Offline
pausiert
ThreadStarter
Registriert seit: 24.04.2017
Version(en): 2010
#3
24.04.2017, 12:57 (Dieser Beitrag wurde zuletzt bearbeitet: 24.04.2017, 12:57 von HerrPlanlos.)
Vielen Dank für deine Antwort, aber in der Formel werden doch nicht nur die letzten 3 Abnahmen bei den gleichen Lieferanten auf die genannten Bedingungen hin überprüft. Wie müsste ich dei Formel denn noch anpassen?
Ich habe deine Formel mal mit eingefügt.


Angehängte Dateien
.xlsx   Beispiel.xlsx (Größe: 12,69 KB / Downloads: 8)
Suchen
Top
shift-del Offline
{Irrtum / Versuch * Glaskugel}
Registriert seit: 12.04.2014
Version(en): Office 365
#4
24.04.2017, 13:37
Stimmt. Das hatte ich aus den Augen verloren.
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.

Homepage Suchen
Top
BoskoBiati Offline
नौसिखिया [vidyaarthi]

Registriert seit: 13.04.2014
Version(en): 365
#5
24.04.2017, 14:07
Hi,

mit einer Hilfsspalte:

Arbeitsblatt mit dem Namen 'Tabelle1'
 ABCDEFGH
1FormMaschinentypVersionLieferantDatumPrüflos angenommen (Ja/Nein)Art der Abnahme (100% oder Stichrobe)◄
2AbnahmeT10001A03.05.2016JaStichprobe1
3BesprechungsberichtAlleAlleB07.06.2016  0
4AbnahmeT20001B27.07.2016JaStichprobe1
5AbnahmeT20002A07.08.2016JaStichprobe1
6AbnahmeT10001C09.08.2016JaStichprobe1
7AbnahmeT10001A10.11.2016JaStichprobe2
8AbnahmeT20002A25.11.2016NeinStichprobe1
9AbnahmeT30001B21.12.2016JaStichprobe1
10AbnahmeT10001A03.02.2017Ja100%3
11AbnahmeT20002A25.03.2017JaStichprobe2
12AbnahmeT10001A10.04.2017Ja100%4
13AbnahmeT20002A25.04.2017Ja100%3

ZelleFormel
G2=WENN(A2<>$A$2;"";WENN((H2>2)*(ZÄHLENWENNS($B$1:B2;B2;$C$1:C2;C2;$D$1:D2;D2;$F$1:F2;"Ja";$H$1:H2;">"&H2-3)=3);"100%";"Stichprobe"))
H2=ZÄHLENWENNS($B$1:B2;B2;$C$1:C2;C2;$D$1:D2;D2;$F$1:F2;F2)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Suchen
Top
shift-del Offline
{Irrtum / Versuch * Glaskugel}
Registriert seit: 12.04.2014
Version(en): Office 365
#6
24.04.2017, 14:24
Bei mir wird es aufwändiger.

 ABCDEFGHIJ
1FormMaschinentypVersionLieferantDatumPrüflos angenommen (Ja/Nein)Art der Abnahme (100% oder Stichrobe)   
2AbnahmeT10001A03.05.2016JaStichprobe100%#ZAHL!#ZAHL!
3BesprechungsberichtAlleAlleB07.06.2016   #ZAHL!#ZAHL!
4AbnahmeT20001B27.07.2016JaStichprobe100%#ZAHL!#ZAHL!
5AbnahmeT20002A07.08.2016JaStichprobe100%#ZAHL!#ZAHL!
6AbnahmeT10001C09.08.2016JaStichprobe100%#ZAHL!#ZAHL!
7AbnahmeT10001A10.11.2016JaStichprobe100%#ZAHL!#ZAHL!
8AbnahmeT20002A25.01.2016NeinStichprobe100%#ZAHL!#ZAHL!
9AbnahmeT30001B21.03.2017JaStichprobe100%#ZAHL!#ZAHL!
10AbnahmeT10001A10.11.2016JaStichprobe100%#ZAHL!#ZAHL!
11AbnahmeT20002A25.01.2016Ja100%100%#ZAHL!#ZAHL!
12AbnahmeT10001A10.11.2016JaStichprobeStichprobe23
13AbnahmeT20002A25.01.2016Ja100%100%52
14AbnahmeT10001A Nein Stichprobe73
15AbnahmeT10001A Ja 100%102
16AbnahmeT10001A Ja 100%122
17AbnahmeT10001A Ja 100%142
18AbnahmeT10001A   Stichprobe153

ZelleFormel
H2=WENN(A2<>"Abnahme";"";WENNFEHLER(WENN(J2=3;"Stichprobe";"100%");"100%"))
I2=AGGREGAT(14;6;ZEILE(B$1:B1)/((B$1:B1=B2)/(C$1:C1=C2)/(D$1:D1=D2));3)
J2=ZÄHLENWENNS(INDEX(B:B;I2):INDEX(B:B;ZEILE(A1));B2;INDEX(C:C;I2):INDEX(C:C;ZEILE(A1));C2;INDEX(D:D;I2):INDEX(D:D;ZEILE(A1));D2;INDEX(F:F;I2):INDEX(F:F;ZEILE(A1));"Ja")
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.

Homepage Suchen
Top
neopa Offline
der neopa oder Werner
Registriert seit: 05.05.2014
Version(en): 2010 + 2016 Home and Business
#7
24.04.2017, 15:05
Hallo,

die verbalen Vorgaben stimmen mE nicht mit dem fix in Spalte G eingeschriebenen "Ergebnisswerten" überein.

Die verbalen Vorgaben würde ich so realisieren:

ABCDEFGH
1FormMaschinentypVersionLieferantDatumPrüflos angenommen (Ja/Nein)Art der Abnahme (100% oder Stichrobe)HS
2AbnahmeT10001A03.05.2016JaStichprobe
3BesprechungsberichtAlleAlleB07.06.2016
4AbnahmeT20001B27.07.2016JaStichprobe
5AbnahmeT20002A07.08.2016JaStichprobe
6AbnahmeT10001C09.08.2016JaStichprobe
7AbnahmeT10001A10.11.2016JaStichprobe
8AbnahmeT20002A25.11.2016NeinStichprobe
9AbnahmeT30001B21.12.2016JaStichprobe
10AbnahmeT10001A03.02.2017JaStichprobe
11AbnahmeT20002A25.03.2017JaStichprobe
12AbnahmeT10001A10.04.2017Ja100%2
13AbnahmeT20002A25.04.2017JaStichprobe5
14AbnahmeT10001A10.05.2017NeinStichprobe7
15AbnahmeT20002A25.05.2017JaStichprobe8
16AbnahmeT20002A26.05.2017Ja100%11
17
Formeln der Tabelle
ZelleFormel
G2=WAHL(1+(A2="Abnahme")+WENNFEHLER((ZÄHLENWENNS(INDEX(B:B;H2):B1;B2;INDEX(C:C;H2):C1;C2;INDEX(D:D;H2):D1;D2;INDEX(F:F;H2):F1;"Ja")=3*(F2="Ja")););"";"Stichprobe";"100%")
H2=WENNFEHLER(AGGREGAT(14;6;ZEILE(A1:A$2)/(A1:A$2="Abnahme")/(B1:B$2=B2)/(C1:C$2=C2)/(D1:D$2=D2);3);"")
Gruß Werner
.. , - ...
Suchen
Top
HerrPlanlos Offline
pausiert
ThreadStarter
Registriert seit: 24.04.2017
Version(en): 2010
#8
24.04.2017, 15:17 (Dieser Beitrag wurde zuletzt bearbeitet: 24.04.2017, 15:17 von HerrPlanlos.)
Vielen vielen Dank.
Ich habe die Variante von shift-del verwendet und Sie funktioniert super.

Gruß
HerrPlanlos
Suchen
Top
neopa Offline
der neopa oder Werner
Registriert seit: 05.05.2014
Version(en): 2010 + 2016 Home and Business
#9
24.04.2017, 15:30 (Dieser Beitrag wurde zuletzt bearbeitet: 24.04.2017, 15:30 von neopa.)
Hallo,

der Vollständigkeit halber:

Offensichtlich hatte ich die Vorgabe:

Zitat:Wenn dem so ist, soll Stichprobe andernfalls 100%-Prüfung automatisch eingetragen werden

genau vertauscht aufgefasst. Dadurch ist auch die zusätzliche Prüfung auf "Ja" in der aktuellen Zeile nicht notwendig.

Somit muss ich in meiner Formel in G2 auch nur "Stichprobe" mit "100%" vertauschen und *(F2="Ja") löschen.


Code:
=WAHL(1+(A2="Abnahme")+WENNFEHLER((ZÄHLENWENNS(INDEX(B:B;H2):B1;B2;INDEX(C:C;H2):C1;C2;INDEX(D:D;H2):D1;D2;INDEX(F:F;H2):F1;"Ja")=3););"";"100%";"Stichprobe")

Die Formel in H2 bleibt.
Gruß Werner
.. , - ...
Suchen
Top
BoskoBiati Offline
नौसिखिया [vidyaarthi]

Registriert seit: 13.04.2014
Version(en): 365
#10
24.04.2017, 15:36
Hi,

der Fehler ist mir auch passiert.

Arbeitsblatt mit dem Namen 'Tabelle1'
 ABCDEFGH
1FormMaschinentypVersionLieferantDatumPrüflos angenommen (Ja/Nein)Art der Abnahme (100% oder Stichrobe)◄
2AbnahmeT10001A03.05.2016Ja100%1
3BesprechungsberichtAlleAlleB07.06.2016  0
4AbnahmeT20001B27.07.2016Ja100%1
5AbnahmeT20002A07.08.2016Ja100%1
6AbnahmeT10001C09.08.2016Ja100%1
7AbnahmeT10001A10.11.2016Ja100%2
8AbnahmeT20002A25.11.2016Nein100%1
9AbnahmeT30001B21.12.2016Ja100%1
10AbnahmeT10001A03.02.2017JaStichprobe3
11AbnahmeT20002A25.03.2017Ja100%2
12AbnahmeT10001A10.04.2017JaStichprobe4
13AbnahmeT20002A25.04.2017JaStichprobe3

ZelleFormel
G2=WENN(A2<>$A$2;"";WENN((H2>2)*(ZÄHLENWENNS($B$1:B2;B2;$C$1:C2;C2;$D$1:D2;D2;$F$1:F2;"Ja";$H$1:H2;">"&H2-3)=3);"Stichprobe";"100%"))
H2=ZÄHLENWENNS($B$1:B2;B2;$C$1:C2;C2;$D$1:D2;D2;$F$1:F2;F2)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Suchen
Top
Thema geschlossen 


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste