Mehrere Wenn hintereinander, wie schlank gestalten?

[TalaxGießen]

Huhuu

Habe mich dazu entschlossen, bei meinem Dienstplan Projekt, dass schon weit fortgeschritten ist, die Feiertage über ein "reihen" WENN zu lösen. Die wenns habe ich auch schon zusammen:

Code:

=WENN(B9=Ostersonntag-2;$Z$41;
WENN(B9=Ostersonntag;$Z$41;
WENN(B9=Ostersonntag+1;$Z$41;
WENN(B9=Ostersonntag+39;$Z$41;
WENN(B9=Ostersonntag+49;$Z$41;
WENN(B9=Ostersonntag+50;$Z$41;
WENN(B9=Ostersonntag+60;$Z$41;
WENN(B9=WOCHENTAG(1;17);$Z$41;
0))))))))

So weit so gut... Doch ist dieses $Z$41 nur ein Dummy und steht für eine ellenlange Formel, die für jeden der betroffenen Kalendertage nocheinmal etwas abgewandelt, also fortgeschrieben ist..

Code:

$Z$41 steht für:
=WENN(WOCHENTAG(B9)=1;MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+(C9>D9))-MAX(Basisdaten!$O$11;C9))+MAX(;(MIN(Basisdaten!$P$11;D9+(C9>D9))-C9)*(Basisdaten!$O$11>Basisdaten!$P$11))+MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+0)-Basisdaten!$O$11)*(C9>D9);0)

Wie ich den "dann" Befehl kürzen? Immerhin geht es für jeden Monat um rund 90 unterschiedlieche bzw. fortgeschriebene Formeln

Ne elegante Idee, die ich als Poweranfänger verstehe?  


Grüüße
Marcus

---

Komplett ausgeschrieben sähe es so aus:

 

Code:

=WENN(B9=Ostersonntag-2;MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+(C9>D9))-MAX(Basisdaten!$O$11;C9))+MAX(;(MIN(Basisdaten!$P$11;D9+(C9>D9))-C9)*(Basisdaten!$O$11>Basisdaten!$P$11))+MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+0)-Basisdaten!$O$11)*(C9>D9);
WENN(B9=Ostersonntag;MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+(C9>D9))-MAX(Basisdaten!$O$11;C9))+MAX(;(MIN(Basisdaten!$P$11;D9+(C9>D9))-C9)*(Basisdaten!$O$11>Basisdaten!$P$11))+MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+0)-Basisdaten!$O$11)*(C9>D9);
WENN(B9=Ostersonntag+1;MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+(C9>D9))-MAX(Basisdaten!$O$11;C9))+MAX(;(MIN(Basisdaten!$P$11;D9+(C9>D9))-C9)*(Basisdaten!$O$11>Basisdaten!$P$11))+MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+0)-Basisdaten!$O$11)*(C9>D9);
WENN(B9=Ostersonntag+39;MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+(C9>D9))-MAX(Basisdaten!$O$11;C9))+MAX(;(MIN(Basisdaten!$P$11;D9+(C9>D9))-C9)*(Basisdaten!$O$11>Basisdaten!$P$11))+MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+0)-Basisdaten!$O$11)*(C9>D9);
WENN(B9=Ostersonntag+49;MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+(C9>D9))-MAX(Basisdaten!$O$11;C9))+MAX(;(MIN(Basisdaten!$P$11;D9+(C9>D9))-C9)*(Basisdaten!$O$11>Basisdaten!$P$11))+MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+0)-Basisdaten!$O$11)*(C9>D9);
WENN(B9=Ostersonntag+50;MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+(C9>D9))-MAX(Basisdaten!$O$11;C9))+MAX(;(MIN(Basisdaten!$P$11;D9+(C9>D9))-C9)*(Basisdaten!$O$11>Basisdaten!$P$11))+MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+0)-Basisdaten!$O$11)*(C9>D9);
WENN(B9=Ostersonntag+60;MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+(C9>D9))-MAX(Basisdaten!$O$11;C9))+MAX(;(MIN(Basisdaten!$P$11;D9+(C9>D9))-C9)*(Basisdaten!$O$11>Basisdaten!$P$11))+MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+0)-Basisdaten!$O$11)*(C9>D9);
WENN(B9=WOCHENTAG(1;17);MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+(C9>D9))-MAX(Basisdaten!$O$11;C9))+MAX(;(MIN(Basisdaten!$P$11;D9+(C9>D9))-C9)*(Basisdaten!$O$11>Basisdaten!$P$11))+MAX(;MIN(Basisdaten!$P$11+(Basisdaten!$O$11>Basisdaten!$P$11);D9+0)-Basisdaten!$O$11)*(C9>D9);
0))))))))

Und das wäre nur eines von 90 Feldern....

[steve1da]

Hola,

wir sollen also eine Formel kürzen ohne den Tabellenaufbau zu kennen, bzw. was in den Zellen steht die in der Formel angesprochen werden?
Gruß,
steve1da

[shift-del]

Moin

Ich meine Ralf (RPP63) hatte eine Super-Feiertags-Formel kreiert. Allerdings mit Office365-Features.

[RPP63]

Danke für die Blumen, Detlef!
In A1 steht das Jahr, die Liste erhält man mit

PHP-Code:

=SORTIEREN(EINDEUTIG(
LET(
FFT;DATUM(A1;1;{1;121;276;305;359;360})+WENN(MONAT(DATUM(A1;2;29))=2;{0;1;1;1;1;1});
OFT;RUNDEN((TAG(MINUTE(A1/38)/2+55)&".4."&A1)/7;0)*7-6+{-2;0;1;39;49;50;60};
x;ZEILEN(FFT);
y;ZEILEN(OFT);
z;SEQUENZ(x+y);
WENN(z<x+1;INDEX(FFT;z);INDEX(OFT;z-x))
))) 


Aber ist ja hier nicht zielführend.
Um festzustellen, ob ein Datum ein Feiertag ist, braucht es kein ellenlanges WENN-Konstrukt, sondern besagte Liste (egal, wie die erstellt wird) und ein simples Zählenwenn:

	A	B	C	D
1	2021
2	Fr          01.01		12.05.2021	kein Feiertag
3	Fr          02.04		13.05.2021	Feiertag
4	So        04.04
5	Mo      05.04
6	Sa        01.05
7	Do        13.05
8	So        23.05
9	Mo      24.05
10	Do        03.06
11	So        03.10
12	Mo      01.11
13	Sa        25.12
14	So        26.12

Zelle	Formel
D2	=WENN(ZÄHLENWENN(A$2:A$14;C2);"";"kein ")&"Feiertag"
D3	=WENN(ZÄHLENWENN(A$2:A$14;C3);"";"kein ")&"Feiertag"

Gruß Ralf

[TalaxGießen]

Hola,

wir sollen also eine Formel kürzen ohne den Tabellenaufbau zu kennen, bzw. was in den Zellen steht die in der Formel angesprochen werden?
Gruß,
steve1da

Die Tabelle ist mittlerweile sehr komplex geworden. Dort mal eben durchblicken zu wollen, stelle ich mir sehr schwierig vor.

Daher habe ich es mit den Bruckstüchen versucht.


@RPP63
Danke da hab ich was zu knabbern

[RPP63]

Da brauchst Du nicht knabbern, sondern einfach strukturiert vorgehen.
Gut, ein paar Cracker kannst Du währenddessen ja verputzen …

Erstelle die Feiertagsliste und gebe ihr den Namen FT
Aus

PHP-Code:

=WENN(B9=Ostersonntag-2;$Z$41;
WENN(B9=Ostersonntag;$Z$41;
WENN(B9=Ostersonntag+1;$Z$41;
WENN(B9=Ostersonntag+39;$Z$41;
WENN(B9=Ostersonntag+49;$Z$41;
WENN(B9=Ostersonntag+50;$Z$41;
WENN(B9=Ostersonntag+60;$Z$41;
WENN(B9=WOCHENTAG(1;17);$Z$41;
0)))))))) 


wird dann ein flauschiges

PHP-Code:

=WENN(ZÄHLENWENN(FT;B9);$Z$41;0) 


Das andere Monster schaue ich mir mal an, aber ich erwarte durchaus auch Deinen Einsatz!

---

Übrigens:
Was erwartest Du von WOCHENTAG(1;17)
Das ergibt IMMER 1, folglich ist B9=1 offensichtlich immer FALSCH