Mittelwertwenn / Mittelwert mit Bedingung

[Katja213]

Hallo an alle,

ich bin neu hier im Forum, und habe mir schon den halben Tag die Zähne an dieser Datei ausgebissen :'D
Unten ein fiktives Beispiel, wie meine Tabelle ungefähr aussieht. In der linken Spalte steht die Benennung, und ich würde gerne Mittelwerte für alle drei Faktoren berechnen können. Ich habe versucht, die Mittelwertwenn-Funktion zu benutzen, oder die Mittelwert-Funktion und eine Wenn-Funktion zu schachteln, aber da ich mehr als eine Spalte und nicht sehr viel Erfahrung mit Excel habe, bin ich bis jetzt gescheitert. Wenn mir jemand dabei helfen könnte, diese Mittelwerte zu berechnen, wäre ich sehr dankbar!

Viele liebe Grüße,
Katja


  Beispiel Sheet.xlsx (Größe: 9,16 KB / Downloads: 10)

[Fred11]

Hallo Katja,

wenn du die Mittelwerte pro Spalte haben möchtest, dann einfach so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
2	230306 LW Me	1,6	5,4	8,1	9,3	11,5
3	230306 LW Ge	5,2	4,8	7,6	5,4	17,4
4	230306 BO Me	0,1	11,5	4,2	8,7	14,9
5	230306 BO Ge	12,3	14,8	17,0	9,2	3,6
6	230307 LW Me	11,2	11,2	4,5	8,8	7,9
7	230307 LW Ge	2,1	5,3	1,9	2,6	4,7
8	230307 BO Me	3,6	8,7	1,5	9,4	1,6
9	230307 BO Ge	2,5	14,3	7,8	6,4	1,5
10
11	Gesucht: jeweils Mittelwerte für alle Ergebnisse, die im Namen stehen haben:
12	230306	4,8	9,125	9,225	8,15	11,85
13	230307	4,85	9,875	3,925	6,8	3,925
14	LW	5,025	6,675	5,525	6,525	10,375
15	BO	4,625	12,325	7,625	8,425	5,4
16	Me	4,125	9,2	4,575	9,05	8,975
17	Ge	5,525	9,8	8,575	5,9	6,8

Zelle	Formel
B12	=MITTELWERTWENN($A$2:$A$9;"*"&$A12&"*";B$2:B$9)

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

Den bedingten Mittelwert für den gesamten Datenbereich (B2:F9) zum Beispiel so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
2	230306 LW Me	1,6	5,4	8,1	9,3	11,5
3	230306 LW Ge	5,2	4,8	7,6	5,4	17,4
4	230306 BO Me	0,1	11,5	4,2	8,7	14,9
5	230306 BO Ge	12,3	14,8	17,0	9,2	3,6
6	230307 LW Me	11,2	11,2	4,5	8,8	7,9
7	230307 LW Ge	2,1	5,3	1,9	2,6	4,7
8	230307 BO Me	3,6	8,7	1,5	9,4	1,6
9	230307 BO Ge	2,5	14,3	7,8	6,4	1,5
10
11	Gesucht: jeweils Mittelwerte für alle Ergebnisse, die im Namen stehen haben:
12	230306	8,63
13	230307	5,875
14	LW	6,825
15	BO	7,68
16	Me	7,185
17	Ge	7,32

Zelle	Formel
B12	=MITTELWERT(FILTER($B$2:$F$9;ISTZAHL(SUCHEN(A12;$A$2:$A$9))))

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

Oder du verwendest den Autofilter und ermittelst den Mittelwert mit TEILERGEBNIS(1; ...)
Siehe angehängte Beispieldatei (Tabellenblatt "Variante 2")

Gruß
Fred

[BoskoBiati]

Hi,

hier mal meine Version:


  Beispiel Sheet.xlsx (Größe: 10,4 KB / Downloads: 5)

[Katja213]

Hallo Edgar,

danke sehr, das hat mir schon echt weitergeholfen! Eine weitere Frage hätte ich jetzt aber noch: Ich muss die Formel im Moment so schreiben, dass meine Matrix wirklich nur die bestehende Tabelle ist. Sobald leere Zeilen drin sind, kriege ich eine Fehlermeldung. Ich füge allerdings jeden Tag mehrere Zeilen zu der Tabelle hinzu. Gibt es eine Möglichkeit, dass ich dann nicht für jeden Mittelwert, den ich berechnen will, händisch die Matrix um die neuen Zeilen erweitern muss, sondern Excel automatisch erkennt, dass es die neuen Zeilen auch beachten soll?

Lieben Dank nochmal und viele Grüße,
Katja

[HKindler]

Hi,

ja klar. Verwende eine Strg-T-Tabelle und strukturierte Verweise.

[BoskoBiati]

Hi,

abgesehen davon, dass die Lösung von Helmut eine Möglichkeit wäre, kann ich den Fehler nicht nachvollziehen.


  Beispiel Sheet.xlsx (Größe: 10,39 KB / Downloads: 1)

[Katja213]

Hallo,

danke euch allen für die Tipps, die Strg-T-Tabelle hat echt geholfen. Ich hab leider direkt ein neues Problem... Die Parameter Me / Ge sind jetzt nicht mehr gefragt, dafür aber, in welcher Spalte der Tabelle die Werte stehen. Wenn ich das versuche, zu filtern, kriege ich eine #WERT! Fehlermeldung.
   

Hier eine aktualisierte Version der Datei.

  Beispiel Sheet Stand 0309.xlsx (Größe: 12,08 KB / Downloads: 5)

Vielen Dank noch einmal!

Viele Grüße,
Katja

[HKindler]

Hi,

du musst deine gefilterten Werte filtern:

also statt

Code:

=MITTELWERT(
    FILTER(
        Tabelle1[[Run 1]:[Run 5]];
        (Tabelle1[[#Kopfzeilen];[Run 1]:[Run 5]]=$H4)
        *
        (LINKS(Tabelle1[Name];6)=J$1)
    )
)

brauchst du

Code:

=MITTELWERT(
    FILTER(
        FILTER(
            Tabelle1[[Run 1]:[Run 5]];
            Tabelle1[[#Kopfzeilen];[Run 1]:[Run 5]]=$H4
        );
        LINKS(Tabelle1[Name];6)=J$1
    )
)

[Katja213]

Hallo,

so funktioniert es, vielen, vielen Dank!

Liebe Grüße,
Katja