Mitelwert der letzten Einträge

[Manfred28]

Hallo,

ich habe für mein Team eine Excel Datei erstellt, in der ich die tägliche Inbound Mailbearbeitung eintrage.

Hierfür habe ich in Spalte A das Datum und in Spalte B bis I die einzelnen Mitarbeiter.
Die Daten starten ab Zeile 6, die ersten Zeilen sind nur für Namen, Durchschnittswerte gesamt, usw.

So, nun zum Problem. Aktuell sieht die Formel bei mir so aus (Durchschnitt letzte 10 Tage):

=MITTELWERT(BEREICH.VERSCHIEBEN($B$6;ANZAHL2($B$6:$B$999)-10;0;10;1))


Das klappt auch soweit ganz gut, bis auf ein kleines Problem.

In den Spalten B bis I sind nicht nur die Zahlen mit der Anzahl der Mails, sondern auch Buchstaben mit "F","K" und "U",
damit ich auch gleich weiß, wann der Mitarbeiter Krank oder Urlaub hatte.

Wenn ich jetzt jemanden in der Liste habe, der 10 aufeinanderfolgende Tage oder mehr einen Buchstaben in den
Zellen hat, dann gibt Excel mit als Ergebnis "#DIV/0!" als Ergebnis an, was auch logisch ist, da er dann den
Mittelwert daraus errechnen will und das funktioniert nun mal nicht.

Bei der normalen Mittelwertberechnung mit =MITTELWERT(B6:B999) ignoriert er ja leere Zellen und Zellen mit Buchstaben.

Kann ich meine Formel oben so ändern, dass er nur Zahlen in die Berechnung ausnimmt, dies müsste
ja mit =WENN(ISTZAHL oder so ähnlich funktionieren, oder?

Leider bin ich kein Excel Profi und bräuchte deswegen mal ein wenig Hilfe, wie ich die Formel umstellen kann ;)

Schon mal danke...

[ws-53]

z.B.: =WENFEHLER(MITTELWERT(BEREICH.VERSCHIEBEN($B$6;ANZAHL2($B$6:$B$999)-10;0;10;1)):"")

[Manfred28]

Hi, ich gehe mal davon aus du meintest =WENNFEHLER, da fehlte ein N :)

Wenn ich die Formel so eingebe bekomme ich die Meldung "Sie haben zu wenig Argumente für diese Funktion eingegeben".
Der Fehler bezieht sich wohl auf das "", denn dieser Bereich wird direkt hervorgehoben.

[BigJane]

Er wollte sicher vor das "" ein ; setzen statt ein :

[Manfred28]

Danke, mit dem ; funktioniert die Formel.

Sie bewirkt aber leider nur, dass der Fehler "#DIV/0!" nicht mehr erscheint.
Wenn in der Spalte mehr als 10 Zellen ohne Zahlen in Folge vorhanden sind, zeigt er das Ergebnis als leeres Feld an.

Er rechnet die Felder ohne Zahlen mit rein, optimal wäre es, wenn er wirklich nur die Fehler mit Zahlen in die
Berechnung mit aufnehmen würde, da ich den Durchschnitt der 10 letzten Einträge (die Zahlen enthalten) bräuchte.

[HKindler]

Hi,

dann hat deine Formel aber prinzipiell ein Problem. Den im Augenblick berechnest du den Mittelwert der letzten 10 Einträge. Wenn da nun also ein einziges "F" steht, so hast du nur den Mittelwert der letzten 9 Zahlen. Bei 9 "F" ist des der Mittelwert nur einer einzigen Zahl und bei 10 "F" kommt halt die Fehlermeldung. Es gibt noch andere Probleme, z.B. wenn du leere Zellen zwischen den Einträgen hast (dein Bereich geht dann nicht bis zur letzten Zeile), oder insgesamt weniger als 4 Einträge hast (#BEZUG!-Fehler) oder weniger als 10 Einträge (Bereich fängt zu früh an).

Wenn du all diese Dinge ausschließen willst musst du ganz anders an die Bereichsfindung herangehen:

Code:

=LET(a;B$6:B$999;b;FILTER(a;ISTZAHL(a));c;ÜBERNEHMEN(b;-10);d;MITTELWERT(c);d)

Noch besser wäre es, du machst aus deiner Tabelle eine intelligente Tabelle, dann brauchst du diese nämlich nicht auf Zeile 6:999 begrenzen. Für "Mitarbeiter1" der Tabelle "InboundMailbearbeitung" lautet die Formel dann:

Code:

=LET(a;InboundMailbearbeitung[Mitarbeiter1];b;FILTER(a;ISTZAHL(a));c;ÜBERNEHMEN(b;-10);d;MITTELWERT(c);d)

[steve1da]

Hatte ihm hier wohl zu lange gedauert:
https://www.herber.de/forum/archiv/1988t...raege.html