MinWenns ohne leer und zukünftiges Datum

[Tanja20]

Hallo zusammen,

ich bastel nun schon ewig an einer Formel herum, die nicht klappen will. Ich habe die Spalten P, T, X, AB, AD und AF für Fristen eingerichtet, also jeweils als Datum formatiert. Es kann aber sein, dass in einer Zeile gar kein Feld befüllt ist oder auch nur eins. Die Spalten dazwischen jeweils beinhalten andere Inhalte. In Spalte F soll mir jeweils das Datum ermittelt werden, welches als nächstes anliegt. 

Das wäre schon mal die halbe Miete. 

Richtig gut wäre es, noch mit folgender Abwandlung: In den Spalten wischen den jeweiligen Daten wird die Frist mit einem ü (ein Häkchen bei der Schriftart Wingdings) als erledigt markiert. Wenn in Spalte F nun die nächste anstehende Frist erscheint, und das nur dann, wenn sie nicht bereits erledigt (=ü) ist, wäre das der Hammer.

Kann mir da jemand helfen?

Viele Dank vorab.

[BoskoBiati]

Hi,

wie wäre es, wenn Du Deine Datei mal zeigst???

[Tanja20]

Habe ich angehängt. Musste sie aber neu aufbauen, also die spalten sind jetzt andere. Genau die Datei darf ich leider nicht teilen. In Spalte A soll jetzt die nächste Frist aus den grünen spalten, die hier jetzt leer sind. Spalten C, G, K , O, Q und S sind für die Häkchen.

[BoskoBiati]

Hi,

1. macht eine leere Datei genausowenig Sinn wie ein Bild.
2. sollte die Datei im Aufbau dem Original entsprechen.

Wenn Du Hilfe willst, dann zeige eine Datei, die dem Original entspricht und in der zumindest Dummy-Daten sowie Wunschergenisse enthalten sind.

[Tanja20]

Die Spalten hätte ich ja ändern können, aber anbei noch einmal etwas mehr befüllt, die Spalten sind nun da, wo sie in meiner Datei auch sind mit einigen fiktiven Daten.

Vielen Dank schonmal!

[Fred11]

Hallo Tanja,

wenn ich dich richtig verstanden habe, sollte das mit folgender Formel funktionieren:

Formel für F2:
=WENNFEHLER(HEUTE()+AGGREGAT(15;6;($P2:$AF2-HEUTE())/((LINKS($P$1:$AF$1;5)="Frist")*($P2:$AF2>0)*($Q2:$AG2<>"ü"));1);"")

Da du zur Ermittlung des kleinsten Datums ja nur die grünen Spalten berücksichtigen möchtest (und nicht die Werte in den Spalten dazwischen), muss zur  Bestimmung der relevanten Spalten in den Spaltenüberschriften bei den grünen Spalten ein eindeutiges und einheitliches (Erkennungs-) Merkmal stehen.
Die Formel prüft, ob der Zelleintrag in P1:AF1 mit "Frist" beginnt und berücksichtigt dann nur diese Spalten für die Auswertung.
Das funktioniert aber nur, wenn die Spaltenüberschriften in den Spalten dazwischen nicht mit "Frist" beginnen.
Ich habe deine Spaltenüberschriften deshalb entsprechend angepasst.

Edit:
Oder so (etwas einfacher):
=WENNFEHLER(AGGREGAT(15;6;($P2:$AF2)/((LINKS($P$1:$AF$1;5)="Frist")*($P2:$AF2>=HEUTE())*($Q2:$AG2<>"ü"));1);"")
(nicht abgehakte Datumswerte, die in der Vergangenheit liegen, werden hier allerdings nicht berücksichtigt)

Gruß
Fred

[Fred11]

...und mit MINWENNS() geht's natürlich auch:
=WENN(ANZAHL($P2:$AF2)>0;MINWENNS($P2:$AF2;$P$1:$AF$1;"Frist*";$P2:$AF2;">="&HEUTE();$Q2:$AG2;"<>ü");"")

Gruß
Fred

[Tanja20]

Wow! Ganz vielen Dank! Das werde mal in Ruhe testen. Wirklich sehr hilfreich:)

[Tanja20]

Es funktioniert genauso wie ich es wollte! Vielen Dank nochmal. :)